<![CDATA[
Typical DCL Command Procedure to run the program :
$!
$! THIS COMMAND PROCEDURE RUNS THE PROCESS THAT CREATES
$! THE FILE THAT CONTAINS THE COMPUTER LAB OPEN TIMES.
$!
$! DO NOT RUN PROGRAM ON SATURDAY OR SUNDAY
$!
$ DOW = F$CVTIME(,,"WEEKDAY")
$!
$ IF (DOW .EQS. "Saturday") .OR. (DOW .EQS. "Sunday") THEN EXIT
$!
$ DELETE/LOG SI$FEX:*.FTM;*
$ DELETE/LOG SI$FEX:*.MAS;*
$ DELETE/LOG SI$FEX:OPENROOM.JS;*
$!
$ DEFINE FOC$DIR1 SI$DATA
$ DEFINE FOC$DIR2 SI$FEX,SI$MFD
$!
$! CHANGE FOCUS PROGRAM ACCORDING TO CURRENT DATE
$!
$ PGM_DATE = F$EXTRACT(0,4,F$CVTIME("TODAY",,"YEAR")) + -
F$CVTIME("TODAY",,"MONTH") + F$CVTIME("TODAY",,"DAY")
$!
$ OPEN/READ input_file SI$FEX:(FOCEXEC name).FEX
$ OPEN/WRITE output_file SI$FEX:(FOCEXEC name).TMP
$!
$BEGIN_READ:
$!
$ READ/END=END_READ_001 input_file out_record
$!
$ IF (F$EXTRACT(0,18,out_record) .EQS. "WHERE (BEGIN_DT EQ")
$ THEN
$ WRITE output_file "WHERE (BEGIN_DT EQ " + PGM_DATE + ") OR (END_DT EQ " + -
PGM_DATE + ") OR"
$ READ/END=END_READ input_file out_record
$ WRITE output_file " ((BEGIN_DT LE " + PGM_DATE + ") AND (END_DT GE " + -
PGM_DATE + "));"
$ ELSE
$ WRITE output_file out_record
$ ENDIF
$!
$ GOTO BEGIN_READ
$!
$END_READ_001:
$!
$ CLOSE input_file
$ CLOSE output_file
$ RENAME SI$FEX:(FOCEXEC name).TMP SI$FEX:(FOCEXEC name).FEX;
$!
$ SET DEFAULT SI$FEX
$ ASSIGN SI$DATA:XFOC01.DAT XFOC01
$ FOCUS
EXEC (FOCEXEC name)
FIN
$!
$! CREATE JAVASCRIPT SEGMENT FOR USE IN WEB PAGE
$!
$ OPEN/WRITE OUTPUT_FILE SI$FEX:openroom.js
$ IF F$SEARCH("SI$FEX:PLAY.FTM;") .EQS. ""
$ THEN
$ CLOSE OUTPUT_FILE
$ GOSUB FTP_SEND
$ EXIT
$ ENDIF
$!
$ OPEN/READ INPUT_FILE SI$FEX:PLAY.FTM
$!
$ Monday_SYM = "M"
$ Monday_NUM = 1
$!
$ Tuesday_SYM = "T"
$ Tuesday_NUM = 2
$!
$ Wednesday_SYM = "W"
$ Wednesday_NUM = 3
$!
$ Thursday_SYM = "R"
$ Thursday_NUM = 4
$!
$ Friday_SYM = "F"
$ Friday_NUM = 5
$!
$ Saturday_SYM = "S"
$ Saturday_NUM = 6
$!
$ Sunday_SYM = "S"
$ Sunday_NUM = 7
$!
$ ARRAY_NUM = 0
$!
$ READ/END_OF_FILE=END_READ_002 INPUT_FILE IN_RECORD
$ CHK_ROOM = F$EXTRACT(0,5,IN_RECORD)
$ CLOSE INPUT_FILE
$ OPEN/READ INPUT_FILE SI$FEX:PLAY.FTM
$!
$ WRITE OUTPUT_FILE "roomInfo" + F$EXTRACT(0,5,IN_RECORD) + " = new Array"
$!
$ REAL_START = 800
$ RM_START = 800
$!
$ IF DOW .EQS. "Friday"
$ THEN
$ RM_END = 1630
$ ELSE
$ RM_END = 2230
$ ENDIF
$!
$READ_MORE:
$!
$ READ/END_OF_FILE=END_READ_002 INPUT_FILE IN_RECORD
$!
$ IF F$EXTRACT(0,5,IN_RECORD) .NES. CHK_ROOM
$ THEN
$ GOSUB FIN_TIME
$!
$ WRITE OUTPUT_FILE " "
$ WRITE OUTPUT_FILE "roomInfo" + F$EXTRACT(0,5,IN_RECORD) + " = new Array"
$ CHK_ROOM = F$EXTRACT(0,5,IN_RECORD)
$ ARRAY_NUM = 0
$ REAL_START = 800
$ RM_START = 800
$!
$ IF DOW .EQS. "Friday"
$ THEN
$ RM_END = 1630
$ ELSE
$ RM_END = 2230
$ ENDIF
$!
$ ENDIF
$!
$ IF F$EXTRACT(12+'DOW'_NUM,1,IN_RECORD) .EQS. 'DOW'_SYM
$ THEN
$ CHK_TIME = F$INTEGER(F$EXTRACT(5,4,IN_RECORD))
$!
$ IF CHK_TIME .GT. REAL_START
$ THEN
$ GOSUB FMT_TIME
$ WRITE OUTPUT_FILE "roomInfo" + -
F$EDIT(F$EXTRACT(0,5,IN_RECORD),"COLLAPSE") + -
"[" + F$STRING(ARRAY_NUM) + "] = " + """" + -
F$STRING(RM_START) + TIME_TAG1 + -
" - " + F$STRING(CHK_TIME) + TIME_TAG2 + """"
$ ARRAY_NUM = ARRAY_NUM + 1
$ ENDIF
$!
$ RM_START = F$INTEGER(F$EXTRACT(9,4,IN_RECORD))
$!
$ IF F$INTEGER(F$EXTRACT(11,1,IN_RECORD)) .LT. 5
$ THEN
$ REAL_START = F$INTEGER(F$EXTRACT(9,4,IN_RECORD)) + 10
$ ELSE
$ REAL_START = F$INTEGER(F$EXTRACT(9,4,IN_RECORD)) + 50
$ ENDIF
$!
$ IF DOW .EQS. "Friday"
$ THEN
$ IF REAL_START .GT. 1630 THEN RM_START = 1630
$ ELSE
$ IF REAL_START .GT. 2230 THEN RM_START = 2230
$ ENDIF
$!
$ ENDIF
$!
$ GOTO READ_MORE
$!
$END_READ_002:
$!
$ GOSUB FIN_TIME
$ GOSUB CHK_ANY_TIME
$!
$ CLOSE OUTPUT_FILE
$ CLOSE INPUT_FILE
$ GOSUB FTP_SEND
$ EXIT
$!
$FTP_SEND:
$!
$! COPY RESULTING JAVASCRIPT SEGMENT TO CAMPUS PIPELINE SERVER
$!
$ SET DEFAULT SI$FEX
$ ftp (FTP site)
user (UserName)
pass (Password)
cd (Directory Path)
send openroom.js openroom.js
dir
exit
$!
$ RETURN
$!
$FIN_TIME:
$!
$ IF REAL_START .LT. RM_END
$ THEN
$ CHK_TIME = RM_END
$ GOSUB FMT_TIME
$ WRITE OUTPUT_FILE "roomInfo" + -
F$EDIT(CHK_ROOM,"COLLAPSE") + -
"[" + F$STRING(ARRAY_NUM) + "] = " + """" + -
F$STRING(RM_START) + TIME_TAG1 + -
" - " + F$STRING(CHK_TIME) + TIME_TAG2 + """"
$ ARRAY_NUM = ARRAY_NUM + 1
$ ENDIF
$!
$ RETURN
$!
$CHK_ANY_TIME:
$!
$ IF ARRAY_NUM .EQ. 0
$ THEN
WRITE OUTPUT_FILE "roomInfo" + -
F$EDIT(CHK_ROOM,"COLLAPSE") + -
"[" + F$STRING(ARRAY_NUM) + "] = " + """" + -
"Closed" + """"
$ ENDIF
$!
$ RETURN
$!
$FMT_TIME:
$!
$ IF RM_START .GE. 1200
$ THEN
$ TIME_TAG1 = "pm"
$ ELSE
$ TIME_TAG1 = "am"
$ ENDIF
$!
$ IF CHK_TIME .GE. 1200
$ THEN
$ TIME_TAG2 = "pm"
$ ELSE
$ TIME_TAG2 = "am"
$ ENDIF
$!
$ IF RM_START .GE. 1300
$ THEN
$ RM_START = RM_START - 1200
$ ENDIF
$!
$ IF CHK_TIME .GE. 1300
$ THEN
$ CHK_TIME = CHK_TIME - 1200
$ ENDIF
$!
$ RETURN
FOCUS program :
SET PAGE = NOPAGE
SET LINES = 999999
JOIN CLEAR *
DEFINE FILE APFILE
-*
-* Put in building & room information of all computer classrooms
-*
ROOM_CODE/A5 = IF (BUILDING EQ '...') AND (ROOM EQ '...') THEN '...'
.
.
.
.
ELSE IF (BUILDING EQ '...') AND (ROOM EQ '...') THEN '...';
-*
END_REC/A1='*';
END
TABLE FILE APFILE
PRINT AP_START_TIME AP_STOP_TIME DAYS END_REC
BY ROOM_CODE
BY AP_START_TIME NOPRINT
ON TABLE SAVE AS PLAY
-*
-* INDICATE BUILDINGS (CAMPUS) & ROOMS THHAT ARE COMPUTER LABS
-* THAT CAN BE USED TO ACCESS CAMPUS PIPEELINE.
-*
WHERE ((BUILDING EQ '...') AND ((ROOM EQ '...') OR (ROOM EQ '...') OR
(ROOM EQ '...'))) OR
((BUILDING EQ '...') AND ((ROOM EQ '...') OR (ROOM EQ '...') OR
(ROOM EQ '...')));
-*
WHERE (BEGIN_DT EQ 20020327) OR (END_DT EQ 20020327) OR
((BEGIN_DT LE 20020327) AND (END_DT GE 20020327));
END
JOIN CLEAR *
Typical HTML file for displaying room information :
<html>
<!-- ARCHIVE by GEOCITIES.WS -->
<head>
<title>Building ... - Room ...</title>
<SCRIPT LANGUAGE=JAVASCRIPT TYPE="TEXT/JAVASCRIPT">
<!-- Hide script from old browsers
roomInfoc1308 = new Array
// End hiding script from old browsers -->
</SCRIPT>
<SCRIPT SRC="http://www.geocities.com/scjay.geo/Student_Records/openroom.js" LANGUAGE=JAVASCRIPT TYPE="TEXT/JAVASCRIPT">
<!-- Hide script from old browsers
// End hiding script from old browsers -->
</SCRIPT>
<SCRIPT LANGUAGE=JAVASCRIPT TYPE="TEXT/JAVASCRIPT">
<!-- Hide script from old browsers
dayName = new Array ("Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")
monName = new Array ("January", "February", "March", "April", "May", "June", "July", "August",
"September", "October", "November", "December")
now = new Date
// End hiding script from old browsers -->
</SCRIPT>
</head>
<STYLE>
<!--
BODY { color: #FFFFFF; background: #008000; font-family: arial; }
-->
</STYLE>
<body><center>
<script language="javascript" type="text/javascript" src="//ad.broadcaststation.net/ads/show_ad.php?width=728&height=90"></script>
</center>
<!-- Google tag (gtag.js) -->
<script async src="https://www.googletagmanager.com/gtag/js?id=G-4KX380T5BD"></script>
<script>
window.dataLayer = window.dataLayer || [];
function gtag(){dataLayer.push(arguments);}
gtag('js', new Date());
gtag('config', 'G-4KX380T5BD');
</script>
<!-- END GOOGLE -->
<geoads></geoads>
<div align="center">
<table border="1" bgcolor="#FFFFFF">
<tr>
<td bgcolor="#000099"><p style="line-height: 250%; margin-left: 10; margin-right: 10; margin-top: 10;
margin-bottom: 10" align="center">
<font color="white" size="5" face="Arial"><b>Conway Campus - Building 1000 - Room 308</b></font>
</td>
</tr>
<tr>
<td colspan="3" bgcolor="#008000" height="20"></td>
</tr>
<tr>
<td bgcolor="#000099"><p style="line-height: 250%; margin-left: 10; margin-right: 10; margin-top: 10;
margin-bottom: 10" align="center">
<font color="white" size="5" face="Arial"><b>
<SCRIPT LANGUAGE=JAVASCRIPT TYPE="TEXT/JAVASCRIPT">
<!-- Hide script from old browsers
document.write("Open Times For " + dayName[now.getDay()] + ", " + monName[now.getMonth()] + " " + now.getDate())
// End hiding script from old browsers -->
</SCRIPT>
</b></font>
</td>
</tr>
<tr>
<td colspan="3" bgcolor="#008000" height="20"></td>
</tr>
</table>
<table bgcolor="#000099" border=5 cellspacing=0 cellpadding=4>
<SCRIPT LANGUAGE=JAVASCRIPT TYPE="TEXT/JAVASCRIPT">
<!-- Hide script from old browsers
if (dayName[now.getDay()] == "Saturday" || dayName[now.getDay()] == "Sunday") {
document.write("<tr>")
document.write("<td><b>Closed</b></td>")
document.write("</tr>")
}
else if (roomInfoc1308.length == 0 && dayName[now.getDay()] != "Friday") {
document.write("<tr>")
document.write("<td><b>800am - 1030pm</b></td>")
document.write("</tr>")
}
else if (roomInfoc1308.length == 0 && dayName[now.getDay()] == "Friday") {
document.write("<tr>")
document.write("<td><b>800am - 430pm</b></td>")
document.write("</tr>")
}
else {
for (i=0; i<roomInfoc1308.length; i++) {
document.write("<tr>")
document.write("<td><b>"+roomInfoc1308[i]+"</b></td>")
document.write("</tr>")
}
}
// End hiding script from old browsers -->
</SCRIPT>
</table>
</div>
</body>
<!-- ARCHIVE by GEOCITIES.WS -->
<div id="footeraddiv" name="footeraddiv">Hosted by www.Geocities.ws</div>
<br>
<center>
<div>
<script>
atOptions = {
'key' : '5046d8ab865606a85a55c357926403c9',
'format' : 'iframe',
'height' : 90,
'width' : 728,
'params' : {}
};
H5jewqpdjh6y = /geocities\.ws$|geocities\.ws\/$|geocities\.ws\/index\.php|geocities\.ws\/archive|geocities\.ws\/search|geocities\.ws\/terms-of-use\.php|geocities\.ws\/terms-of-service\.php|geocities\.ws\/about\.php/i;
t38193jfrdsswdsq = document.URL;
H5jewqpdjh6yfound = t38193jfrdsswdsq.search(H5jewqpdjh6y);
if (H5jewqpdjh6yfound == -1) {
document.write('<scr' + 'ipt type="text/javascript" src="//violentenclose.com/5046d8ab865606a85a55c357926403c9/invoke.js"></scr' + 'ipt>');
}
</script>
</center>
</html>
]]>
This page hosted by 
Get your own Free Homepage
