Typical DCL Command Procedure to run the program :

$! 
$!      Description:    Creates the NSLC data extract file. 
$! 
$ SET NOVERIFY 
$ SAY :== "WRITE SYS$OUTPUT" 
$ CL
$! 
$!  Prompt for term 
$!
$ SAY "This will create the NSLC data extract file." 
$ SAY " " 
$! 
$ENTER_PARM: 
$ READ SYS$COMMAND/TIME=60/END=EXIT/ERROR=EXIT/PROMPT= -   
  "Enter the FIVE DIGIT term (CCYYx) to run this list for >>> " TERMIN   
$ LEN_TERMIN = F$LENGTH(TERMIN) 
$ IF LEN_TERMIN .NE. 5 THEN GOTO ENTER_PARM 
$ TYP_TERMIN = F$TYPE(TERMIN) 
$ IF TYP_TERMIN .NES. "INTEGER" THEN GOTO ENTER_PARM
$! 
$!  Create parameter file the run the RBA349 program. 
$! 
$ OPEN/WRITE output_file SI$DATA:RBA349PRM.DAT 
$! 
$ output_record = "PGM=RBA349,TERM=" + F$EXTRACT(2,3,TERMIN) + ",RUNTYPE=E,OPTION2=Y"
$ WRITE output_file output_record 
$ CLOSE output_file 
$!
$!  Create the file of student ids to feed into RBA349.
$!
$ COM_FILE = "SYS$LOGIN:FOCTEMP.COM"
$!
$ OPEN/WRITE output_file 'COM_FILE' 
$! 
$ WRITE output_file "$ DEFINE FOC$DIR1 SI$DATA" 
$ WRITE output_file "$ DEFINE FOC$DIR2 SI$FEX,SI$MFD" 
$ WRITE output_file "$ SET DEFAULT SYS$LOGIN" 
$ WRITE output_file "$ FOCUS" 
$ WRITE output_file "EXEC SI$FOCUS:GE-NSLC-DATA IN_TERM=" + TERMIN 
$ WRITE output_file "FIN" 
$ WRITE output_file "$ EXIT" 
$! 
$ CLOSE output_file 
$ SUBMIT/NOPRINT/NOTIFY 'COM_FILE'
$ SYNCHRONIZE FOCTEMP
$ COPY SYS$LOGIN:PLAY.FTM SI$DATA:RBA349INP.DAT;
$ SUBMIT/NOPRINT/NOTIFY SI$COM:RJA349.COM
$ SYNCHRONIZE RJA349
$!
$!  E-mail results to user.
$!
$ NAME = F$GETJPI("","USERNAME")
$ MAIL/SUBJECT="RBA349 - STATUS REPORT" Z$PRT:RBA349.PRT 'NAME' 
$!
$EXIT:
$!
$ SAY " " 
$ SAY "All done...  " 
$ SAY " " 
$!
$!  CLEAN UP.
$!
$ DELETE/LOG SYS$LOGIN:*.FTM;*
$ DELETE/LOG SYS$LOGIN:*.MAS;*
$ DELETE/LOG SYS$LOGIN:*.WP;*
$ DELETE/LOG SYS$LOGIN:FOCTEMP.COM;*
$ SET DEFAULT SYS$LOGIN
$ EXIT


FOCUS program :

-*begin doc
-*
-*FEX:	GE-NSLC-DATA
-*
-*INPUT
-*	IN_TERM
-*
-*	This procedure produces an input data file which will be 
-*	feed into RBA349.
-*	RBA439 produces the NSLC extract file.
-*
-*
-*end doc
-*
JOIN CLEAR *
SET LINES=999999
SET PAGE = NOPAGE
-*
TABLE FILE RTFILE
PRINT STU_ID
ON TABLE SAVE AS PLAY
WHERE TERM EQ '&IN_TERM';
WHERE COLLEGE NE 'CE';
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage