// malicious.txt
// Creature picks out the creature with the least hit points and attempts
// to attack it.  Works best with ranged units who don't have to move to
// reach their desired targets.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target,charcheck,minchar,minhp;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Seek out the most vulnerable enemy out there.
	charcheck = 0;
	minhp = 0;
	minchar = 121;
	while(charcheck <= 119){
		if(char_ok(charcheck) == TRUE){
			if(can_see_char(charcheck) == TRUE){
				if((get_attitude(my_number()) != get_attitude(charcheck)) && (get_attitude(charcheck) != 4)){
					if(minhp == 0){
						minhp = get_health(charcheck);
						minchar = charcheck;
					}
					if(get_health(charcheck) < minhp){
						minhp = get_health(charcheck);
						minchar = charcheck;
					}
					if(get_health(charcheck) == minhp){
						if(get_ran(1,0,1) == 0){
							minhp = get_health(charcheck);
							minchar = charcheck;
						}
					}
				}
			}
		}

		charcheck = (charcheck + 1);
	}
	if(minchar != 121){
		set_target(ME,minchar);
		set_state(3);
	}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;