report zvv_spool no standard page heading.

parameter spool_id like tsp01sys-rqident.

data: w_info like tsp01sys,
      w_data like rspo_ds occurs 0 with header line,
      w_pages like rspo_index occurs 0 with header line,
      line_length type rststype-linelength.

call function 'RSPO_ISELECT_TSP01'
     exporting
          rfcsystem  = sy-sysid
          rqident    = spool_id
     importing
          tsp01_elem = w_info
     exceptions
          error      = 1
          others     = 2.
if sy-subrc <> 0.
  message id sy-msgid type sy-msgty number sy-msgno
          with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
endif.


call function 'RSPO_IRETURN_RAW_DATA'
     exporting
          rq          = w_info
     tables
          line_buffer = w_data
          page_index  = w_pages
     exceptions
          error       = 1
          others      = 2.
if sy-subrc <> 0.
  message id sy-msgid type sy-msgty number sy-msgno
          with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
endif.

if w_info-rqdoctype = 'LIST'.
  call function 'RSPO_SPOOLDATA_WRITE_INIT'.
  loop at w_data.
    if w_data-precol = 'P' and w_data-data_line(1) = ' '.
      new-page.
      continue.
    endif.
*   compute line length
    if w_data-data_len is initial.
      line_length = strlen( w_data-data_line ) - 1.
    else.
      line_length = w_data-data_len - 1.
    endif.
    if line_length > 0.
      call function 'RSPO_SPOOLDATA_WRITE'
           exporting
                spool_data     = w_data-data_line
                data_length    = line_length
           exceptions
                data_too_short = 1
                others         = 2.
      if sy-subrc <> 0.
        message id sy-msgid type sy-msgty number sy-msgno
                with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
      endif.
    else.
      skip.               " empty line
    endif.
  endloop.
elseif w_info-rqdoctype = 'OTF'.
endif.