Typical DCL Command Procedure to run the program :

$ DELETE SI$FOCUS:*.FTM;*/LOG
$ DELETE SI$FOCUS:*.MAS;*/LOG
$ DELETE SI$FOCUS:TEMP.DOC;*/LOG
$ COPY SI$FOCUS:PLAY5.MFD; SI$FOCUS:PLAY5.MAS; /LOG
$ DEFINE FOC$DIR1 SI$DATA
$ SET DEFAULT SI$FOCUS
$ FOCUS
EXEC (FOCEXEC name #1) IAWPD=(Financial Aid Award Period), IAWYR=(Financial Aid Award Year)
FIN
$ MERGE/KEY=(POSITION=1,SIZE=9) PLAY2.FTM,PLAY4.FTM TEMP.DOC
$ SORT/KEY=(POSITION=1,SIZE=9)/KEY=(POSITION=15,SIZE=7)/NODUPLICATES -
    TEMP.DOC PLAY5.FTM
$ DELETE/LOG PLAY.FTM;*
$ FOCUS
EXEC (FOCEXEC name #2) IAWPD=(Financial Aid Award Period), IAWYR=(Financial Aid Award Year)
FIN
$ CONVERT/APPEND/PAD=%D32 SI$FOCUS:PLAY.FTM SI$DATA:AIBBFL.DAT
$ EXIT

FOCUS program #1 :

-*  THIS FOCEXEC WILL PRODUCE THE BATCH TRANSACTIONS FOR THOSE STUDENTS
-*  WHO NEED FINANCIAL AID TRANSCRIPT TRACKING.
-*  THIS IS PART ONE OF A TWO PART PROCEDURE.
-*
SET LINES=999999
SET PAGE=OFF
JOIN CLEAR *
JOIN KEY IN RAFILE TO KEY IN AAFILE AS J1
DEFINE FILE RAFILE
  JN_TO_OKAY/A16 = SID_RA|TRNF_SCHL_CD;
END
TABLE FILE RAFILE
  PRINT SID_RA AS '' TRNF_SCHL_CD AS ''
    BY JN_TO_OKAY AS ''
  IF TRNF_CTR_RA GT 0
  IF TRNF_SCHL_CD NE ' '
  IF FAM_LOC_AA EQ 'Y'
  WHERE (RA_040_ORDER LE TRNF_CTR_RA);
  ON TABLE HOLD AS PLAY
END
-*
DEFINE FILE PLAY
  THS_REC/A1=IF TRNF_SCHL_CD NE LAST TRNF_SCHL_CD THEN 'Y' ELSE 'N';
  EXR/A5='     ';
END
TABLE FILE PLAY
  PRINT SID_RA AS '' EXR AS '' TRNF_SCHL_CD AS '' 
  IF THS_REC EQ 'Y'
  ON TABLE SAVE AS PLAY2
END
-*
JOIN KEY IN RBFILE TO KEY IN AAFILE AS J1
DEFINE FILE RBFILE
  JN_TO_OKAY_RB/A16 = SID_RB|PREV_COLL_CD;
END
TABLE FILE RBFILE
  PRINT SID_RB AS '' PREV_COLL_CD AS ''
    BY JN_TO_OKAY_RB AS ''
  IF PRV_COLL_CTR GT 0
  IF PREV_COLL_CD NE ' '
  IF FAM_LOC_AA EQ 'Y'
  WHERE (RB_040_ORDER LE PRV_COLL_CTR);
  ON TABLE HOLD AS PLAY3
END
-*
DEFINE FILE PLAY3
  THS_REC/A1=IF PREV_COLL_CD NE LAST PREV_COLL_CD THEN 'Y' ELSE 'N';
  EXR/A5='     ';
END
TABLE FILE PLAY3
  PRINT SID_RB AS '' EXR AS '' PREV_COLL_CD AS '' 
  IF THS_REC EQ 'Y'
ON TABLE SAVE AS PLAY4
END
JOIN CLEAR *

FOCUS program #2 :

-*  THIS FOCEXEC WILL PRODUCE THE BATCH TRANSACTIONS FOR THOSE STUDENTS
-*  WHO NEED FINANCIAL AID TRANSCRIPT TRACKING.
-*  THIS IS PART TWO OF A TWO PART PROCEDURE.
-*
SET LINES=999999
SET PAGE=OFF
JOIN CLEAR *
MATCH FILE STFILE
  PRINT TRK_FORM
    BY SID_ST AS SID_CODE
  IF TRK_FORM EQ 'PELL'
  IF TRK_CTR_ST GT 0
  IF TRK_AWD_YR EQ '&IAWYR'
  WHERE (ST_020_ORDER LE TRK_CTR_ST);
RUN
FILE PLAY5
  PRINT TRANS_COLL_CD
    BY SID_CODE
-*
-*  LEAVE OUT THOSE CODES THAT ARE NOT 'REAL' INSTITUTIONS LIKE
-*  PLACEMENT TESTS, ETC.
-* 
  IF TRANS_COLL_CD NE '0000001' OR '0000002' OR '0000003' OR '0000004' OR 
                      '0000005' OR '0000006' OR '0000007' OR '0000008' OR                                                                   '0000009'
  AFTER MATCH HOLD OLD-AND-NEW
END
-RUN
-*
DEFINE FILE HOLD
  COMBO_KEY1/A16 = SID_CODE | TRANS_COLL_CD;
END
TABLE FILE HOLD
  PRINT SID_CODE TRANS_COLL_CD
    BY COMBO_KEY1
  ON TABLE HOLD AS PLAY6
END
-*
DEFINE FILE SLFILE
  COMBO_KEY2/A16 = SID_SL | FAT_SCHL_CD;
END
TABLE FILE SLFILE
  PRINT SID_SL FAT_SCHL_CD
    BY COMBO_KEY2
  ON TABLE HOLD AS PLAY7 
  IF FAM_TRAN_CTR GT 0
  WHERE (SL_040_ORDER LE FAM_TRAN_CTR);
END
-*
FILEDEF PLAY DISK PLAY.FTM APPEND
JOIN COMBO_KEY1 IN PLAY6 TO COMBO_KEY2 IN PLAY7 AS J1
DEFINE FILE PLAY6
  BTH_TRANS1/A21 = ('72C'|SID_CODE|'  '|TRANS_COLL_CD); 
END
TABLE FILE PLAY6
  PRINT BTH_TRANS1 IN 1 AS ''
  ON TABLE SAVE AS PLAY
  IF COMBO_KEY2 EQ ' '
END
JOIN CLEAR *

Master File Description (MFD) for PLAY5 :

FILE=PLAY5,SUFFIX=FIX
SEGNAME=ROOT
FIELDNAME=SID_CODE,E01,A09,A09,$
FIELDNAME=EXR,E02,A05,A05,$
FIELDNAME=TRANS_COLL_CD,E03,A07,A07,$

This page hosted by Get your own Free Homepage