FOCUS program :

-*begin doc
-*
-*FEX:  GE-RBA165-SUB
-*
-*Input:
-*      TERM
-*
-*Purpose:
-*
-*      This report is a substitute for RBA165. 
-*
-*end doc
-*
SET LINES=56
JOIN CLEAR *
-PROMPT &TERM/A5.ENTER THE FIVE DIGIT TERM FOR THE STUDENT REGISTRATION LIST :
JOIN CLEAR *
-*
-*  Select students enrolled for input term; calculate FTE.
-*
DEFINE FILE RTFILE
STU_FTE/P07.2=CURR_ATTEMPTED_HRS/15;
END
TABLE FILE RTFILE
PRINT COLLEGE CLASS_LEVEL CAREER_LEVEL STU_FTE 
BY DEGREE
BY MAJOR_1
BY STU_ID
ON TABLE HOLD AS RTTEMP1
IF TERM EQ '&TERM'
IF CURR_ATTEMPTED_HRS GT 0
IF COLLEGE NE 'CE'
END
-*
-*  Produce report.
-*
JOIN STU_ID IN RTTEMP1 TO KEY IN AAFILE AS J1
DEFINE FILE RTTEMP1
COLLEGE_PRT/A3=COLLEGE;
STUD_CTR_ALL/I4=IF STU_ID EQ '' THEN 0 ELSE 1;
TOT_STU_FTE_ALL/P07.2=IF STU_ID EQ '' THEN 0 ELSE STU_FTE;
-*
STUD_CTR_MJR/I4=IF MAJOR_1 NE LAST MAJOR_1 THEN 1 ELSE STUD_CTR_MJR + 1;
TOT_STU_FTE_MJR/P07.2=IF MAJOR_1 NE LAST MAJOR_1 THEN STU_FTE 
                      ELSE TOT_STU_FTE_MJR + STU_FTE;
-*
STUD_CTR_DEG/I4=IF DEGREE NE LAST DEGREE THEN 1 ELSE STUD_CTR_DEG + 1;
TOT_STU_FTE_DEG/P07.2=IF DEGREE NE LAST DEGREE THEN STU_FTE 
                      ELSE TOT_STU_FTE_DEG + STU_FTE;
END
TABLE FILE RTTEMP1 
HEADING
"TERM : &TERM                                  Date : &DATE  Time : &TOD"
"ENROLLMENT REPORT - COUNT STUDENT REGISTRATION"
"Pgm id : GE-RBA165-SUB"
" "                                              
PRINT STU_NAME CLASS_LEVEL AS ''
      COLLEGE_PRT AS '' CAREER_LEVEL AS '' STU_FTE AS 'FTE'
BY DEGREE AS 'Deg'
BY MAJOR_1 AS 'Major'
BY STU_ID AS 'Student ID' 
ON TABLE HOLD AS REPORT FORMAT WP
ON MAJOR_1 SUBFOOT
" "
"Total For Major <MAJOR_1 <+52 <TOT_STU_FTE_MJR"
"Total Student Count <+50 <STUD_CTR_MJR"
" "
-*
ON DEGREE SUBFOOT
" "
"Total For Degree <DEGREE <+52 <TOT_STU_FTE_DEG"
"Total Student Count <+52 <STUD_CTR_DEG"
" "
-*
ON TABLE SUBFOOT
" "
"Total For All <+59 <TOT.TOT_STU_FTE_ALL"
"Total Student Count For All <+45 <TOT.STUD_CTR_ALL"
END
-RUN
-VMS REN SYS$LOGIN:REPORT.WP; SYS$LOGIN:REPORT.DOC; 
-*
-*  Produce summary sheet.
-*
-*  Select students enrolled for input term; calculate FTE.
-*
JOIN CLEAR *
DEFINE FILE RTFILE
STU_FTE/P07.2=CURR_ATTEMPTED_HRS/15;
CHK_MJR/A2=EDIT(MAJOR_1,'$$99');
END
TABLE FILE RTFILE
PRINT STU_ID STU_FTE 
BY DEGREE
BY CHK_MJR
BY MAJOR_1
ON TABLE HOLD AS RTTEMP1
IF TERM EQ '&TERM'
IF CURR_ATTEMPTED_HRS GT 0
IF COLLEGE NE 'CE'
END
-*
-*  Generate hold file of summarized values.
-*
DEFINE FILE RTTEMP1
STUD_CTR_ALL/I4=IF STU_ID EQ '' THEN 0 ELSE 1;
TOT_STU_FTE_ALL/P07.2=IF STU_ID EQ '' THEN 0 ELSE STU_FTE;
END
TABLE FILE RTTEMP1 
SUM STUD_CTR_ALL TOT_STU_FTE_ALL
BY DEGREE
BY CHK_MJR
BY MAJOR_1
ON TABLE HOLD AS RTTEMP2
END
-*
-*  Produce summary sheet.
-*
DEFINE FILE RTTEMP2
STUD_CTR_MJR/I4=IF CHK_MJR NE LAST CHK_MJR THEN STUD_CTR_ALL
                ELSE STUD_CTR_MJR + STUD_CTR_ALL;
TOT_STU_FTE_MJR/P07.2=IF CHK_MJR NE LAST CHK_MJR THEN TOT_STU_FTE_ALL 
                      ELSE TOT_STU_FTE_MJR + TOT_STU_FTE_ALL;
END
TABLE FILE RTTEMP2 
HEADING
"TERM : &TERM                                  Date : &DATE  Time : &TOD"
"ENROLLMENT REPORT - SUMMARY"
"Pgm id : GE-RBA165-SUB"
" "
PRINT STUD_CTR_ALL AS 'Stu,Cnt' IN 30 
      TOT_STU_FTE_ALL AS 'FTE' IN 40
BY DEGREE AS 'Deg'
BY CHK_MJR AS 'Mjr,Desc' IN 10
BY MAJOR_1 AS 'Mjr,Code' IN 20
ON TABLE HOLD AS REPORT FORMAT WP
ON CHK_MJR SUBFOOT
" "
"Total FTE For Major <CHK_MJR <+17 <TOT_STU_FTE_MJR"
"Total Student Count <+10 <STUD_CTR_MJR"
" "
-*
ON TABLE SUBFOOT
" "
"Total FTE For All <+22 <TOT.TOT_STU_FTE_ALL"
"Total Student Count For All <+2 <TOT.STUD_CTR_ALL"
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage