A                                      DSPSIZ(24 80 *DS3)
     A                                      MSGLOC(24)
     A                                      CA03
     A                                      CA05
     A                                      CA06
     A                                      CA07
     A                                      CA08
     A                                      CA09
     A                                      CA12
     A*============================================================
     A          R V2BK
     A                                      TEXT('Background fmt')
     A                                  1 34'Super AS/400 tetris'
     A                                      COLOR(WHT)
     A                                  9 67'F6-Left'
     A                                      COLOR(WHT)
     A                                 10 67'F5-Left max'
     A                                      COLOR(WHT)
     A                                 11 67'F7-Right'
     A                                      COLOR(WHT)
     A                                 12 67'F8-Right max'
     A                                      COLOR(WHT)
     A                                 14 67'F9-Rotate'
     A                                      COLOR(WHT)
     A                                 16 67'Enter-Drop'
     A                                      COLOR(WHT)
     A                                 18 67'F12-Reset'
     A                                      COLOR(WHT)
     A                                 19 67'F3-Exit'
     A                                      COLOR(WHT)
     A*============================================================
     A          R V200                      USRRSTDSP
     A                                      TEXT('Glass fmt')
     A  50                                  INVITE
     A                                      PUTOVR
     A                                      WINDOW(2 27 21 30)
     A                                      WDWBORDER((*CHAR '³ ³³³³³³'))
     A            $$OALL        21A  B  1  5OVRDTA
     A                                      COLOR(WHT)
     A                                  2  5'SCORE:'
     A                                      COLOR(BLU)
     A            $$OSCR         5Y 0O  2 12
     A  60                                  OVRDTA
     A                                      COLOR(BLU)
     A                                      EDTCDE(3)
     A            $$O01         30A  O  3  1
     A  61                                  OVRDTA
     A            $$O02         30A  O  4  1
     A  62                                  OVRDTA
     A            $$O03         30A  O  5  1
     A  63                                  OVRDTA
     A            $$O04         30A  O  6  1
     A  64                                  OVRDTA
     A            $$O05         30A  O  7  1
     A  65                                  OVRDTA
     A            $$O06         30A  O  8  1
     A  66                                  OVRDTA
     A            $$O07         30A  O  9  1
     A  67                                  OVRDTA
     A            $$O08         30A  O 10  1
     A  68                                  OVRDTA
     A            $$O09         30A  O 11  1
     A  69                                  OVRDTA
     A            $$O10         30A  O 12  1
     A  70                                  OVRDTA
     A            $$O11         30A  O 13  1
     A  71                                  OVRDTA
     A            $$O12         30A  O 14  1
     A  72                                  OVRDTA
     A            $$O13         30A  O 15  1
     A  73                                  OVRDTA
     A            $$O14         30A  O 16  1
     A  74                                  OVRDTA
     A            $$O15         30A  O 17  1
     A  75                                  OVRDTA
     A            $$O16         30A  O 18  1
     A  76                                  OVRDTA
     A            $$O17         30A  O 19  1
     A  77                                  OVRDTA
     A            $$O18         30A  O 20  1
     A  78                                  OVRDTA
     A*============================================================
     A          R V2IN                      USRRSTDSP
     A                                      TEXT('Info fmt')
     A                                      PUTOVR
     A                                      WINDOW(1 2 20 23)
     A                                      WDWBORDER((*CHAR '        '))
     A                                  6  1'Record:'
     A                                      COLOR(BLU)
     A            $$RECR         5Y 0O  6  9
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A                                      EDTCDE(3)
     A                                  7  3'From:'
     A                                      COLOR(BLU)
     A            $$FROM        21A  O  8  1
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A                                  9  3'Owned by:'
     A                                      COLOR(BLU)
     A            $$NAME        20A  O 10  1
     A  59                                  OVRDTA
     A                                      COLOR(BLU)
     A*============================================================
     A          R VBYE                      USRRSTDSP
     A                                      TEXT('Bye fmt')
     A                                      OVERLAY
     A                                      WINDOW(12 37 3 10)
     A                                  2  2'Good Bye!'
     A                                      COLOR(RED)
     A*============================================================
     A          R VREC                      USRRSTDSP
     A                                      TEXT('Record fmt')
     A                                      OVERLAY
     A                                      WINDOW(12 10 5 60)
     A                                  1  9'Your result is greather than previ-
     A                                      ous record!'
     A                                      COLOR(BLU)
     A                                  2 13'Please, enter your name for histor-
     A                                      y:'
     A                                      COLOR(BLU)
     A            $$INAM        20   I  4 21CHECK(LC)
     A*============================================================
     A          R VLAT                      USRRSTDSP
     A                                      WINDOW(14 15 3 50)
     A                                      TEXT('Record fmt')
     A                                      OVERLAY
     A                                  2 16'Sorry, You are late..'
     A                                      COLOR(BLU)
     A*============================================================