1 REM THIS PROGRAM APPEARS AT PAGE 130 OF THE ITALIAN VERSION OF
2 REM "PROGRAMMING IN BASIC" 1ST EDITION, BY BYRON S. GOTTFRIED 
3 REM WARNING: dib CANNOT ACCEPT VOID INPUTS, LIKE AN ENVIRONMENT
4 REM WITH STRINGS, WHICH CAN ACCEPT VOID STRINGS IN INPUT
5 REM SO, WHEN ASKED TO PRESS ENTER, TYPE ANY FAKE NUMBER BEFORE
9 REM		SIMULATON OF A GAME OF CRAPS
10 RANDOMIZE
20 PRINT "0 = END; 1 = PRINT RULES; 2 = PLAY >";
30 INPUT N
40 ON (N+1) GO TO 600,300,90
50 GO TO 600	' END
60 REM
70 REM
80 REM
90 LET K=FNK(6)
100 ON (K-1) GO TO 110,110,150,150,150,130,150,150,150,130,110
110 PRINT K;"- - YOU LOSE ON THE FIRST THROW"
120 GO TO 250
130 PRINT K;"- - YOU WIN ON THE FIRST THROW"
140 GO TO 250
150 LET K1=K
160 PRINT K;"- - THROW THE DICE AGAIN (PRESS ENTER)"
170 INPUT Y
180 LET K=FNK(6)
190 IF K=K1 THEN 220
200 IF K=7 THEN 240
210 GO TO 160
220 PRINT K;"- - YOU WIN BY MATCHING YOUR FIRST SCORE"
230 GO TO 250
240 PRINT K;"- -YOU LOSE BY FAILING TO MATCH YOUR FIRST SCORE"
250 PRINT
260 GO TO 20	' PLAY ANOTHER GAME
270 REM
300 REM 	PRINT RULES OF CRAPS
320 PRINT,"RULES OF CRAPS"
330 PRINT
340 PRINT "TO WIN: OBTAIN A 7 OR 11 ON THE FIRST THROW"
350 PRINT "    OR: OBTAIN A 4,5,6,8,9 OR 10 ON THE FIRST THROW"
360 PRINT,"AND MATCH YOUR ORIGINAL SCORE BEFORE THROWING A 7"
370 PRINT
380 PRINT "TO LOSE: OBTAIN A 2,3,OR 12 ON THE FIRST THROW"
390 PRINT "     OR: OBTAIN A 4,5,6,8,9 OR 10 ON THE FIRST THROW"
400 PRINT,"AND THROW A 7 BEFORE MATCHING YOUR ORIGINAL SCORE"
410 PRINT
420 GO TO 20
500 DEF FNK(X)=2+INT(X*RND)+INT(X*RND)
600 END
