FOCUS program :

-*begin doc
-*
-*FEX:  RE-HS-FTF-RPT
-*
-*input
-*      Term : The fall term to check to see if these graduating
-*             students registered and received grades.
-*      Graduation Year : The year in which the student graduated high school. 
-*
-*      This FOCEXEC produces the first term freshman report for S.C.
-*      high schools, which is a legal requirement.  First, it selects
-*      the students who graduated high school last spring and then reports 
-*      on those who registered and received grades.
-*
-*end doc
-*
SET LINES=56                                                                   
-PROMPT &GRAD_YR/A5.ENTER THE FOUR DIGIT GRADUATION YEAR TO PRODUCE REPORT (CCYY) :
-PROMPT &INTERM/A5.ENTER THE FIVE DIGIT ENROLLMENT TERM TO PRODUCE REPORT (CCYYX) :
FILEDEF D_MAJOR DISK SI$FOCUS:PR_TABLE.DAT
SET COMPUTE=OLD
JOIN CLEAR *
-*
-*  Select recent high school graduates.
-*
DEFINE FILE RBFILE
YEAR_ONLY/A4=EDIT(HS_END_DT,'9999');
HS_ALPHA/A7=EDIT(HS_INSTITUTION);
END
TABLE FILE RBFILE
PRINT STU_ID BY HS_ALPHA
ON TABLE HOLD AS RBTEMP1
IF YEAR_ONLY EQ '&GRAD_YR'
IF HS_INSTITUTION NE 419996 OR 419997 OR 419998 OR 419999
IF HIGH_SCHOOL_CNTR GT 0
WHERE RB020_ORDER EQ 1;
END
-*
-*  Get high school name.
-*
JOIN HS_ALPHA IN RBTEMP1 TO KEY IN AIFILE AS J1
TABLE FILE RBTEMP1
PRINT HS_ALPHA INSTIT_NAME BY STU_ID
ON TABLE HOLD AS RBTEMP2
END
-*
-*  Get recent registration information.
-*
JOIN TEMP_KEY WITH STU_ID IN RBTEMP2 TO KEY IN RTFILE AS J2
DEFINE FILE RBTEMP2
TEMP_KEY/A14=('&INTERM'|STU_ID);
END
TABLE FILE RBTEMP2
PRINT STU_ID OFFICIAL_GRADE MAJOR_1 INSTIT_NAME HS_ALPHA 
      BY SECTION_ID 
ON TABLE HOLD AS RBTEMP3
IF CURR_ATTEMPTED_HRS GT 0.0
IF SPE_STATUS NE 'D'
WHERE RT020_ORDER LE STU_PGM_ENTRY_CNTR;
END
-*
-*  Get course name information.
-*
JOIN TEMP_KEY2 WITH SECTION_ID IN RBTEMP3 TO KEY IN RCFILE AS J3
DEFINE FILE RBTEMP3
TEMP_KEY2/A16='&INTERM'|SECTION_ID;
END
TABLE FILE RBTEMP3
PRINT SECTION_ID RC_CRS_TITLE OFFICIAL_GRADE MAJOR_1 INSTIT_NAME 
      HS_ALPHA 
      BY STU_ID
ON TABLE HOLD AS RBTEMP4
END 
-*
-*  Get student name information.
-*
JOIN STU_ID IN RBTEMP4 TO STU_ID IN AAFILE AS J4
DEFINE FILE RBTEMP4
PRINT_MAJOR/A60=DECODE MAJOR_1 (D_MAJOR ELSE '*****');
SHRT_MAJOR/A40=EDIT(PRINT_MAJOR,'9999999999999999999999999999999999999999');
SHRT_NAME/A25=EDIT(STU_NAME,'9999999999999999999999999');
SHRT_CRS/A25=EDIT(RC_CRS_TITLE,'9999999999999999999999999');
EDIT_SID/A11=EDIT(STU_ID,'999-99-9999');
END
TABLE FILE RBTEMP4
HEADING
"<46 FIRST TERM FRESHMAN REPORT FOR HIGH SCHOOLS </1"
"<1  FOR : <HS_ALPHA> : <INSTIT_NAME> - GUIDANCE DEPARTMENT"
"<1  FROM : REGISTRAR; SOME COLLEGE;" 
"<+1 FLORENCE, S.C. </1"
PRINT SECTION_ID AS 'Course ID' SHRT_CRS AS 'Course Name' 
      OFFICIAL_GRADE AS 'Grade'
      BY HS_ALPHA NOPRINT
      BY INSTIT_NAME NOPRINT
      BY SHRT_NAME AS 'Student Name' 
      BY EDIT_SID AS 'Student ID' 
      BY SHRT_MAJOR AS 'Major'
      ON INSTIT_NAME PAGE-BREAK
      ON EDIT_SID SKIP-LINE
      ON EDIT_SID SUBFOOT
      "         "
ON TABLE HOLD AS REPORT FORMAT WP
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage