     A                                      DSPSIZ(24 80 *DS3)
     A                                      MSGLOC(24)
     A                                      CA03
     A                                      CA05
     A                                      CA06
     A                                      CA07
     A                                      CA08
     A                                      CA09
     A                                      CA10
     A                                      CA12
     A                                      CA01
     A                                      CA02
     A                                      CA04
     A                                      CA11
     A                                      HOME
     A                                      HELP
     A                                      ROLLUP
     A                                      ROLLDOWN
     A*============================================================
     A          R V2BK
     A                                      TEXT('Background fmt')
     A                                  1  2'Author: Victor Voilevitch'
     A                                      COLOR(WHT)
     A                                  2  2'1998-99'
     A                                      COLOR(WHT)
     A                                  1 40'Super AS/400 tetris'
     A                                      COLOR(WHT)
     A                                  9 69'F6-Left'
     A                                      COLOR(WHT)
     A                                 10 69'F5-Left max'
     A                                      COLOR(WHT)
     A                                 11 69'F7-Right'
     A                                      COLOR(WHT)
     A                                 12 69'F8-Right max'
     A                                      COLOR(WHT)
     A                                 14 69'F9-Rotate'
     A                                      COLOR(WHT)
     A                                 16 69'Enter-Drop'
     A                                      COLOR(WHT)
     A                                 18 69'F10-Next'
     A                                      COLOR(WHT)
     A                                 20 69'F12-Reset'
     A                                      COLOR(WHT)
     A                                 21 69'F3-Exit'
     A                                      COLOR(WHT)
     A*============================================================
     A          R V2NX                      USRRSTDSP
     A                                      PUTOVR
     A                                      WINDOW(1 68 6  9)
     A                                      WDWBORDER((*CHAR '        '))
     A                                      TEXT('Next fmt')
     A            $$NX1          8A  O  2  1
     A            $$NX2          8A  O  3  1
     A            $$NX3          8A  O  4  1
     A            $$NX4          8A  O  5  1
     A*============================================================
     A          R V200                      USRRSTDSP
     A                                      TEXT('Glass fmt')
     A  50                                  INVITE
     A                                      PUTOVR
     A                                      WINDOW(2 33 21 30)
     A                                      WDWBORDER((*CHAR '| ||||||'))
     A            $$OALL        21A  B  1  5OVRDTA
     A                                      COLOR(WHT)
     A                                  2  5'SCORE:'
     A                                      COLOR(BLU)
     A            $$OSCR         5Y 0O  2 12
     A  60                                  OVRDTA
     A                                      COLOR(BLU)
     A                                      EDTCDE(3)
     A            $$O01         30A  O  3  1
     A  61                                  OVRDTA
     A            $$O02         30A  O  4  1
     A  62                                  OVRDTA
     A            $$O03         30A  O  5  1
     A  63                                  OVRDTA
     A            $$O04         30A  O  6  1
     A  64                                  OVRDTA
     A            $$O05         30A  O  7  1
     A  65                                  OVRDTA
     A            $$O06         30A  O  8  1
     A  66                                  OVRDTA
     A            $$O07         30A  O  9  1
     A  67                                  OVRDTA
     A            $$O08         30A  O 10  1
     A  68                                  OVRDTA
     A            $$O09         30A  O 11  1
     A  69                                  OVRDTA
     A            $$O10         30A  O 12  1
     A  70                                  OVRDTA
     A            $$O11         30A  O 13  1
     A  71                                  OVRDTA
     A            $$O12         30A  O 14  1
     A  72                                  OVRDTA
     A            $$O13         30A  O 15  1
     A  73                                  OVRDTA
     A            $$O14         30A  O 16  1
     A  74                                  OVRDTA
     A            $$O15         30A  O 17  1
     A  75                                  OVRDTA
     A            $$O16         30A  O 18  1
     A  76                                  OVRDTA
     A            $$O17         30A  O 19  1
     A  77                                  OVRDTA
     A            $$O18         30A  O 20  1
     A  78                                  OVRDTA
     A*============================================================
     A          R V2IN                      USRRSTDSP
     A                                      TEXT('Info fmt')
     A                                      PUTOVR
     A                                      WINDOW(3 2 20 26)
     A                                      WDWBORDER((*CHAR '        '))
     A                                  4  1'Record:'
     A                                      COLOR(BLU)
     A            $$RECR         5Y 0O  4  9
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A                                      EDTCDE(3)
     A                                  5  3'From:'
     A                                      COLOR(BLU)
     A            $$FROM        21A  O  6  1
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A                                  7  3'Owned by:'
     A                                      COLOR(BLU)
     A            $$NAME        20A  O  8  1
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A                                 10  3'Top ten:'
     A                                      COLOR(BLU)
     A            $$RE02         5Y 0O 11  1
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A                                      EDTCDE(3)
     A            $$NA02        20A  O 11  7
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A            $$RE03         5Y 0O 12  1
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A                                      EDTCDE(3)
     A            $$NA03        20A  O 12  7
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A            $$RE04         5Y 0O 13  1
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A                                      EDTCDE(3)
     A            $$NA04        20A  O 13  7
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A            $$RE05         5Y 0O 14  1
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A                                      EDTCDE(3)
     A            $$NA05        20A  O 14  7
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A            $$RE06         5Y 0O 15  1
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A                                      EDTCDE(3)
     A            $$NA06        20A  O 15  7
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A            $$RE07         5Y 0O 16  1
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A                                      EDTCDE(3)
     A            $$NA07        20A  O 16  7
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A            $$RE08         5Y 0O 17  1
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A                                      EDTCDE(3)
     A            $$NA08        20A  O 17  7
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A            $$RE09         5Y 0O 18  1
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A                                      EDTCDE(3)
     A            $$NA09        20A  O 18  7
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A            $$RE10         5Y 0O 19  1
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A                                      EDTCDE(3)
     A            $$NA10        20A  O 19  7
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A*============================================================
     A          R VBYE                      USRRSTDSP
     A                                      TEXT('Bye fmt')
     A                                      OVERLAY
     A                                      WINDOW(12 37 3 10)
     A                                  2  2'Good Bye!'
     A                                      COLOR(RED)
     A*============================================================
     A          R VREC                      USRRSTDSP
     A                                      TEXT('Record fmt')
     A                                      OVERLAY
     A                                      WINDOW(12 10 5 60)
     A  83                              1  9'Your result is greather than previ-
     A                                      ous record!'
     A                                      COLOR(BLU)
     A N83                              1 21'You are in Top Ten!'
     A                                      COLOR(BLU)
     A                                  2 13'Please, enter your name for histor-
     A                                      y:'
     A                                      COLOR(BLU)
     A            $$INAM        20   I  4 21CHECK(LC)
     A*============================================================
     A          R VHLP
     A                                      WINDOW(7 20 7 40)
     A                                      TEXT('Help fmt')
     A                                      OVERLAY
     A                                  5  2'http://www.geocities.com/SiliconVa-
     A                                      lley/'
     A                                  6 16'Haven/6243'
     A                                  1 13'Victor Voilevitch'
     A                                  3 10'tel. 0-375-17-215-76-59'
     A                                  4 12'victorav15@usa.net'
