FOCUS program :

JOIN CLEAR *
FILEDEF SBA500 DISK (file name to use)
-*
-*  Strip out id numbers from SBA500 letter file.
-*
DEFINE FILE SBA500
CHK_FLD/A1=IF (EDIT(SBA500_SSN,'$$$9') EQ '-') AND 
              (EDIT(SBA500_SSN,'$$$$$$9') EQ '-')
           THEN 'Y' ELSE 'N';
COMP_FLD/A9=EDIT(SBA500_SSN,'999$99$9999');
END
TABLE FILE SBA500
PRINT SBA500_SSN COMP_FLD
ON TABLE HOLD AS IRMTMP1
WHERE CHK_FLD EQ 'Y';
END
-*
TABLE FILE IRMTMP1
PRINT SBA500_SSN BY COMP_FLD
ON TABLE HOLD AS IRMTMP2
END
-*
-*  Select those enrolled for the specified term(s).  
-*
TABLE FILE RTFILE
PRINT CURR_ATTEMPTED_HRS BY STU_ID
ON TABLE HOLD AS IRMTMP9
WHERE CURR_ATTEMPTED_HRS GT 0;
-*
-*  Specify which enrollment term(s) to look at.
-*
WHERE (TERM EQ '19981') OR (TERM EQ '19982') OR (TERM EQ '19983');
END
-*
-*  Remove duplicates.
-*
DEFINE FILE IRMTMP9
THS_REC/A1=IF STU_ID NE LAST STU_ID THEN 'Y' ELSE 'N';
END
TABLE FILE IRMTMP9
PRINT CURR_ATTEMPTED_HRS BY STU_ID
ON TABLE HOLD AS IRMTMP8
WHERE THS_REC EQ 'Y';
END
-*
-*  Retrieve students enrolled for the specified term(s) who had
-*  a missing information letter (SBA500) generated on them.
-*
MATCH FILE IRMTMP2
PRINT SBA500_SSN BY COMP_FLD AS MATCH_ID
RUN
FILE IRMTMP8
PRINT CURR_ATTEMPTED_HRS BY STU_ID AS MATCH_ID
AFTER MATCH HOLD OLD-AND-NEW
END
-RUN
-*
-*  Get student's name and generate report.
-*
JOIN MATCH_ID IN HOLD TO STU_ID IN AAFILE AS J1
TABLE FILE HOLD
PRINT MATCH_ID AS 'Student ID' BY STU_NAME
END
JOIN CLEAR *


SBA500.MFD :

FILE=SBA500,SUFFIX=FIX
SEGNAME=ROOT
FIELD=GEN_FIL001, ,A57,A57,$   
FIELD=SBA500_SSN, ,A11,A11,$  
FIELD=GEN_FIL002, ,A64,A64,$

This page hosted by Get your own Free Homepage