FOCUS program :

JOIN CLEAR *
TABLE FILE RTFILE
PRINT CAREER_RT BY SID_RT
ON TABLE HOLD AS EXTTEMP1
IF TERM_RT EQ '(Enrollment term)'
IF CURR_AHRS_RT GT 00.00
IF CAREER_RT NE 'CE'
END
JOIN TEMP_KEY WITH SID_RT IN EXTTEMP1 TO KEY IN RTFILE AS J1
DEFINE FILE EXTTEMP1
TEMP_KEY/A14=('(Enrollment term)XX'|SID_RT);
END
TABLE FILE EXTTEMP1
PRINT ATT_HRS_RT SID_RT BY SPE_SECT_RT 
ON TABLE HOLD AS RTTEMP1
IF TERM_RT EQ '(Enrollment term)'
IF SPE_STAT_RT EQ 'E'
IF CALC_CRER1RT NE 'CE'
IF CALC_CRER2RT NE 'CE'
IF CALC_CRER3RT NE 'CE'
WHERE RT_020_ORDER LE SPE_CTR_RT;
END
JOIN TEMP_KEY WITH SPE_SECT_RT IN RTTEMP1 TO KEY IN RCFILE AS J2
DEFINE FILE RTTEMP1
TEMP_KEY/A16=('XX(Enrollment term)'|SPE_SECT_RT);
END
TABLE FILE RTTEMP1
PRINT ATT_HRS_RT SPE_SECT_RT 
      BY SID_RT
      BY SCHD_PRT_RC 
ON TABLE HOLD AS RTTEMP2
END
DEFINE FILE RTTEMP2
CNT_COUR_HRS/P07.2C=IF (SID_RT EQ LAST SID_RT) THEN
                       CNT_COUR_HRS + ATT_HRS_RT ELSE ATT_HRS_RT;
HOURS_DAY/P07.2C=IF (SID_RT NE LAST SID_RT) THEN 00.00;
HOURS_NITE/P07.2C=IF (SID_RT NE LAST SID_RT) THEN 00.00;
HOURS_DAY/P07.2C=IF (SID_RT EQ LAST SID_RT) 
                       AND (SCHD_PRT_RC EQ 'D') THEN
                       HOURS_DAY + ATT_HRS_RT ELSE 
                       IF (SCHD_PRT_RC EQ 'D') THEN ATT_HRS_RT;
HOURS_NITE/P07.2C=IF (SID_RT EQ LAST SID_RT)
                       AND (SCHD_PRT_RC EQ 'E') THEN
                       HOURS_NITE + ATT_HRS_RT ELSE 
                       IF (SCHD_PRT_RC EQ 'E') THEN ATT_HRS_RT;
END
TABLE FILE RTTEMP2
PRINT CNT_COUR_HRS HOURS_DAY HOURS_NITE
      BY SID_RT
ON TABLE HOLD AS RTTEMP3
END
TABLE FILE RTTEMP3
PRINT HOURS_DAY HOURS_NITE
      BY SID_RT
      BY HIGHEST CNT_COUR_HRS 
ON TABLE HOLD AS RTTEMP4
END
DEFINE FILE RTTEMP4
THS_REC/A1=IF (SID_RT NE LAST SID_RT) THEN 'Y' ELSE 'N';
END
TABLE FILE RTTEMP4
PRINT HOURS_DAY HOURS_NITE
      BY SID_RT
ON TABLE HOLD AS RTTEMP5
IF THS_REC EQ 'Y'
END
DEFINE FILE RTTEMP5
DAY_OR_NITE/A1=IF (HOURS_NITE GT HOURS_DAY) THEN 'E' ELSE 'D';
JN_KEY/A11=('XX'|SID_RT);
END
TABLE FILE RTTEMP5
PRINT DAY_OR_NITE SID_RT BY JN_KEY
ON TABLE HOLD AS RTTEMP6
END
JOIN CLEAR *
-*
JOIN JN_KEY IN RTTEMP6 TO KEY IN RPFILE AS J1
DEFINE FILE RTTEMP6
SUPER_JN_KEY/A14=(ACTV_TERM_RP|'XX'|SID_RT);
END
TABLE FILE RTTEMP6
PRINT DAY_OR_NITE SID_RT BY SUPER_JN_KEY
ON TABLE HOLD AS RTTEMP7
WHERE (ACTV_TERM_RP NE '   ') AND (ACTV_TERM_RP LE '(Enrollment term)'); 
END
JOIN SUPER_JN_KEY IN RTTEMP7 TO KEY IN RTFILE AS J2
TABLE FILE RTTEMP7
PRINT DAY_OR_NITE SID_RT TERM_RT BY SUPER_JN_KEY
ON TABLE HOLD AS RTTEMP8
IF CURR_AHRS_RT GT 00.00
END
TABLE FILE RTTEMP8
PRINT DAY_OR_NITE BY SID_RT BY TERM_RT
ON TABLE HOLD AS RTTEMP9
END
DEFINE FILE RTTEMP9
THS_REC/A1=IF SID_RT NE LAST SID_RT THEN 'Y' ELSE 'N';
FST_SEM/A3=TERM_RT;
END
TABLE FILE RTTEMP9
PRINT DAY_OR_NITE FST_SEM BY SID_RT 
ON TABLE HOLD AS EXTTEMP3
IF THS_REC EQ 'Y'
END
-*
JOIN CLEAR *
JOIN TEMP_KEY1 WITH SID_RT IN EXTTEMP3 TO KEY IN RTFILE AS J1
JOIN TEMP_KEY2 WITH SID_RT IN EXTTEMP3 TO KEY IN MMFILE AS J2
JOIN TEMP_KEY2 WITH SID_RT IN EXTTEMP3 TO KEY IN AAFILE AS J3
DEFINE FILE EXTTEMP3
TEMP_KEY1/A14=('(Enrollment term)XX'|SID_RT);
TEMP_KEY2/A11=('XX'|SID_RT);
END
TABLE FILE EXTTEMP3
PRINT STU_NAME_AA DOB_AA SEX_AA ETH_ORIG_AA STATE_ORIGAA CNTY_ORIG_AA
      RESD_STAT_AA PRIM_MJR1_RT CURR_AHRS_RT RPT3_FLG_RT DAY_OR_NITE
      RPT_FLG_1 RPT_FLG_2 RPT4_FLG_RT RPT5_FLG_RT FST_SEM
BY SID_RT
ON TABLE SAVE AS INSTEXT
IF TERM_RT EQ '(Enrollment term)'
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage