FOCUS program(s) :
-*
-* These FOCUS programs are used to correct award and financial aid
-* data in conjunction with PARS.
-*
-*
-* This FOCUS program will create batch transactions to delete
-* awards for the specified fund/award year/students.
-*
JOIN CLEAR *
-SET &AWD_YR = '(Input Award Year)';
-SET &IAWPD = '(Input Award Period)';
SET LINES=999999
SET PAGE=NOPAGE
FILEDEF FAATB DISK FAATB.FTM APPEND LREC 83 RECFM F
-*
-* Create The Batch Header
-*
DEFINE FILE AAFILE
BATCH_HEADER1/A40 = '$$$MSC652 FA CAN AWD YFA ';
BATCH_HEADER2/A43 = ' ';
END
TABLE FILE AAFILE
PRINT BATCH_HEADER1 AS ''
BATCH_HEADER2 AS ''
BY STU_ID NOPRINT
ON TABLE SAVE AS FAATB
IF RECORDLIMIT EQ 1
END
-*
DEFINE FILE SWFILE
TEMP_KEY/A13 = '&AWD_YR'|STU_ID;
BTH_TRANS1/A83 = ('80D'|STU_ID|' '|'&IAWPD'|SW_FUND|SW_PAY_CD|MSG_CD);
END
TABLE FILE SWFILE
PRINT BTH_TRANS1 IN 1 AS ''
ON TABLE SAVE AS FAATB
WHERE SW_FUND EQ '(Subcode Of Award To Cancel)';
WHERE AWD_YR EQ '(Input Award Year)';
END
JOIN CLEAR *
-*
-* This FOCUS program will create batch transactions to cancel awards
-* and then re-post them in "offered" status for the specified fund/award
-* year/students.
-*
JOIN CLEAR *
-SET &AWD_YR = '(Input Award Year)';
-SET &IAWPD = '(Input Award Period)';
SET LINES=999999
SET PAGE=NOPAGE
FILEDEF FAATB DISK FAATB.FTM APPEND LREC 83 RECFM F
-*
-* Create The Batch Header
-*
DEFINE FILE AAFILE
BATCH_HEADER1/A40 = '$$$MSC662 CH NBG AWD YFA ';
BATCH_HEADER2/A43 = ' ';
END
TABLE FILE AAFILE
PRINT BATCH_HEADER1 AS ''
BATCH_HEADER2 AS ''
BY STU_ID NOPRINT
ON TABLE SAVE AS FAATB
IF RECORDLIMIT EQ 1
END
-*
DEFINE FILE SWFILE
BTH_TRANS1/A83 = ('80C'|STU_ID|' '|'&IAWPD'|SW_FUND);
END
TABLE FILE SWFILE
PRINT BTH_TRANS1 IN 1 AS ''
WHERE SW_FUND EQ '(Subcode Of Award To Cancel)'
WHERE AWD_YR EQ '(Input Award Year)';
WHERE AWD_STAT EQ 'A';
ON TABLE SAVE AS FAATB
END
-*
DEFINE FILE SWFILE
ALP_AMT1/A9=EDIT(TOT_AMT);
ALP_AMT2/A5=EDIT(ALP_AMT1,'$$$$99999');
BTH_TRANS1/A83 = ('80O'|STU_ID|' '|'&IAWPD'|SW_FUND|SW_PAY_CD|
MSG_CD|LNDR|ALP_AMT2|'00');
END
TABLE FILE SWFILE
PRINT BTH_TRANS1 IN 1 AS ''
WHERE SW_FUND EQ '(Subcode Of Award To Offer)'
WHERE AWD_YR EQ '(Input Award Year)';
WHERE AWD_STAT EQ 'A';
ON TABLE SAVE AS FAATB
END
JOIN CLEAR *
-*
-* This FOCUS program will create batch transactions to change award
-* status from "offered" to "accepted" for the specified fund/award
-* year/students.
-*
JOIN CLEAR *
-SET &AWD_YR = '(Input Award Year)';
-SET &IAWPD = '(Input Award Period)';
SET LINES=999999
SET PAGE=NOPAGE
FILEDEF FAATB DISK FAATB.FTM APPEND LREC 83 RECFM F
-*
-* Create The Batch Header
-*
DEFINE FILE AAFILE
BATCH_HEADER1/A40 = '$$$MSC656 CH SEO AWD YFA ';
BATCH_HEADER2/A43 = ' ';
END
TABLE FILE AAFILE
PRINT BATCH_HEADER1 AS ''
BATCH_HEADER2 AS ''
BY STU_ID NOPRINT
ON TABLE SAVE AS FAATB
IF RECORDLIMIT EQ 1
END
-*
DEFINE FILE SWFILE
BTH_TRANS1/A83 = ('80A'|STU_ID|' '|'&IAWPD'|SW_FUND);
END
TABLE FILE SWFILE
PRINT BTH_TRANS1 IN 1 AS ''
WHERE SW_FUND EQ '(Subcode Of Award To Offer/Accept)'
WHERE AWD_YR EQ '(Input Award Year)';
WHERE (AWD_STAT EQ 'O');
ON TABLE SAVE AS FAATB
END
JOIN CLEAR *
-*
-* This FOCUS program will create batch transactions to cancel awards
-* on students who were awarded from one fund when actually they
-* should had been awarded from two funds.
-*
JOIN CLEAR *
-SET &AWD_YR = '(Input Award Year)';
-SET &IAWPD = '(Input Award Period)';
SET LINES=999999
SET PAGE=NOPAGE
FILEDEF FAATB DISK FAATB.FTM APPEND LREC 83 RECFM F
-*
-* Create The Batch Header
-*
DEFINE FILE AAFILE
BATCH_HEADER1/A40 = '$$$MSC652 FA CAN AWD YFA ';
BATCH_HEADER2/A43 = ' ';
END
TABLE FILE AAFILE
PRINT BATCH_HEADER1 AS ''
BATCH_HEADER2 AS ''
BY STU_ID NOPRINT
ON TABLE SAVE AS FAATB
IF RECORDLIMIT EQ 1
END
-*
-* Select students not awarded from 1st fund.
-*
TABLE FILE SWFILE
PRINT SW_FUND BY STU_ID
WHERE SW_FUND NE '(Subcode #1 Of Award To Adjust)'
WHERE AWD_YR EQ '(Input Award Year)';
ON TABLE HOLD AS SWTEMP1
END
-*
-* Remove duplicates.
-*
DEFINE FILE SWTEMP1
THS_REC/A1=IF STU_ID NE LAST STU_ID THEN 'Y' ELSE 'N';
END
TABLE FILE SWTEMP1
PRINT SW_FUND BY STU_ID
WHERE THS_REC EQ 'Y';
ON TABLE HOLD AS SWTEMP2
END
-*
-* Select students not awarded from 1st fund or 2nd fund.
-*
MATCH FILE SWTEMP2
PRINT SW_FUND BY STU_ID
RUN
FILE SWFILE
PRINT SW_FUND BY STU_ID
WHERE SW_FUND EQ '(Subcode #2 Of Award To Adjust)'
WHERE AWD_YR EQ '(Input Award Year)';
AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
-*
JOIN TEMP_KEY WITH STU_ID IN HOLD TO SUBKEY1_SW IN SWFILE AS J1
DEFINE FILE HOLD
TEMP_KEY/A13 = '&AWD_YR'|STU_ID;
BTH_TRANS1/A83 = ('80D'|STU_ID|' '|'&IAWPD'|SW_FUND|SW_PAY_CD|MSG_CD);
END
TABLE FILE HOLD
PRINT BTH_TRANS1 IN 1 AS ''
ON TABLE SAVE AS FAATB
WHERE (SW_FUND EQ '(Subcode #1 Of Award To Adjust)') OR
(SW_FUND EQ '(Subcode #2 Of Award To Adjust)');
WHERE (AWD_STAT EQ 'C');
END
JOIN CLEAR *
-*
-* This FOCUS program will create batch transactions to clear out
-* packaging and award letter status of those students who were not
-* awarded by PARS.
-*
JOIN CLEAR *
-SET &AWD_YR = '(Input Award Year)';
-SET &IAWPD = '(Input Award Period)';
SET LINES=999999
SET PAGE=NOPAGE
FILEDEF FAATB DISK FAATB.FTM APPEND LREC 83 RECFM F
-*
-* Create The Batch Header
-*
DEFINE FILE AAFILE
BATCH_HEADER1/A40 = '$$$MSC515 FA ATB UPD YFA ';
BATCH_HEADER2/A43 = ' ';
END
TABLE FILE AAFILE
PRINT BATCH_HEADER1 AS ''
BATCH_HEADER2 AS ''
BY STU_ID NOPRINT
ON TABLE SAVE AS FAATB
IF RECORDLIMIT EQ 1
END
-*
MATCH FILE SAFILE
PRINT PKG_STAT BY STU_ID
WHERE (PKG_STAT EQ '5') OR (PKG_STAT EQ '6');
WHERE AWD_YR EQ '(Input Award Year)';
RUN
FILE SWFILE
PRINT SW_FUND BY STU_ID
WHERE AWD_YR EQ '(Input Award Year)';
AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
-*
DEFINE FILE HOLD
BTH_TRANS1/A83 = ('73B'|STU_ID|' '|'&IAWPD'|' '|
' * *');
BTH_TRANS2/A83 = ('73C'|STU_ID|' '|'&IAWPD'|' *');
END
TABLE FILE HOLD
PRINT BTH_TRANS1 IN 1 AS ''
ON TABLE SAVE AS FAATB
END
-*
TABLE FILE HOLD
PRINT BTH_TRANS2 IN 1 AS ''
ON TABLE SAVE AS FAATB
END
JOIN CLEAR *
This page hosted by 
Get your own Free Homepage