// commoner.txt
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.  Talks to the party only
// using default responses based on his/her role.
//
//   by Terror's Martyr (terrorsmartyr@wi.rr.com)
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Default response given.
//     0 - Guard
//     1 - Townsman
//     2 - Townswoman
//     3 - Accolyte
//     4 - Child
//     5 - Soldier Male
//     6 - Soldier Female
//     7 - Generic Male
//     8 - Generic Female
//     9 - Rich Male
//    10 - Rich Female
//    11 - Beggar
//    12 - Generic It

begincreaturescript;

variables;

short i,target;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: The guard ignores you and continues patrolling the city.");
		}
	if (get_memory_cell(3) == 1) {
		print_str("Talking: The townsman ignores you and goes about his business.");
		}
	if (get_memory_cell(3) == 2) {
		print_str("Talking: The townswoman ignores you and goes about her business.");
		}
	if (get_memory_cell(3) == 3) {
		print_str("Talking: The acolyte nods curtly to you but doesn't respond.");
		}
	if (get_memory_cell(3) == 4) {
		print_str("Talking: The child leaves you alone.  Thankfully.");
		}
	if (get_memory_cell(3) == 5) {
		print_str("Talking: The soldier holds his sword and ignores you.");
		}
	if (get_memory_cell(3) == 6) {
		print_str("Talking: The soldier holds her sword and ignores you.");
		}
	if (get_memory_cell(3) == 7) {
		print_str("Talking: He doesn't respond.");
		}
	if (get_memory_cell(3) == 8) {
		print_str("Talking: She doesn't respond.");
		}
	if (get_memory_cell(3) == 9) {
		print_str("Talking: The aristocrat stares at you and scowls.");
		print_str("Clearly, you are beneath him.");
		}
	if (get_memory_cell(3) == 10) {
		print_str("Talking: The aristocrat stares at you and scowls.");
		print_str("Clearly, you are beneath her.");
		}
	if (get_memory_cell(3) == 11) {
		print_str("Talking: The lowly beggar shuffles away from you as you approach.");
		}
	if (get_memory_cell(3) > 11) {
		print_str("Talking: It doesn't respond.");
		}
break;