FOCUS program (Institutional Budget) :
-*begin doc
-*
-*FEX: FA50_INBUD01
-*
-* This FOCUS program will produce the batch transactions in order to
-* establish budgets for the institutional budget code 01.
-* The selection criteria is as follows : in county/living with parents
-* or relatives.
-*
-*INPUT
-* Award Year
-* Award Period
-*
-*end doc
-**********************************************************************
-*
-SET &HDRKEY = (Batch Header Id);
-SET &IAWYR = (Financial Aid Award Year);
-SET &IAWPD = (Financial Aid Award Period);
JOIN CLEAR *
-*
-* Create batch header
-*
-INCLUDE IR_BATCH_HEADER_FA.SEG
=======================================================================
-*begin doc
-*
-*FEX: IR_BATCH_HEADER.SEG
-*
-* This FOCUS segment will produce the batch header based upon
-* the input parameters.
-*
-*INPUT
-* Batch Header Key : Information To Be Used Within Batch Header.
-*
-*end doc
-**********************************************************************
-*
JOIN CLEAR *
SET LINES=999999
SET PAGE=NOPAGE
FILEDEF HLDTRANS DISK HLDTRANS.FTM APPEND LREC 80 RECFM F
-*
-* Create The Batch Header
-*
DEFINE FILE AAFILE
BH1/A35 = '$$$FIN'||'&HDRKEY'|' FAM TRACK'||'&HDRKEY'|' YFA';
BH2/A45 = ' ';
BATCH_HEADER/A80=BH1|BH2;
END
TABLE FILE AAFILE
PRINT BATCH_HEADER
BY STU_ID NOPRINT
IF RECORDLIMIT EQ 1
ON TABLE SAVE AS HLDTRANS
END
JOIN CLEAR *
=======================================================================
-*
-* Select eligible financial aid students.
-*
TABLE FILE SAFILE
PRINT ROOT_KEY
IF AWD_YR EQ '&IAWYR'
IF PKG_CNTR GT 0
IF PELL_CNTR GT 0
ON TABLE HOLD AS SATEMP1
END
-*
JOIN ROOT_KEY IN SATEMP1 TO ROOT_KEY IN SAFILE AS J1
TABLE FILE SATEMP1
PRINT ROOT_KEY
WHERE (PKG_STAT EQ ' ') OR (PKG_STAT EQ '0') OR (PKG_STAT EQ '1') OR
(PKG_STAT EQ '2') OR (PKG_STAT EQ '3') OR (PKG_STAT EQ '4');
WHERE AWD_PER EQ '&IAWPD';
WHERE SA002_ORDER LE 2;
ON TABLE HOLD AS SATEMP2
END
-*
-* Select students who meet the selection criteria of : living with parents
-* or relatives.
-*
JOIN ROOT_KEY IN SATEMP2 TO ROOT_KEY IN SAFILE AS J2
TABLE FILE SATEMP2
PRINT PELL_INFO_SOURCE BY STU_ID
IF PELL_INFO_SOURCE EQ 'P' OR '0' OR '1' OR '2'
IF HOUS_STAT EQ '3' OR ' ' OR '1'
ON TABLE HOLD AS SATEMP3
END
-*
-* Select students who meet the selection criteria of : in county.
-*
JOIN STU_ID IN SATEMP3 TO STU_ID IN MMFILE AS J3
TABLE FILE SATEMP3
PRINT STU_ID
IF RESIDENT_STAT EQ 'I'
ON TABLE HOLD AS SATEMP4
END
-*
-* Create the batch transactions to establish budgets.
-*
DEFINE FILE SATEMP4
BTH_TRANS1/A26 = ('75A'|STU_ID|' '|'&IAWYR'|'&IAWPD'|' '|'01');
BTH_TRANS2/A54 = '01320 01523 00534 01376 00000 00633 ';
BTH_TRANS3/A41 = ('73B'|STU_ID|' '|'&IAWPD'|' 001200001200');
BTH_TRANS4/A39 = ' ';
END
TABLE FILE SATEMP4
PRINT BTH_TRANS1 IN 1 AS '' BTH_TRANS2 AS ''
ON TABLE SAVE AS HLDTRANS
END
-*
TABLE FILE SATEMP4
PRINT BTH_TRANS3 IN 1 AS '' BTH_TRANS4 AS ''
ON TABLE SAVE AS HLDTRANS
END
JOIN CLEAR *
FOCUS program (Pell Budget) :
-*begin doc
-*
-*FEX: FA60_PEBUD01
-*
-* This FOCUS program will produce the batch transactions in order to
-* establish amounts for the specified Pell budget.
-* The selection criteria is as follows : in county/living with parents
-* or relatives.
-*
-*INPUT
-* Award Year
-* Award Period
-*
-*end doc
-**********************************************************************
-*
-SET &HDRKEY = (Batch Header Id);
-SET &IAWYR = (Financial Aid Award Year);
-SET &IAWPD = (Financial Aid Award Period);
JOIN CLEAR *
-*
-* Create batch header
-*
-INCLUDE IR_BATCH_HEADER_FA.SEG
=======================================================================
-*begin doc
-*
-*FEX: IR_BATCH_HEADER.SEG
-*
-* This FOCUS segment will produce the batch header based upon
-* the input parameters.
-*
-*INPUT
-* Batch Header Key : Information To Be Used Within Batch Header.
-*
-*end doc
-**********************************************************************
-*
JOIN CLEAR *
SET LINES=999999
SET PAGE=NOPAGE
FILEDEF HLDTRANS DISK HLDTRANS.FTM APPEND LREC 80 RECFM F
-*
-* Create The Batch Header
-*
DEFINE FILE AAFILE
BH1/A35 = '$$$FIN'||'&HDRKEY'|' FAM TRACK'||'&HDRKEY'|' YFA';
BH2/A45 = ' ';
BATCH_HEADER/A80=BH1|BH2;
END
TABLE FILE AAFILE
PRINT BATCH_HEADER
BY STU_ID NOPRINT
IF RECORDLIMIT EQ 1
ON TABLE SAVE AS HLDTRANS
END
JOIN CLEAR *
=======================================================================
-*
-* Select eligible financial aid students.
-*
TABLE FILE SAFILE
PRINT ROOT_KEY
IF AWD_YR EQ '&IAWYR'
IF PKG_CNTR GT 0
IF PELL_CNTR GT 0
ON TABLE HOLD AS SATEMP1
END
-*
JOIN ROOT_KEY IN SATEMP1 TO ROOT_KEY IN SAFILE AS J1
TABLE FILE SATEMP1
PRINT ROOT_KEY
WHERE (PKG_STAT EQ ' ') OR (PKG_STAT EQ '0') OR (PKG_STAT EQ '1') OR
(PKG_STAT EQ '2') OR (PKG_STAT EQ '3') OR (PKG_STAT EQ '4');
WHERE AWD_PER EQ '&IAWPD';
WHERE SA002_ORDER LE 2;
ON TABLE HOLD AS SATEMP2
END
-*
-* Select students who meet the selection criteria of : living with parents
-* or relatives.
-*
JOIN ROOT_KEY IN SATEMP2 TO ROOT_KEY IN SAFILE AS J2
TABLE FILE SATEMP2
PRINT PELL_INFO_SOURCE BY STU_ID
IF PELL_INFO_SOURCE EQ 'P' OR '0' OR '1' OR '2'
IF HOUS_STAT EQ '3' OR ' ' OR '1'
ON TABLE HOLD AS SATEMP3
END
-*
-* Select students who meet the selection criteria of : in county.
-*
JOIN STU_ID IN SATEMP3 TO STU_ID IN MMFILE AS J3
TABLE FILE SATEMP3
PRINT STU_ID
IF RESIDENT_STAT EQ 'I'
ON TABLE HOLD AS SATEMP4
END
-*
-* Create the batch transactions to establish budgets.
-*
DEFINE FILE SATEMP4
BTH_TRANS1/A26 = ('76B'|STU_ID|' '|'&IAWYR');
BTH_TRANS2/A54 = ' 0132004066 ';
END
TABLE FILE SATEMP4
PRINT BTH_TRANS1 IN 1 AS '' BTH_TRANS2 AS ''
ON TABLE SAVE AS HLDTRANS
END
JOIN CLEAR *
This page hosted by 
Get your own Free Homepage