H
     FMULTIFM CF  E                    WORKSTN
     F                                              KNUM        5
     F                                              KID    DSPL
     F                                        RECNO KSFILE SFL
     E                    DSP        10 21
     E                    MES        21 70
     IDSPDS       DS
     I                                        1  10 NAME
     I                                       11  20 DEV
     I                                       21  21 MODE
     IFDS        SDS
     I                                      244 253 FDSP
     I              'Has Joined'          C         CST1
     I              'is now known as '    C         CST2
     I              'Has Exited'          C         CST3
     C           C         DOWGT0
     C                     SETOF                     030612
     C                     SETON                     80
     C                     READ MULTIFM                  01
     C                     MOVELDSPL      @TMPDD 10
     C                     MOVE C         CC      20
     C           1         DO   CC        X       20
     C                     MOVELDSP,X     DSPDS
     C           @TMPDD    IFEQ DEV
      *
     C                     SELEC
     C           MODE      WHEQ 'O'
     C           *IN04     ANDEQ'1'
     C                     WRITEWIND1
     C                     MOVE 'I'       MODE
     C                     MOVELDSPDS     DSP,X
      *
     C           MODE      WHEQ 'O'
     C           *IN06     ANDEQ'1'
     C                     WRITEWIND2
     C                     MOVE 'A'       MODE
     C                     MOVELDSPDS     DSP,X
      *
     C           MODE      WHEQ 'O'
     C           *IN03     ANDEQ'1'
     C           DSPL      REL  MULTIFM
     C                     MOVE DSP,CC    DSP,X  21
     C                     SUB  1         C
     C                     MOVE *BLANKS   MESSAG
     C                     MOVELX'22'     MESSAG
     C                     CAT  NAME:1    MESSAG
     C                     CAT  CST3:1    MESSAG
     C                     EXSR ADDENT
     C                     EXSR BUILD
      *
     C           MODE      WHEQ 'O'
     C           *IN09     ANDEQ'1'
     C                     MOVE NAME      NEWNAM
     C                     WRITEWIND3
     C                     MOVE 'N'       MODE
     C                     MOVELDSPDS     DSP,X
      *
     C           MODE      WHEQ 'A'
     C           *IN12     ANDEQ*OFF
     C                     MOVE DSPDS     @TMP2  21
     C           DEVICE    ACQ  MULTIFM                55
     C           *IN55     IFEQ *OFF
     C                     MOVELDEVICE    NAME
     C                     MOVELDEVICE    DEV
     C                     MOVEL'O'       MODE
     C                     EXSR INZSFL
     C                     MOVE @TMP2     DSPDS
     C                     MOVEL'O'       MODE
     C                     MOVELDSPDS     DSP,X
     C                     EXSR BUILD
     C                     ELSE
     C                     WRITEWIND2
     C                     SETOF                     55
     C                     ENDIF
      *
     C           MODE      WHEQ 'A'
     C           *IN12     ANDEQ*ON
     C                     MOVEL'O'       MODE
     C                     MOVELDSPDS     DSP,X
     C                     EXSR BUILD
      *
     C           MODE      WHEQ 'N'
     C           *IN12     ANDEQ*OFF
     C                     MOVE 'O'       MODE
     C                     MOVE *BLANKS   MESSAG
     C                     MOVELX'22'     MESSAG
     C                     CAT  NAME:1    MESSAG
     C                     CAT  CST2:1    MESSAG
     C                     CAT  NEWNAM:1  MESSAG
     C                     EXSR ADDENT
     C                     MOVELNEWNAM    NAME
     C                     MOVELDSPDS     DSP,X
     C                     EXSR BUILD
      *
     C           MODE      WHEQ 'I'
     C                     MOVE *BLANKS   @TMP   70
     C                     CAT  NAME:0    @TMP
     C                     CAT  ':':1     @TMP
     C           @TMP      CAT  INPUT:1   MESSAG 70
     C  N12                EXSR ADDENT
     C                     MOVE 'O'       MODE
     C                     MOVELDSPDS     DSP,X
     C                     EXSR BUILD
      *
     C                     OTHER
     C                     EXSR BUILD
      *
     C                     ENDSL
      *
      *
     C                     ENDIF
     C                     ENDDO
     C                     ENDDO
     C                     SETON                     LR
      *
     C           BUILD     BEGSR
     C           1         DO   C         J       20
     C                     MOVELDSP,J     DSPDS
     C           MODE      IFEQ 'O'
     C                     MOVELDEV       DSPL
     C                     MOVEA'01'      *IN,80
     C                     WRITESFLCTL
     C           1         DO   20        K       20
     C                     Z-ADDK         RECNO   50
     C                     MOVELMES,K     LINE
     C                     WRITESFL
     C                     ENDDO
     C                     MOVEA'10'      *IN,80
     C                     WRITESFLCTL
     C                     ENDIF
     C                     ENDDO
     C                     ENDSR
      *
     C           *INZSR    BEGSR
     C                     MOVELFDSP      NAME
     C                     MOVELFDSP      DEV
     C                     MOVEL'O'       MODE
     C                     EXSR INZSFL
     C                     ENDSR
      *
     C           INZSFL    BEGSR
     C                     ADD  1         C       20
     C                     MOVE DSPDS     DSP,C
     C                     MOVE DEV       DSPL
     C                     SETOF                     80
     C                     WRITESFLCTL
     C                     SETON                     80
     C                     WRITESFLFOT
     C                     MOVE *BLANKS   MESSAG
     C                     MOVELX'22'     MESSAG
     C                     CAT  NAME:0    MESSAG
     C                     CAT  CST1:1    MESSAG
     C                     EXSR ADDENT
     C                     ENDSR
      *
     C           ADDENT    BEGSR
      * SHIFT THEM ALL UP
     C           1         DO   18        Y1      20
     C           Y1        ADD  1         Y2      20
     C                     MOVE MES,Y2    MES,Y1
     C                     ENDDO
     C* ADD ENTRY TO BOTTOM
     C                     MOVELMESSAG    MES,19
     C                     ENDSR