<![CDATA[
-*
-* THIS FOCEXEC WILL LIST OUT THE BENEFITS FOR AN EMPLOYEE.
-*
JOIN CLEAR *
-*
-* RETRIEVE EMPLOYEE ASSIGNMENT
-*
DEFINE FILE EBFILE
THS_DATE/A10='&DATEMDYY';
CONV_DATE/A8=EDIT(THS_DATE,'$$$$$$9999')|EDIT(THS_DATE,'99')|
EDIT(THS_DATE,'$$$99');
-*
JOIN_KEY/A12=('(Site ID)'|EMP_ID_210);
END
TABLE FILE EBFILE
PRINT ASGN_END_DT EARN_210_CD BY JOIN_KEY
-*
-* RETRIEVE CURRENT FULL-TIME EMPLOYEES
-*
WHERE ASGN_END_DT GE CONV_DATE;
-*
-* Substitute the information below with the earnings code(s)
-* for your site's employees.
-*
WHERE EARN_210_CD EQ '010' OR
EARN_210_CD EQ '011' OR
EARN_210_CD EQ '012';
ON TABLE HOLD AS EBTEMP1
END
-*
-* RETRIEVE EMPLOYEE NAME
-*
DEFINE FILE EAFILE
EMP_NAME_HOR/A70=EMP_NAME_PRE||(' '|EMP_NAME_FST||(' '|EMP_NAME_MID||
(' '|EMP_NAME_LST||(' '|EMP_NAME_SUF))))||'*';
TOK_NAME/A32=GETTOK(EMP_NAME_HOR,70,1,'*',32,TOK_NAME);
LJUST_NAME/A32=LJUST(32,TOK_NAME,LJUST_NAME);
-*
JOIN_KEY/A12=('(Site ID)'|EMP_ID_100);
END
TABLE FILE EAFILE
PRINT EMP_NAME_LST LJUST_NAME BY JOIN_KEY
ON TABLE HOLD AS EATEMP1
END
-*
-* RETRIEVE EMPLOYEE BENEFITS
-*
DEFINE FILE EFFILE
JOIN_KEY/A12=('(Site ID)'|EMPR_ID_830);
THS_DATE/A10='&DATEMDYY';
CONV_DATE/A8=EDIT(THS_DATE,'$$$$$$9999')|EDIT(THS_DATE,'99')|
EDIT(THS_DATE,'$$$99');
END
TABLE FILE EFFILE
PRINT EMPR_PLANTY EMPR_PLAN EMPR_COVER EMPR_AMT_PC
EMPR_BGN_DT EMPR_END_DT
BY JOIN_KEY
WHERE EMPR_END_DT GE CONV_DATE;
ON TABLE HOLD AS EFTEMP1
END
-*
-* MERGE EMPLOYEE NAME WITH EMPLOYEE BENEFITS & ASSIGNMENTS
-*
JOIN JOIN_KEY IN EFTEMP1 TO JOIN_KEY IN EATEMP1 AS J1
JOIN JOIN_KEY IN EFTEMP1 TO JOIN_KEY IN EBTEMP1 AS J2
DEFINE FILE EFTEMP1
THS_DATE/A10='&DATEMDYY';
CONV_DATE/A8=EDIT(THS_DATE,'$$$$$$9999')|EDIT(THS_DATE,'99')|
EDIT(THS_DATE,'$$$99');
END
TABLE FILE EFTEMP1
PRINT EMP_NAME_LST LJUST_NAME
EMPR_PLANTY EMPR_PLAN EMPR_COVER EMPR_AMT_PC
EMPR_BGN_DT EMPR_END_DT
BY JOIN_KEY
ON TABLE HOLD AS EFTEMP2
-*
-* RETRIEVE CURRENT FULL-TIME EMPLOYEES
-*
WHERE ASGN_END_DT GE CONV_DATE;
-*
-* Substitute the information below with the earnings code(s)
-* for your site's employees.
-*
WHERE EARN_210_CD EQ '010' OR
EARN_210_CD EQ '011' OR
EARN_210_CD EQ '012';
END
-*
-* CREATE REPORT
-*
DEFINE FILE EFTEMP2
HOR_ID/A9=EDIT(JOIN_KEY,'$$$999999999');
CONV_BGN/A10=EDIT(EMPR_BGN_DT,'$$$$99')|'/'|EDIT(EMPR_BGN_DT,'$$$$$$99')|'/'|
EDIT(EMPR_BGN_DT,'9999');
-*
CONV_END/A10=EDIT(EMPR_END_DT,'$$$$99')|'/'|EDIT(EMPR_END_DT,'$$$$$$99')|'/'|
EDIT(EMPR_END_DT,'9999');
END
TABLE FILE EFTEMP2
HEADING
"DATE RUN &DATEMDYY <+30 Some site
<+23 PROGRAM ID : BENELST"
"TIME RUN &TOD <+36 PAYROLL INFORMATION SYSTEM </1"
-*
PRINT EMPR_PLANTY AS 'Employer,Plan Type' EMPR_PLAN AS 'Employer,Plan Code'
EMPR_COVER AS 'Employer,Coverage' EMPR_AMT_PC AS 'Empr,Amt,Pct'
CONV_BGN AS 'Empr Pay,Begin,Date'
CONV_END AS 'Empr Pay,End,Date'
BY EMP_NAME_LST NOPRINT
BY LJUST_NAME AS 'Employee Name' IN 1
BY HOR_ID AS 'Employee ID'
WHERE EMP_NAME_LST NE '';
END
JOIN CLEAR *
]]>
This page hosted by 
Get your own Free Homepage
