FOCUS program :

-*begin doc
-*
-*FEX:  FA-AWD-TRK-INC
-*
-*input
-*      Award Year
-*
-*
-*      This report lists students who are awarded but their 
-*      tracking information on screen 306 is not complete.
-*
-*
-*end doc
-*
SET LINES=56
-PROMPT &AWD_YR/A4.ENTER THE FOUR DIGIT AWARD YEAR (CCYY) :
JOIN CLEAR *
-*
-*  Select all students who have incomplete tracking on screen 306.
-*
TABLE FILE STFILE
PRINT AWD_YR BY STU_ID
WHERE AWD_YR EQ '&AWD_YR';
WHERE TRK_FORM NE '';
WHERE TRK_STAT EQ '';
WHERE TRK_CNTR GT 0;
ON TABLE HOLD AS STTEMP1
END
-*
-*  Remove duplicates.
-*
DEFINE FILE STTEMP1
THS_REC/A1=IF STU_ID NE LAST STU_ID THEN 'Y' ELSE 'N';
END
TABLE FILE STTEMP1
PRINT AWD_YR BY STU_ID
WHERE THS_REC EQ 'Y';
ON TABLE HOLD AS STTEMP2
END
-*
-*  Select students with a valid award on screen 318.
-*
TABLE FILE SWFILE
PRINT SW_FUND BY STU_ID
WHERE (AWD_STAT EQ 'A') OR (AWD_STAT EQ 'O');
WHERE AWD_YR EQ '&AWD_YR';
ON TABLE HOLD AS SWTEMP1
END
-*
-*  Remove duplicates.
-*
DEFINE FILE SWTEMP1
THS_REC/A1=IF STU_ID NE LAST STU_ID THEN 'Y' ELSE 'N';
END
TABLE FILE SWTEMP1
PRINT SW_FUND BY STU_ID
WHERE THS_REC EQ 'Y';
ON TABLE HOLD AS SWTEMP2
END
-*
-*  Select students who are awarded but their tracking  
-*  information on screen 306 is not complete.
-*
MATCH FILE STTEMP2
PRINT AWD_YR BY STU_ID
RUN
FILE SWTEMP2
PRINT SW_FUND BY STU_ID
AFTER MATCH HOLD OLD-AND-NEW
END
-RUN
-*
-*  Retrieve student name and produce report.
-*
JOIN STU_ID IN HOLD TO STU_ID IN AAFILE AS J1
TABLE FILE HOLD
HEADING CENTER
"DATE: &DATE  TIME: &TOD  Report Name: FA-AWD-TRK-INC" 
" "
"Financial Aid Students Awarded But With Tracking Not Complete"
" "
PRINT STU_ID AS 'Student Id' STU_NAME
ON TABLE HOLD AS REPORT FORMAT WP
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage