FOCUS program :

-*begin doc
-*
-*FEX:	GE-PREQUISITE-CHECK
-*
-*Input:
-*	Term
-*	Course enrolled in for term  (prefix and number)
-*	Prerequisite course to check (prefix and number)
-*
-*Purpose:
-*	Checks that students enrolled in a course have at least a 
-*	"C" in a prerequisite course.
-*
-*end doc
-*
-***************************************************************************
-*
-PROMPT &TERM/A5.ENTER THE FIVE DIGIT TERM (CCYYX) :
-PROMPT &CPRE/A3.ENTER THE 3 LETTER COURSE PREFIX :
-PROMPT &CNUM/A3.ENTER THE 3 DIGIT COURSE NUMBER :
-PROMPT &PPRE/A3.ENTER THE 3 LETTER PREREQUISITE PREFIX :
-PROMPT &PNUM/A3.ENTER THE 3 DIGIT PREREQUISITE NUMBER :
-* 
SET LINES=56
JOIN CLEAR *
-* 
-*  Select students registered in course to check against.
-*
DEFINE FILE RTFILE
COUPRE/A7 = '&PPRE' | ' ' | '&PNUM';
CSE_PRE/A3 = EDIT(SECTION_ID,'999');
CSE_NUM/A3 = EDIT(SECTION_ID,'$$$$999');
END
TABLE FILE RTFILE                                                             
PRINT SECTION_ID COUPRE BY STU_ID 
WHERE (TERM EQ '&TERM') AND (CSE_PRE EQ '&CPRE')
                        AND (CSE_NUM EQ '&CNUM')
                        AND (SPE_STATUS NE 'D');
WHERE RT020_ORDER LE STU_PGM_ENTRY_CNTR;
ON TABLE HOLD AS RTTEMP1
END                  
DEFINE FILE RXFILE
COUPRE/A7 = '&PPRE' | ' ' | '&PNUM';
END
-* 
-*  Discard students who have transfer credit for prerequisite course.
-*
MATCH FILE RTTEMP1
PRINT SECTION_ID COUPRE BY STU_ID 
RUN
FILE RXFILE
PRINT EXTR_COURSE BY STU_ID
WHERE (EDIT(EXTR_COURSE,'9999999') EQ COUPRE) AND 
      ((ACCEPT_FLAG EQ 'Y') OR (ACCEPT_FLAG EQ 'A')); 
WHERE RX020_ORDER LE EXTR_CRED_CNTR;
AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
-* 
-*  Select students who have completed prerequisite course.
-*
DEFINE FILE RTFILE
CSE_PRE/A3 = EDIT(SECTION_ID,'999');
CSE_NUM/A3 = EDIT(SECTION_ID,'$$$$999');
END
TABLE FILE RTFILE
SUM OFFICIAL_GRADE BY STU_ID
WHERE ((CSE_PRE EQ '&PPRE') AND (CSE_NUM EQ '&PNUM')) AND
       (OFFICIAL_GRADE EQ 'A' OR 'B' OR 'C');
WHERE RT020_ORDER LE STU_PGM_ENTRY_CNTR;
ON TABLE HOLD AS RTTEMP3
END 
-* 
-*  Select students who are enrolled in the check course, but have not
-*  completed the prerequisite course.
-*
MATCH FILE HOLD
PRINT SECTION_ID COUPRE BY STU_ID 
RUN
FILE RTTEMP3
PRINT OFFICIAL_GRADE BY STU_ID
AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
-* 
JOIN STU_ID IN HOLD TO STU_ID IN AAFILE AS J2
TABLE FILE HOLD
-*
HEADING CENTER
"DATE: &DATE  TIME: &TOD  Report Name: GE-PREQUISITE-CHECK"
"Term: &TERM  "
" "
"Students not meeting prerequisits for &CPRE &CNUM by not having "
"a grade of A, B, or C or transfer credit for &PPRE &PNUM </1"
" "
-*
PRINT STU_ID AS 'Student ID' SECTION_ID AS 'Course'
BY STU_NAME
ON TABLE HOLD AS REPORT FORMAT WP
END                                                         
JOIN CLEAR *

This page hosted by Get your own Free Homepage