FOCUS program :

-*  THIS FOCEXEC WILL LIST THE SAT SCORE & HIGH SCHOOL RANK FOR EACH 
-*  STUDENT ENROLLED UNDER THE AA/AS PROGRAM, IRREGARDLESS OF HIGH 
-*  SCHOOL DATE.  ALSO, THE NUMBER OF STUDENTS WITH & WITHOUT SAT
-*  SCORES IS LISTED.
-*
OFFLINE CLOSE
FILEDEF OFFLINE DISK TEMPFILE.DOC
FILEDEF HOLD DISK HOLD.FTM
JOIN CLEAR *
MATCH FILE HOLD
PRINT APP_FOR_MJR RESD_STAT_AA BY SID_CODE
RUN
FILE MMFILE
PRINT APP_FOR_DEG BY SID_MM AS SID_CODE
IF APP_TERM EQ '(Application term)'
IF APP_FOR_MJR EQ '(Admissions majors)'
IF ADMIT_ACTN EQ 'X' OR 'A'
WHERE MM_030_ORDER LE 3;
AFTER MATCH HOLD OLD-AND-NEW
END
-RUN
MATCH FILE HOLD
PRINT RESD_STAT_AA APP_FOR_MJR BY SID_CODE
RUN
FILE RTFILE
PRINT CAREER_RT BY SID_RT AS SID_CODE
IF TERM_RT EQ '(Enrollment term)'
IF CURR_AHRS_RT GT 00.00
IF CAREER_RT NE 'CE'
AFTER MATCH HOLD OLD-AND-NEW
END
-RUN
JOIN TEMP_KEY WITH SID_CODE IN HOLD TO KEY IN RBFILE AS J1
DEFINE FILE HOLD
TEMP_KEY/A11=('XX'|SID_CODE);
REAL_HS_RANK/P3=IF HS_RANK_PCT EQ 0 THEN HS_RANK_PCT ELSE
                (HS_RANK_PCT-100)*-1;
END
TABLE FILE HOLD
PRINT SID_CODE REAL_HS_RANK
ON TABLE HOLD AS RBTEMP1
WHERE RB_020_ORDER EQ 1;
END
JOIN CLEAR *
JOIN TEMP_KEY WITH SID_CODE IN RBTEMP1 TO KEY IN RBFILE AS J1
DEFINE FILE RBTEMP1
TEMP_KEY/A11=('XX'|SID_CODE);
END
TABLE FILE RBTEMP1
PRINT SCORE3 REAL_HS_RANK BY SID_CODE
ON TABLE HOLD AS RBTEMP2
IF TEST_CD EQ 'SAT  '
END
JOIN CLEAR *
SET PAGE-NUM=NOPAGE
TABLE FILE HOLD
HEADING 
"< /3"
"<5 TOTAL NUMBER OF ENTERING FRESHMAN </1"
SUM CNT.SID_CODE AS ''
END 
MATCH FILE HOLD
PRINT CAREER_RT BY SID_CODE
RUN
FILE RBTEMP2
PRINT SCORE3 BY SID_CODE
AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
TABLE FILE HOLD
HEADING 
"< /3"
"<5 NUMBER OF ENTERING FRESHMAN WITH NO SAT SCORES  </1"
SUM CNT.SID_CODE AS ''
END 
DEFINE FILE RBTEMP2
THS_REC/A1=IF SID_CODE NE LAST SID_CODE THEN 'Y' ELSE 'N';
END
TABLE FILE RBTEMP2
HEADING 
"< /3"
"<5 NUMBER OF ENTERING FRESHMAN WITH SAT SCORES </1"
SUM CNT.SID_CODE AS ''
IF THS_REC EQ 'Y'
END 
DEFINE FILE RBTEMP1
BUFFER3/A4='    ';
END
MATCH FILE RBTEMP1
PRINT BUFFER3 REAL_HS_RANK BY SID_CODE
RUN
FILE RBTEMP2
PRINT SCORE3 BY SID_CODE
AFTER MATCH HOLD OLD-OR-NEW
END
-RUN
FILEDEF OFFLINE DISK TEMPFILE2.DOC
SET PAGE-NUM=ON
JOIN TEMP_KEY WITH SID_CODE IN HOLD TO KEY IN AAFILE AS J1
DEFINE FILE HOLD
TEMP_KEY/A11=('XX'|SID_CODE);
SID_ID/A11=EDIT(SID_CODE,'999-99-9999');
THS_REC/A1=IF SID_CODE NE LAST SID_CODE THEN 'Y' ELSE 'N';
HINFO/A44=' ';
PRID/A8='NA';
END
TABLE FILE HOLD
-INCLUDE STDHEAD.SEG
"<50 AA/AS PROGRAM REVIEW; SAT REPORT </1"
PRINT STU_NAME_AA IN 30 SID_ID AS 'Student ID' IN 60 
      SCORE3 AS 'SAT Score' IN 75 REAL_HS_RANK 
      AS 'HS Rank' IN 85
      BY NAME_SORT_AA NOPRINT
IF THS_REC EQ 'Y'
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage