FOCUS program :

JOIN CLEAR *
OFFLINE CLOSE
FILEDEF OFFLINE DISK TEMPFILE.DOC
TABLE FILE RTFILE
  PRINT FAM_ATT_HRS
    BY SID_RT
  ON TABLE HOLD AS RTTEMP2
  IF FAM_ATT_HRS GE 12.00
  IF TERM_RT EQ '(Enrollment term)'
  IF TERM_RESD_RT EQ 'CM' OR 'RM'
-*
-*  LEAVE OUT MAJORS THAT ARE NOT ELIGIBLE TO RECIEVE THE GRANT
-*
  WHERE (PRIM_MJR1_RT NE '(Not eligible majors');
END
-*
-*  CUMULATIVE G.P.A. OF 2.0 OR HIGHER
-*
JOIN TEMP_KEY WITH SID_RT IN RTTEMP2 TO KEY IN RPFILE AS J2
DEFINE FILE RTTEMP2
  TEMP_KEY/A11=('XX'|SID_RT);
END
TABLE FILE RTTEMP2
  PRINT FAM_ATT_HRS
    BY SID_RT
  ON TABLE HOLD AS RTTEMP3
  WHERE ((CUM_EARN_HRS GT 00.00) AND (GPA_RP GE 2.0)) OR 
         (CUM_EARN_HRS EQ 00.00);
END
-*
-*  MUST NOT HAVE A BACHELOR'S DEGREE ALREADY
-*
JOIN TEMP_KEY WITH SID_RT IN RTTEMP3 TO KEY IN SAFILE AS J3
DEFINE FILE RTTEMP3
  TEMP_KEY/A13=('(Financial Aid Award Year)XX'|SID_RT);
END
TABLE FILE RTTEMP3
  PRINT FAM_ATT_HRS PGI_PRIM
    BY SID_RT
  ON TABLE HOLD AS RTTEMP4
  IF AWD_YR_SA EQ '(Financial Aid Award Year)'
  IF PELL_SEG_CTR GT 0
  IF PL_S_DEG_JLY NE 'Y'
END
-*
-*  MUST BE HAVING SATISFACTORY ACADEMIC PROGRESS
-*
MATCH FILE RTTEMP4
  PRINT FAM_ATT_HRS PGI_PRIM
    BY SID_RT AS SID_CODE
RUN
FILE SAFILE
  PRINT NON_TITLE4
    BY SID_SA AS SID_CODE
  IF AWD_YR_SA EQ '(Financial Aid Award Year)'
  IF PKG_AWPD EQ '(Financial Aid Award Period)'
  IF PKG_SEG_CTR GT 0
  IF RAP_CD_SA NE '4'
  WHERE SA_020_ORDER EQ 1;
  AFTER MATCH HOLD OLD-AND-NEW
END
-RUN
-*
-*  MUST HAVE ALL ITEMS ON SCREEN 306 COMPLETE EXCEPT FOR (Tracking
-*  Item for internal financial aid form), (Tracking Item for student
-*  loan entrance interview), (Tracking Item for award letter response),
-*  AND (Tracking Item for SC Needs Based Grant).
-*
DEFINE FILE STFILE
  INC_FLG/A1=IF (TRK_FORM NE '(Tracking Item for internal financial aid form)') AND (TRK_FORM NE '(Tracking Item for student loan entrance interview)') AND
                (TRK_FORM NE '(Tracking Item for award letter response)') AND (TRK_FORM NE '(Tracking Item for SC Needs Based Grant)') AND 
                (TRK_STAT_ST NE 'C') AND (TRK_STAT_ST NE 'W') THEN 'Y'
                                                              ELSE 'N';
END
TABLE FILE STFILE
  PRINT TRK_FORM
    BY SID_ST 
  ON TABLE HOLD AS STTEMP1
  IF INC_FLG EQ 'Y'
  IF TRK_CTR_ST GT 0
  IF TRK_AWD_YR EQ '(Financial Aid Award Year)'
  IF TRK_AWPD EQ '(Financial Aid Award Period)'
  WHERE (ST_020_ORDER LE TRK_CTR_ST);
END
-*
DEFINE FILE STTEMP1
  THS_REC/A1=IF SID_ST NE LAST SID_ST THEN 'Y' ELSE 'N';
END
TABLE FILE STTEMP1
  PRINT TRK_FORM
    BY SID_ST 
  ON TABLE HOLD AS STTEMP2
  IF THS_REC EQ 'Y'
END
-*
MATCH FILE HOLD
  PRINT FAM_ATT_HRS PGI_PRIM NON_TITLE4
    BY SID_CODE
RUN
FILE STTEMP2
  PRINT TRK_FORM 
    BY SID_ST AS SID_CODE
  AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
-*
-*  MUST HAVE COMPLETED VALID FAFSA ON FILE
-*
MATCH FILE HOLD
  PRINT FAM_ATT_HRS PGI_PRIM NON_TITLE4
    BY SID_CODE
RUN
FILE STFILE
  SUM TRK_AWPD
    BY SID_ST AS SID_CODE
  IF TRK_CTR_ST GT 0
  IF TRK_AWD_YR EQ '(Financial Aid Award Year)'
  IF TRK_AWPD EQ '(Financial Aid Award Period)'
  WHERE ((TRK_FORM EQ 'PELL') AND (TRK_STAT_ST EQ 'C' OR 'W'));
  WHERE (ST_020_ORDER LE TRK_CTR_ST);
  AFTER MATCH HOLD OLD-AND-NEW
END
-RUN
JOIN CLEAR *
-*
-*  DETERMINE NEED
-*
-*  COMPUTE FIGURE FROM VALUES ON SCREEN 312
-*
MATCH FILE HOLD
  PRINT FAM_ATT_HRS PGI_PRIM NON_TITLE4
    BY SID_CODE
RUN
FILE SAFILE
  PRINT N1_TOT_BDGT LOAN_FEE_N1 N1_OTH_RSRCS N1_VET_BEN N1_OTH_AID
    BY SID_SA AS SID_CODE
  IF AWD_YR_SA EQ '(Financial Aid Award Year)'
  IF BDGT_AWPD EQ '(Financial Aid Award Period)'
  IF BDGT_SEG_CTR GT 0
  WHERE SA_040_ORDER EQ 1;
  AFTER MATCH HOLD OLD-AND-NEW
END
-RUN
-*
DEFINE FILE HOLD
  FIG_FST/P06C=N1_TOT_BDGT-LOAN_FEE_N1-PGI_PRIM-N1_OTH_RSRCS-N1_VET_BEN-
               N1_OTH_AID-NON_TITLE4;
END
TABLE FILE HOLD
  PRINT FAM_ATT_HRS PGI_PRIM FIG_FST
    BY SID_CODE
  ON TABLE HOLD AS HOLDTEMP
END
-*
-*  SUBSTRACT EVERYTHING FROM SCREEN 318 EXCEPT WORKSTUDY, SUBSIDIZED LOAN, AND
-*  UNSUBSIDIZED LOAN.
-*
TABLE FILE SWFILE
  SUM AWPD_OFF FUND_NUM_SW
    BY SID_SW
  ON TABLE HOLD AS SWTEMP1
  IF AWD_YR_SW EQ '(Financial Aid Award Year)'
  IF AWPD_OFF GT 00.00
  IF AWPD_ID EQ '(Financial Aid Award Period)'
  IF FUND_NUM_SW NE '(Subcode for Workstudy)' OR '(Subcode for Subsidized Loans)' OR '(Subcode for Unsubsidized Loans)'
END
-*
MATCH FILE HOLDTEMP
  PRINT FAM_ATT_HRS PGI_PRIM FIG_FST
    BY SID_CODE
RUN
FILE SWTEMP1
  PRINT AWPD_OFF
    BY SID_SW AS SID_CODE
  AFTER MATCH HOLD OLD
END
-RUN
-*
DEFINE FILE HOLD
  UNMEET_NEED_FST/P08C=FIG_FST-AWPD_OFF;
END
TABLE FILE HOLD
  PRINT UNMEET_NEED_FST FAM_ATT_HRS PGI_PRIM FIG_FST
    BY SID_CODE
  ON TABLE HOLD AS HOLDTEM2
END
-*
-*  LEAVE OUT THOSE WHO HAVE ALREADY BEEN AWARDED THE GRANT.
-*
TABLE FILE SWFILE
  PRINT AWPD_OFF FUND_NUM_SW
    BY SID_SW
  ON TABLE HOLD AS SWTEMP2
  IF AWD_YR_SW EQ '(Financial Aid Award Year)'
  IF AWPD_OFF GT 00.00
  IF AWPD_ID EQ '(Financial Aid Award Period)'
  IF FUND_NUM_SW EQ '(Subcode for SC Needs Based Grant)'
END
-*
MATCH FILE HOLDTEM2
  PRINT UNMEET_NEED_FST FAM_ATT_HRS PGI_PRIM FIG_FST
    BY SID_CODE
RUN
FILE SWTEMP2
  PRINT AWPD_OFF AS SCNBG_AWD_OFF
    BY SID_SW AS SID_CODE
  AFTER MATCH HOLD OLD
END
-RUN
-*
JOIN CLEAR *
JOIN TEMP_KEY WITH SID_CODE IN HOLD TO KEY IN AAFILE AS J1
DEFINE FILE HOLD
  TEMP_KEY/A11=('XX'|SID_CODE);
END
TABLE FILE HOLD
  PRINT STU_NAME_AA SID_CODE AS 'Student ID' 
        SCNBG_AWD_OFF AS 'Amount,Awarded'
        UNMEET_NEED_FST AS 'Unmeet, Need' 
  BY HIGHEST PGI_PRIM
  WHERE PGI_PRIM GT 00.00
  WHERE UNMEET_NEED GE 00.00;
  WHERE SCNBG_AWD_OFF EQ 00.00
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage