FOCUS program (1) :

-*
-*  THIS FOCEXEC WILL VERIFY THE FINANCIAL HOURS FOR STUDENTS.
-*
JOIN CLEAR *
TABLE FILE RTFILE
PRINT SECTION_ID FIN_ATTEMPTED_HRS CRS_ATTEMPTED_HRS TERM BY STU_ID 
WHERE TERM GE '(input enrollment term)';
WHERE (FIN_ATTEMPTED_HRS EQ 0) OR
      (FIN_ATTEMPTED_HRS NE CRS_ATTEMPTED_HRS);
WHERE COLLEGE_SPE NE 'CE';
END
JOIN CLEAR *


FOCUS program (2) :

-*
-*  THIS FOCEXEC WILL CREATE A BATCH TRANSACTION TO CORRECT THE FINANCIAL
-*  HOURS ON A STUDENT'S RECORD.
-*
JOIN CLEAR *
FILEDEF FINFIX DISK FINFIX.FTM APPEND LREC 90 RECFM F
-*
-*  Create The Batch Header
-*
DEFINE FILE AAFILE
BATCH_HEADER1/A35 = '$$$MSC502        FIN HRS UPD    YBU';
BATCH_HEADER2/A55 =      
'                                                       ';
END
TABLE FILE AAFILE
PRINT BATCH_HEADER1 AS ''
      BATCH_HEADER2 AS ''
BY STU_ID NOPRINT   
ON TABLE SAVE AS FINFIX   
IF RECORDLIMIT EQ 1  
END
-*
-*  Get all non-CE course sections with zero financial hours.
-*
DEFINE FILE RTFILE
JN_KEY/A16=TERM|SECTION_ID;
END
TABLE FILE RTFILE
PRINT STU_ID TERM SECTION_ID BY JN_KEY
ON TABLE HOLD AS RTTEMP1
WHERE TERM EQ '(input enrollment term)';
WHERE FIN_ATTEMPTED_HRS EQ 0;
WHERE COLLEGE_SPE NE 'CE';
END
-*
-*  Get financial hours data from section definition (screen 129).
-*
JOIN JN_KEY IN RTTEMP1 TO KEY IN RCFILE AS J1
TABLE FILE RTTEMP1
PRINT STU_ID TERM SECTION_ID CTF_FIN_CREDIT BY JN_KEY
ON TABLE HOLD AS RTTEMP2
WHERE CTF_FIN_CREDIT GT 0;
END
-*
-*  Create batch transaction to update SIS.
-*
DEFINE FILE RTTEMP2
FIN_CRE_INC/P05.2=CTF_FIN_CREDIT*100;
FIN_CRE_ALPHA/A5=EDIT(FIN_CRE_INC);
BTH_TRANS/A90 = ('45B'|STU_ID|'MNT'|TERM|SECTION_ID|
'                                             '|EDIT(FIN_CRE_ALPHA,'$9999'));
END
TABLE FILE RTTEMP2
PRINT BTH_TRANS BY STU_ID NOPRINT
ON TABLE SAVE AS FINFIX
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage