Typical DCL Command Procedure to run the program :  

$!
$!  THIS COMMAND PROCEDURE RUNS THE FOCEXEC FOR THE
$!  FINANCIAL AID COMMONLINE GRADUATION DATE UPDATE.
$!
$ SAY :== "WRITE SYS$OUTPUT"
$ DELETE SI$FEX:*.FTM;*/LOG
$ DELETE SI$FEX:*.MAS;*/LOG
$ DEFINE FOC$DIR2 SI$DATA, SI$MFD
$ SET DEFAULT SI$FEX
$ FOCUS
EXEC (FOCEXEC name) AWD_PER=(Award Period), AWD_YR=(Award Year)
FIN
$!
$!  Skip SBA300 if no file to be processed.
$!
$ IF F$SEARCH("SI$FEX:AATEMP2.FTM;") .EQS. ""
$ THEN
$     SAY " "
$     SAY "NO COMMONLINE APPLICATION FILE TO PROCESS..."
$     SAY " "
$     GOTO PGM_EXIT
$ ELSE
$     CONVERT/APPEND SI$FEX:PLAY.FTM SI$DATA:AIB2FL.DAT
$     SUBMIT/QUE=SYS$FAST/AFTER=(sometime afterwards) SI$COM:SJA300
$ ENDIF
$!
$PGM_EXIT:
$!
$ EXIT


FOCUS program :

-*
SET PAGE = NOPAGE
SET LINES = 999999
JOIN CLEAR *
-*
-*  Get graduation date for active terms
-*
FILEDEF ACFL054 DISK SI$DATA:ACFILE.DAT
DEFINE FILE ACFL054
CONV_GRAD_DT/A8=EDIT(GRADUATION_DATE);
OUTLINE/A78=(TERM_CODE_CAL|' '''|CONV_GRAD_DT||''' ');
END
TABLE FILE ACFL054
PRINT OUTLINE AS ''
WHERE GRADUATION_DATE NE 00000000;
ON TABLE SAVE AS TRMGRAD
END
-RUN
-*
-*  Create The Batch Header
-*
-SET &HDRKEY = '$$$FIN601        UPD GRAD DATE  YFA';
-INCLUDE (SIS Batch Header).SEG
-*
-*  Retrieve students whose CommonLine anticipated graduation
-*  date is blank
-*
TABLE FILE SGFILE
PRINT LOAN_ID AWD_YR BY STU_ID
ON TABLE HOLD AS SGTEMP1
WHERE LN_RQST_AMT NE 0;
WHERE EXPCT_GRAD_DT EQ 00000000;
WHERE CMLN_RECIP_XREF EQ 'A';
WHERE LENDR EQ '(Lender ID)';
WHERE AWD_YR EQ '&AWD_YR';
END
-*
-*  Get all open matriculations
-*
JOIN STU_ID IN SGTEMP1 TO KEY IN AAFILE AS J1
TABLE FILE SGTEMP1
PRINT LOAN_ID AWD_YR BY STU_ID BY HIGHEST EXIT_TERM
ON TABLE HOLD AS AATEMP1
WHERE COLLEGE NE 'CE';
WHERE EXIT_ACTION NE 'GD';
WHERE AA060_ORDER LE AP_CNTR;
END
-*
-*  Remove duplicates
-*
DEFINE FILE AATEMP1
THS_REC/A1=IF STU_ID NE LAST STU_ID THEN 'Y' ELSE 'N';
END
TABLE FILE AATEMP1
PRINT LOAN_ID AWD_YR BY STU_ID BY EXIT_TERM
ON TABLE HOLD AS AATEMP2
WHERE THS_REC EQ 'Y';
END
-*
-*  Create batch transactions to update CommonLine anticipated graduation
-*  date
-*
FILEDEF GRADFL DISK TRMGRAD.FTM
DEFINE FILE AATEMP2
DEC_GRAD_DT/A8=DECODE EXIT_TERM(GRADFL ELSE '****');
FMT_GRD_DT/A8=EDIT(DEC_GRAD_DT,'$$$$99')|EDIT(DEC_GRAD_DT,'$$$$$$99')|
              EDIT(DEC_GRAD_DT,'9999');
BTH_TRANS/A80 = ('84F'|STU_ID|'  '|AWD_YR|'&AWD_PER'|EDIT(LOAN_ID,'9999')|
'                              '|FMT_GRD_DT);
END
TABLE FILE AATEMP2
PRINT BTH_TRANS BY STU_ID NOPRINT
ON TABLE SAVE AS PLAY
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage