FOCUS program (1) :

-*begin doc
-*
-*FEX:	GE-ADVISOR-STUD-COL
-*
-*INPUT
-*	TERM
-*	COLLEGE
-*
-*	This procedure produces a list of students by advisor for a
-*	particular college as input. Lists are sorted by student name
-*	and there is a page break on advisor
-*
-*
-*end doc
-*
JOIN CLEAR *
SET LINES=56
-PROMPT &TERM/A5.ENTER THE FIVE DIGIT TERM FOR THE LIST OF ADVISING STUDENTS (CCYYX) :
-PROMPT &COLLEGE/A2.ENTER THE COLLEGE FOR ADVISOR'S LIST.
-*
-*  Select students enrolled for a given term and college.
-*
TABLE FILE RTFILE
PRINT MAJOR_1 BY STU_ID 
WHERE TERM EQ '&TERM' AND COLLEGE EQ '&COLLEGE' AND CURR_ATTEMPTED_HRS GT 0;
ON TABLE HOLD AS RTTEMP1
END 
-*
-*  Retrieve student name and advisor id.
-*
JOIN STU_ID IN RTTEMP1 TO KEY IN AAFILE AS J1
DEFINE FILE RTTEMP1
ADVISOR_ALPHA/A9=EDIT(ADVISOR_ID_1);
END
TABLE FILE RTTEMP1
PRINT STU_NAME STU_ID MAJOR_1 BY ADVISOR_ALPHA
ON TABLE HOLD AS RTTEMP2
END
-*  
-*  Retrieve advisor name and create report.  
-*  
JOIN ADVISOR_ALPHA IN RTTEMP2 TO KEY IN AYFILE AS J2
TABLE FILE RTTEMP2
"DATE: &DATE  TIME: &TOD  REPORT NAME: GE-ADVISOR-STUD-COL"
"<5 STUDENTS SORTED BY ADVISOR 1, NAME FOR TERM &TERM </1"
"Advisor: <NAME  <ADVISOR_ALPHA"
-*
PRINT STU_NAME AS 'Student Name' STU_ID AS 'Student ID' MAJOR_1 AS 'Major'
BY FAC_NAME NOPRINT
BY STU_NAME NOPRINT
ON FAC_NAME PAGE-BREAK
-*
ON TABLE HOLD AS REPORT FORMAT WP
END                                                                           
JOIN CLEAR *


FOCUS program (2) :

-*begin doc
-*
-*FEX:	GE-ADVISOR-STUD-IND
-*
-*INPUT
-*	TERM
-*      ADVISOR ID
-*
-*	This procedure produces an alphabetical list of students 
-*	for the input advisor id.
-*
-*
-*end doc
-*
JOIN CLEAR *
SET LINES=56
-PROMPT &TERM/A5.ENTER THE FIVE DIGIT TERM FOR THE LIST OF ADVISING STUDENTS :
-PROMPT &AID/A9.ENTER THE ADVISOR'S NINE DIGIT ID :
-*
-*  Select students enrolled for a given term.
-*
TABLE FILE RTFILE
PRINT MAJOR_1 BY STU_ID 
WHERE TERM EQ '&TERM' AND COLLEGE NE 'CE' AND CURR_ATTEMPTED_HRS GT 0;
ON TABLE HOLD AS RTTEMP1
END 
-*
-*  Retrieve student name and advisor id.
-*
JOIN STU_ID IN RTTEMP1 TO KEY IN AAFILE AS J1
DEFINE FILE RTTEMP1
ADVISOR_ALPHA/A9=EDIT(ADVISOR_ID_1);
END
TABLE FILE RTTEMP1
PRINT STU_NAME STU_ID MAJOR_1 BY ADVISOR_ALPHA
ON TABLE HOLD AS RTTEMP2
END
-*  
-*  Retrieve advisor name and create report.  
-*  
JOIN ADVISOR_ALPHA IN RTTEMP2 TO KEY IN AYFILE AS J2
TABLE FILE RTTEMP2
"Date: &DATE  Time: &TOD  Report Name: GE-ADVISOR-STUD-IND"
"<5 Students sorted by advisor 1, name for term &TERM </1"
"Advisor: <FAC_NAME  <ADVISOR_ALPHA"
-*
PRINT STU_NAME AS 'Student Name' STU_ID AS 'STUDENT ID' MAJOR_1 AS 'Major'
BY FAC_NAME NOPRINT
BY STU_NAME NOPRINT
ON ADVISOR_ALPHA PAGE-BREAK
WHERE ADVISOR_ALPHA EQ '&AID'; 
-*
ON TABLE HOLD AS REPORT FORMAT WP
END                                                                           
JOIN CLEAR *


FOCUS program (3) :

-*begin doc
-*
-*FEX:	GE-ADVISOR-STUD-LIST
-*
-*INPUT
-*	TERM
-*
-*	This procedure produces an alphabetical list of students 
-*	by advisor for every advisor. Report is sorted by college
-*	advisor and student with a page break on advisor. If 
-*	students has wrong college for advisor then multiple lists
-*	for an advisor will be produced.
-*
-*
-*end doc
-*
JOIN CLEAR *
SET LINES=56
-PROMPT &TERM/A5.ENTER THE FIVE DIGIT TERM FOR THE LIST OF ADVISING STUDENTS :
-*
-*  Select students enrolled for a given term.
-*
TABLE FILE RTFILE
PRINT COLLEGE MAJOR_1 BY STU_ID
WHERE TERM EQ '&TERM' AND COLLEGE NE 'CE' AND CURR_ATTEMPTED_HRS GE 1;
ON TABLE HOLD AS RTTEMP1
END 
-*
-*  Retrieve student name and advisor id.
-*
JOIN STU_ID IN RTTEMP1 TO KEY IN AAFILE AS J1
DEFINE FILE RTTEMP1
ADVISOR_ALPHA/A9=EDIT(ADVISOR_ID_1);
END
TABLE FILE RTTEMP1
PRINT COLLEGE MAJOR_1 STU_NAME STU_ID BY ADVISOR_ALPHA
ON TABLE HOLD AS RTTEMP2
END
-*  
-*  Retrieve advisor name.  
-*
JOIN ADVISOR_ALPHA IN RTTEMP2 TO KEY IN AYFILE AS J2
TABLE FILE RTTEMP2
PRINT COLLEGE MAJOR_1 ADVISOR_ALPHA FAC_NAME STU_NAME 
BY STU_ID 
ON TABLE HOLD AS RTTEMP3
END
-*
-*  Create report.
-*
TABLE FILE RTTEMP3
"DATE: &DATE  TIME: &TOD  Report Name: GE-ADVISOR-STUD-LIST"
"<5 Students Sorted By College, Advisor 1, & Name For Term &TERM </1"
"Advisor: <FAC_NAME  <ADVISOR_ALPHA        College: <COLLEGE </1"
-*
PRINT STU_NAME AS 'Name' STU_ID AS 'Student ID' MAJOR_1 AS 'Major' IN 70
BY COLLEGE NOPRINT
BY ADVISOR_ALPHA NOPRINT 
BY STU_NAME NOPRINT
ON ADVISOR_ALPHA PAGE-BREAK
-*
ON TABLE HOLD AS REPORT FORMAT WP
END                                                                           
JOIN CLEAR *

This page hosted by Get your own Free Homepage