Windows 3.1/3.11 Troubleshooting

Windows 3.1/3.11 Troubleshooting

Windows 3.1 has a few basic tools built in for troubleshooting. Windows 3.11 has fewer available in that it is not designed with Standard Mode. The trick is knowing where they are and how to use them.

LOGGED STARTUP
START MODE SWITCHES
Error Messages

Problem:
Windows Doesn't start:
This could be a defective commands in the CONFIG.SYS AUTOEXEC.BAT file. The command WIN should be at the end of the AUTOEXEC.BAT file.
If it fails, when you start the computer, press F8 just before you see "Starting MS-DOS" at boot. This will select Step-By-Step startup. Omit or include each item to find which is stopping Windows.
>Generally, the following lines won't need to be omitted:
DEVICE=C:\WINDOWS\HIMEM.SYS
DEVICE=C:\WINDOWS\EMM386.EXE
DOS=HIGH,UMB
BUFFERS=40
FILES=30
STACKS=9,256

If the CONFIG.SYS file doesn't create a problem, you may not be able to use Step-By-Step. Make a copy of the AUTOEXEC.BAT file as follows:
COPY C:\AUTOEXEC.BAT C:\AUTOEXEC.BA_
Now type:
EDIT C:\AUTOEXEC.BAT

Put REM at the beginning of any line which may be a command. You can ignore lines with:
PATH=
SET
ECHO

at the beginning. If the line has LH at the beginning, this is the LoadHi command. If you remove the LH, the device will be loaded in Conventional memory. Sometimes loading a program into high memory will create a problem. However, loading low can use up your memory needed by programs and Windows. But it's something to test.

If the problem is a line in the CONFIG.SYS file, edit that and put REM at the beginning of the problem line to disable that until you either remove it or find a fix for the problem.

LOGGED STARTUP

Logged Boot is a feature on both Windows 3.1 and Windows 95. It records each step Windows atempts to accomplish and what Windows succeeds in installing during the startup. If Windows fails to start you can see how many tasks it completed. Knowing where it stopped can indicate a bad command, bad file or a possible hardware conflict. This certainly can beat staring at "It is safe to shut off your computer" when you were trying to start it wondering why.

DOS
At DOS type
EDIT C:\bootlog.txt

WINDOWS
Open the Notepad.
Select File, Open, then type:
c:\bootlog.txt

If there is one there, look at the end to see if all was completed. The last few lines should be:
Init = Installable Drivers
InitDone = Installable Drivers
You can save this as c:\boot-01.txt as you will make a new one.
Exit Windows.
At the DOS Prompt type:
win /b
This will create a bootlog.txt when Windows starts.

WINDOWS START MODE SWITCHES

Another set of diagnosic tools are the switches for starting Windows in different modes. With Windows 3.1 you can start in DOS and add the switches. But DOS mode in Windows 95 doesn't load the drivers if you use F5 or select DOS mode from the F8 Boot menu. So if the device that is causing the problem is among the drivers loaded in a normal startup, the problem won't show up.

Windows 3.x has a group of startup switches. At the DOS prompt type:
win /?
to see a list of them. For easy use of them without modifying files to activate them copy the following into your AUTOEXEC.BAT file or another batch files you can call up with the AUTOEXEC.BAT file. I suggest creating a Multiple Boot Menu and creating a Diagnostic selection on it.

A Windows Diagnostic Startup Menu Batch file

echo off
:start
cls
echo Windows 95b Boot Mode Menu
echo Diagnostic Windows Startup. Choose one or more of the following:
echo MODE DESCRIPTION
echo F    Turns off 32-bit disk access.
echo     Equivalent to SYSTEM.INI file setting: 32BitDiskAccess=FALSE.
echo M   Enables Safe mode.
echo     This is automatically enabled during Safe start (function key F5).
echo N   Enables Safe mode networking.
echo     This is automatically enabled during Safe start (function key F6).
echo S   Specifies that Windows should not use ROM address space between
echo     F000:0000 and 1 MB for a break point.
echo     Equivalent to SYSTEM.INI file setting: SystemROMBreakPoint=FALSE.
echo V   Specifies that the ROM routine will handle interrupts from the hard
echo     disk controller. Equivalent to SYSTEM.INI file setting: VirtualHDIRQ=FALSE.
echo X   Excludes all of the adapter area from the range of memory that Windows
echo     scans to find unused space.
echo        Equivalent to SYSTEM.INI file setting: EMMExclude=A000-FFFF.
echo Q   Quit. Windows may start if BOOTGUI=1 is in MSDOS.SYS file.
echo   After you have made selections from above type D to start Windows in the mode
echo   selected.
echo   The selections you have made are: %m1% %m2% %m3% %m4% %m5% %m6%
echo D Starts Windows with selected settings. If none selected, starts normally.
choice /c:fmnsvxdwq /n /t:w,15 W starts Windows normally. If no key is press within 15 seconds Normal is run!
if errorlevel 9 goto end
if errorlevel 8 goto win
if errorlevel 7 goto diag
if errorlevel 6 goto setx
if errorlevel 5 goto setv
if errorlevel 4 goto sets
if errorlevel 3 goto setn
if errorlevel 2 goto setm
if errorlevel 1 goto setf

:setf
set m1=F
goto start

:setm
set m2=M
goto start

:setn
set m3=N
goto start

:sets
set m4=S
goto start

:setv
set m5=V
goto start

:setx
set m6=X
goto start

:diag
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo the following command line was executed:
echo c:\windows\win.com /D:%m1%%m2%%m3%%m4%%m5%%m6%
echo.
c:\windows\win.com /D:%m1%%m2%%m3%%m4%%m5%%m6%
goto end

:win
c:\windows\win.com
goto end

:end
set m1=
set m2=
set m3=
set m4=
set m5=
set m6=

You can copy this and paste it into a new file or into your AUTOEXEC.BAT. Make sure the headers (:names) don't already exist in the file you are pasting to. If they do you have to change one set or the other. The group of "set =" after ":end" should be at the end of the file you paste is in.

WINDOWS 3.x Error Messages

Windows Err Msg: Cannot Run This Program... A Microsoft Knowledgebase Article. You can't open a DOS window or DOS program while in Windows.

PoliTalk Technical Menu

Comment to PoliTalk

Updated June 21, 2001