Typical DCL Command Procedure to run the program :
$ DELETE SI$FOCUS:*.FTM;*/LOG
$ DELETE SI$FOCUS:*.MAS;*/LOG
$ DEFINE FOC$DIR1 SI$DATA
$ SET DEFAULT SI$FOCUS
$ FOCUS
EXEC (FOCEXEC name)A ENRTRM=(Enrollment term)
FIN
$ COPY SI$FOCUS:RTTEMP2.FTM VETHOLD.DAT;/LOG
$ COPY SI$FOCUS:VETHOLD.MFD SI$FOCUS:*.MAS;/LOG
$ COPY SI$FOCUS:VETCHK.MFD SI$FOCUS:*.MAS;/LOG
$ FOCUS
EXEC (FOCEXEC name)B ENRTRM=(Enrollment term)
FIN
$ COPY VETHOLD.DAT VETCHK.DAT;/LOG
$ SET DEFAULT Z$PRT
$ RENAME TEMPFILE.DOC (FOCEXEC name).PRT /LOG
$ NAME = F$GETJPI("","USERNAME")
$ MAIL/SUBJECT="VETERAN CHANGE REPORT" (FOCEXEC name).PRT 'NAME'
$ EXIT
FOCUS program :
(1)
-* THIS FOCEXEC CHECKS THE VETERAN STUDENTS FOR ANY CHANGE IN NAME,
-* ADDRESS, PROGRAM, OR CREDIT HOURS WHO ARE ENROLLED FOR THE
-* INPUT TERM. THIS PART BUILDS THE HOLD FILE.
-* VARIABLES USED :
-* ENRTRM : THE ENROLLMENT TERM TO LOOK AT
-*
JOIN CLEAR *
TABLE FILE RTFILE
PRINT RPT6_FLG_RT FAM_ATT_HRS CURR_AHRS_RT PRIM_MJR1_RT BY SID_RT
IF TERM_RT EQ '&ENRTRM'
IF CURR_AHRS_RT GT 00.00
ON TABLE HOLD AS RTTEMP1
END
JOIN TEMP_KEY WITH SID_RT IN RTTEMP1 TO KEY IN AAFILE AS J1
DEFINE FILE RTTEMP1
TEMP_KEY/A11=('XX'|SID_RT);
END
TABLE FILE RTTEMP1
PRINT STU_NAME_AA CURR_AHRS_RT PRIM_MJR1_RT CITY_AA STATE_AA
ZIP_AA STREET1_AA STREET2_AA VET_CD_AA VET_BEN_AA RPT6_FLG_RT
FAM_ATT_HRS
BY SID_RT
ON TABLE SAVE AS RTTEMP2
WHERE (VET_CD_AA NE ' ') OR (VET_BEN_AA NE ' ');
WHERE AA_020_ORDER EQ 1;
END
JOIN CLEAR *
(2)
-* THIS FOCEXEC CHECKS THE VETERAN STUDENTS FOR ANY CHANGE IN NAME,
-* ADDRESS, PROGRAM, OR CREDIT HOURS WHO ARE ENROLLED FOR THE
-* INPUT TERM. THIS PART DOES THE ACTUAL CHECKING.
-* VARIABLES USED :
-* ENRTRM : THE ENROLLMENT TERM TO LOOK AT
-*
JOIN CLEAR *
OFFLINE CLOSE
FILEDEF OFFLINE DISK Z$PRT:TEMPFILE.DOC
FILEDEF VETHOLD DISK VETHOLD.DAT
FILEDEF VETCHK DISK VETCHK.DAT
SET PAGE=NOPAGE
SET LINES=999999
JOIN D1 IN VETHOLD TO D21 IN VETCHK AS J1
DEFINE FILE VETHOLD
CHK_D2/A1=IF D2 NE D22 THEN 'Y' ELSE 'N';
VERB_D2/A5=IF CHK_D2 EQ 'Y' THEN 'NAME ' ELSE ' ';
-*
CHK_D3/A1=IF D3 NE D23 THEN 'Y' ELSE 'N';
VERB_D3/A8=IF CHK_D3 EQ 'Y' THEN 'CUR HRS ' ELSE ' ';
-*
CHK_D4/A1=IF D4 NE D24 THEN 'Y' ELSE 'N';
VERB_D4/A6=IF CHK_D4 EQ 'Y' THEN 'MAJOR ' ELSE ' ';
-*
CHK_D5/A1=IF D5 NE D25 THEN 'Y' ELSE 'N';
VERB_D5/A5=IF CHK_D5 EQ 'Y' THEN 'CITY ' ELSE ' ';
-*
CHK_D6/A1=IF D6 NE D26 THEN 'Y' ELSE 'N';
VERB_D6/A6=IF CHK_D6 EQ 'Y' THEN 'STATE ' ELSE ' ';
-*
CHK_D7/A1=IF D7 NE D27 THEN 'Y' ELSE 'N';
VERB_D7/A4=IF CHK_D7 EQ 'Y' THEN 'ZIP ' ELSE ' ';
-*
CHK_D8/A1=IF D8 NE D28 THEN 'Y' ELSE 'N';
VERB_D8/A9=IF CHK_D8 EQ 'Y' THEN 'STREET 1 ' ELSE ' ';
-*
CHK_D9/A1=IF D9 NE D29 THEN 'Y' ELSE 'N';
VERB_D9/A9=IF CHK_D9 EQ 'Y' THEN 'STREET 2 ' ELSE ' ';
-*
CHK_D12/A1=IF D12 NE D32 THEN 'Y' ELSE 'N';
VERB_D12/A10=IF CHK_D12 EQ 'Y' THEN 'PEND EVAL ' ELSE ' ';
-*
CHK_D13/A1=IF D13 NE D33 THEN 'Y' ELSE 'N';
VERB_D13/A8=IF CHK_D13 EQ 'Y' THEN 'FAM HRS ' ELSE ' ';
-*
OUT_FST_LINE1/A80=(D1|(' ')|D2|(' ')|D3|(' ')|D4|(' ')|D10|(' ')|D11|
(' ')|D12|(' ')|D13);
OUT_FST_LINE2/A80=(D8|(' ')|D9);
OUT_FST_LINE3/A80=(D5|(' ')|D6|(' ')|D7);
-*
OUT_SEC_LINE1/A80=(D21|(' ')|D22|(' ')|D23|(' ')|D24|(' ')|D30|(' ')|D31|
(' ')|D32|(' ')|D33);
OUT_SEC_LINE2/A80=(D28|(' ')|D29);
OUT_SEC_LINE3/A80=(D25|(' ')|D26|(' ')|D27);
-*
OUT_THD_LINE/A80=(VERB_D2|VERB_D3|VERB_D4|VERB_D5|VERB_D6|VERB_D7|
VERB_D8|VERB_D9|VERB_D12|VERB_D13);
-*
EXTRA_LINE/A10=' ';
END
TABLE FILE VETHOLD
HEADING CENTER
"VETERAN COMPARISON REPORT FOR TERM &ENRTRM </1"
PRINT OUT_FST_LINE1 AS '' OVER OUT_FST_LINE2 AS '' OVER OUT_FST_LINE3 AS ''
OVER EXTRA_LINE AS '' OVER OUT_SEC_LINE1 AS '' OVER OUT_SEC_LINE2 AS ''
OVER OUT_SEC_LINE3 AS '' OVER EXTRA_LINE AS '' OVER OUT_THD_LINE AS ''
OVER EXTRA_LINE AS '' OVER EXTRA_LINE AS ''
WHERE (CHK_D2 EQ 'Y') OR (CHK_D3 EQ 'Y') OR (CHK_D4 EQ 'Y') OR
(CHK_D5 EQ 'Y') OR (CHK_D6 EQ 'Y') OR (CHK_D7 EQ 'Y') OR
(CHK_D8 EQ 'Y') OR (CHK_D9 EQ 'Y') OR (CHK_D12 EQ 'Y') OR
(CHK_D13 EQ 'Y');
END
JOIN CLEAR *
Master File Description (MFD) for VETHOLD :
FILE=VETHOLD,SUFFIX=FIX SEGNAME=ROOT FIELD=D1 , ,A09,A09,$ FIELD=D2 , ,A32,A32,$ FIELD=D3 , ,A07,A07,$ FIELD=D4 , ,A04,A04,$ FIELD=D5 , ,A13,A13,$ FIELD=D6 , ,A02,A02,$ FIELD=D7 , ,A09,A09,$ FIELD=D8 , ,A32,A32,$ FIELD=D9 , ,A32,A32,$ FIELD=D10, ,A02,A02,$ FIELD=D11, ,A02,A02,$ FIELD=D12, ,A01,A01,$ FIELD=D13, ,A07,A07,$
Master File Description (MFD) for VETCHK :
FILE=VETCHK,SUFFIX=FIX SEGNAME=ROOT FIELD=D21, ,A09,A09,$ FIELD=D22, ,A32,A32,$ FIELD=D23, ,A07,A07,$ FIELD=D24, ,A04,A04,$ FIELD=D25, ,A13,A13,$ FIELD=D26, ,A02,A02,$ FIELD=D27, ,A09,A09,$ FIELD=D28, ,A32,A32,$ FIELD=D29, ,A32,A32,$ FIELD=D30, ,A02,A02,$ FIELD=D31, ,A02,A02,$ FIELD=D32, ,A01,A01,$ FIELD=D33, ,A07,A07,$
This page hosted by 
Get your own Free Homepage