Typical DCL Command Procedure to run the program :

$ DEFINE FOC$DIR1 SI$DATA
$ DEL SI$FOCUS:*.FTM;*/LOG
$ DEL SI$FOCUS:*.MAS;*/LOG
$ SET DEFAULT SI$FOCUS
$ FOCUS
EXEC (FOCEXEC name) GRAD_YR=(High School graduation year), INTERM=(Enrollment term) 
FIN
$ SET DEFAULT Z$PRT
$ RENAME TEMPFILE.DOC (FOCEXEC name).PRT /LOG
$ EXIT

FOCUS program :

-*  THIS FOCEXEC PRODUCES THE FIRST TERM FRESHMAN REPORT FOR S.C.
-*  HIGH SCHOOLS, WHICH IS A LEGAL REQUIREMENT.  FIRST, IT SELECTS
-*  THE STUDENTS WHO GRADUATED HIGH SCHOOL LAST SPRING AND THEN REPORTS 
-*  ON THOSE WHO REGISTERED AND RECEIVED GRADES.
-*    VARIABLES USED :
-*      GRAD_YR : THE YEAR IN WHICH THE STUDENT GRADUATED HIGH SCHOOL
-*      INTERM  : THE FALL TERM TO CHECK TO SEE IF THESE GRADUATING
-*                STUDENTS REGISTERED AND RECEIVED GRADES
-*
OFFLINE CLOSE
FILEDEF OFFLINE DISK Z$PRT:TEMPFILE.DOC
FILEDEF D_MAJOR DISK SI$FOCUS:D_MAJOR.DOC
JOIN CLEAR *
DEFINE FILE RBFILE
YEAR_ONLY/A2=EDIT(HS_END_DT, '99$$');
END
TABLE FILE RBFILE
PRINT SID_RB HS_CODE
ON TABLE HOLD AS RBTEMP1
IF YEAR_ONLY EQ '&GRAD_YR'
IF HS_CODE NE '419826' OR '419996' OR '419997' OR '419998' OR '419999'
IF HS_CTR GT 0
WHERE RB_020_ORDER EQ 1;
END
DEFINE FILE RBTEMP1
KEYTOAC/A18='070XX0'|HS_CODE|'      ';
END
TABLE FILE RBTEMP1
PRINT SID_RB HS_CODE BY KEYTOAC
ON TABLE HOLD AS RBTEMP2
END
JOIN KEYTOAC IN RBTEMP2 TO SCH_IND_KEY IN ACFILE AS J1
TABLE FILE RBTEMP2
PRINT SID_RB HS_CODE SCHL_NAME
ON TABLE HOLD AS RBTEMP3
END
JOIN CLEAR *
JOIN TEMP_KEY WITH SID_RB IN RBTEMP3 TO KEY IN RTFILE AS J1
DEFINE FILE RBTEMP3
TEMP_KEY/A14=('&INTERM'|'XX'|SID_RB);
END
TABLE FILE RBTEMP3
PRINT SPE_SECT_RT OFCL_GRD_RT PRIM_MJR1_RT SCHL_NAME HS_CODE 
      BY SID_RB
ON TABLE HOLD AS RBTEMP4
IF CURR_AHRS_RT GT 0.0
IF SPE_STAT_RT NE 'D'
WHERE RT_020_ORDER LE SPE_CTR_RT;
END
JOIN TEMP_KEY2 WITH SPE_SECT_RT IN RBTEMP4 TO KEY IN RCFILE AS J2
DEFINE FILE RBTEMP4
TEMP_KEY2/A16='XX'|'&INTERM'|SPE_SECT_RT;
END
TABLE FILE RBTEMP4
PRINT SPE_SECT_RT SECT_TTL_RC OFCL_GRD_RT PRIM_MJR1_RT SCHL_NAME 
      HS_CODE 
      BY SID_RB
ON TABLE HOLD AS RBTEMP5
END 
JOIN CLEAR *
JOIN TEMP_KEY3 WITH SID_RB IN RBTEMP5 TO KEY IN AAFILE AS J1
DEFINE FILE RBTEMP5
TEMP_KEY3/A11=('XX'|SID_RB);
PRINT_MAJOR/A35=DECODE PRIM_MJR1_RT (D_MAJOR ELSE '*****');
EDIT_SID/A11=EDIT(SID_RB,'999-99-9999');
END
TABLE FILE RBTEMP5
HEADING
"<46 FIRST TERM FRESHMAN REPORT FOR HIGH SCHOOLS </1"
"<1  FOR : <HS_CODE> : <SCHL_NAME> - GUIDANCE DEPARTMENT"
"<1 FROM : THE REGISTRAR; REGISTRAR; SOME COLLEGE; 
<+1 CONWAY, S.C. </1"
PRINT SPE_SECT_RT AS 'Course ID' SECT_TTL_RC AS 'Course Name' 
      OFCL_GRD_RT AS 'Grade'
      BY HS_CODE NOPRINT
      BY SCHL_NAME NOPRINT
      BY STU_NAME_AA 
      BY EDIT_SID AS 'Student ID' 
      BY PRINT_MAJOR AS 'Major'
      ON SCHL_NAME PAGE-BREAK
      ON EDIT_SID SKIP-LINE
      ON EDIT_SID SUBFOOT
      "         "
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage