// teleportboss.txt
// Uses the combat behavior of hunter.txt, the monster will hunt party
// actively.  When slain, monster will "teleport away" to another location,
// revealing another "phase" of the boss.  Allows objects to be cleared,
// assuring that boss will not land on an already-existing character.
//
//     By Terror's Martyr
//     (terrorsmartyr@wi.rr.com)
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - Hidden Group to activate
//   Cell 5,6 - x,y location of new boss
//   Cell 7 - Treatment of on-space objects
//     0 - Don't Destroy
//     1 - Destroy without boom
//     2 - Destroy with boom

begincreaturescript;

variables;

short i,target;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	if (get_attitude(ME) >= 10)
		alert_char(ME);
	break;

beginstate DEAD_STATE;

	erase_char(ME);
	put_boom_on_space(my_loc_x(),my_loc_y(),2,0);
	force_instant_terrain_redraw();
	run_animation_sound(10);
	if(get_memory_cell(7) == 1){
		set_terrain(get_memory_cell(5),get_memory_cell(6),0);
		force_instant_terrain_redraw();
	}
	if(get_memory_cell(7) == 2){
set_terrain(get_memory_cell(5),get_memory_cell(6),0);
put_boom_on_space(get_memory_cell(5),get_memory_cell(6),1,0);
force_instant_terrain_redraw();
run_animation_sound(5);
	}
	activate_hidden_group(get_memory_cell(4));
	put_boom_on_space(get_memory_cell(5),get_memory_cell(6),2,0);
	force_instant_terrain_redraw();
	run_animation_sound(10);
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	if (get_attitude(ME) >= 10)
		alert_char(ME);

	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if (my_dist_from_start() >= 6) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (get_attitude(ME) >= 10)
		alert_char(ME);

	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;