Typical DCL Command Procedure to run the program :

$ DELETE SI$FOCUS:*.FTM;*/LOG
$ DELETE SI$FOCUS:*.MAS;*/LOG
$ DEFINE FOC$DIR1 SI$DATA
$ SET DEFAULT SI$FOCUS
$ FOCUS
EXEC (FOCEXEC name) AWDYR=(Financial Aid Award Year), ETERM1=(First Enrollment Term), ETERM2=(Second Enrollment Term)
FIN
$ SET DEFAULT Z$PRT
$ RENAME TEMPFILE.DOC (FOCEXEC name).PRT /LOG
$ EXIT

FOCUS program :

-*  THIS FOCEXEC WILL LIST THOSE FINANCIAL AID STUDENTS WHO HAVE 
-*  CHANGED THEIR MAJOR IN THE PAST TWO TERMS.
-*    VARIABLES USED:
-*      AWDYR        : THE AWARD YEAR TO SELECT FROM
-*      ETERM1       : THE FIRST ENROLLMENT TERM TO SELECT FROM
-*      ETERM2       : THE SECOND ENROLLMENT TERM TO SELECT FROM
-*
OFFLINE CLOSE
FILEDEF OFFLINE DISK Z$PRT:TEMPFILE.DOC
JOIN CLEAR *
DEFINE FILE SAFILE
JN_KEY1/A14=('&ETERM1'|INSTIT_SA|SID_SA);
JN_KEY2/A14=('&ETERM2'|INSTIT_SA|SID_SA);
CHK_FLD1/A3=('&AWDYR'|'A');
CHK_FLD2/A3=('&AWDYR'|'S');
END
TABLE FILE SAFILE
PRINT JN_KEY1 JN_KEY2 BY SID_SA
ON TABLE HOLD AS SATEMP1
IF AWD_YR_SA EQ '&AWDYR'
IF TOT_AID_PKG GT 00.00
IF PKG_SEG_CTR GT 0
WHERE (PKG_AWPD EQ CHK_FLD1) OR (PKG_AWPD EQ CHK_FLD2);
END
JOIN JN_KEY1 IN SATEMP1 TO ROOT_KEY_RT IN RTFILE AS J1
TABLE FILE SATEMP1
PRINT PRIM_MJR1_RT BY SID_RT
ON TABLE HOLD AS SATEMP2
IF TERM_RT EQ '&ETERM1'
END
JOIN CLEAR *
JOIN JN_KEY2 IN SATEMP1 TO ROOT_KEY_RT IN RTFILE AS J2
TABLE FILE SATEMP1
PRINT PRIM_MJR1_RT BY SID_RT
ON TABLE HOLD AS SATEMP3
IF TERM_RT EQ '&ETERM2'
END
MATCH FILE SATEMP2
PRINT PRIM_MJR1_RT AS MAJOR_FST_TRM BY SID_RT AS SID_CODE
RUN
FILE SATEMP3
PRINT PRIM_MJR1_RT AS MAJOR_SND_TRM BY SID_RT AS SID_CODE
AFTER MATCH HOLD OLD-AND-NEW
END
-RUN
JOIN TEMP_KEY WITH SID_CODE IN HOLD TO KEY IN AAFILE AS J1
DEFINE FILE HOLD
TEMP_KEY/A11=('XX'|SID_CODE);
END
TABLE FILE HOLD
HEADING
"<50 FINANCIAL AID PROGRAM CHANGE REPORT </1"
PRINT SID_CODE AS 'Student ID' IN 60
      MAJOR_FST_TRM AS 'Major,1st Term' IN 90
      MAJOR_SND_TRM AS 'Major,2nd Term' 
BY STU_NAME_AA AS 'Student Name' IN 20
WHERE MAJOR_FST_TRM NE MAJOR_SND_TRM;
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage