Typical DCL Command Procedure to run the program :

$!
$!  FA_UPD_REVW.COM
$!
$!      Description:    Creates batch transactions to update the 
$!                      "O/P Doc Rev" field on screen 313 for the 
$!                      input award year.
$!
$!  CREATE TEMPORARY COMMAND PROCEDURE THE RUN FOCUS JOB.
$!
$ WF := WRITE FILE
$ COM_FILE = "SYS$LOGIN:FOCTEMP.COM"
$!
$ OPEN/WRITE FILE 'COM_FILE' 
$ WF "$ SET DEFAULT SYS$LOGIN"
$ WF "$ DEFINE FOC$DIR1 SI$DATA"
$ WF "$ DEFINE FOC$DIR2 SI$MFD"
$ WF "$ FOCUS"
$ WF "EXEC SI$FOCUS:FA_UPD_REVW"
$ WF "FIN"
$ WF "$ EXIT"
$ CLOSE FILE
$ @'COM_FILE'
$!
$!  MOVE RESULTING BATCH TRANSACTIONS TO MAINTENANCE CYCLE FEED FILE.
$!
$ CONVERT/APPEND SYS$LOGIN:UPDREV.FTM SI$DATA:AIB2FL.DAT
$!
$!  CLEAN UP.
$!
$ DELETE/LOG SYS$LOGIN:*.FTM;*
$ DELETE/LOG SYS$LOGIN:*.MAS;*
$ DELETE/LOG SYS$LOGIN:*.WP;*
$ DELETE/LOG SYS$LOGIN:FOCTEMP.COM;*
$EXIT


FOCUS program :

-*begin doc
-*
-*FEX:  FA_UPD_REVW
-*
-*      This FOCUS program will produce the batch transactions to update
-*      the "O/P Doc Rev" field on screen 313 for the input award year.
-*
-*INPUT
-*      Award Year
-*
-*end doc
-**********************************************************************
-*
JOIN CLEAR *
-SET &IAWYR = '2000';
SET LINES=999999                                                               
SET PAGE=NOPAGE                                                                
FILEDEF UPDREV DISK UPDREV.FTM APPEND LREC 80 RECFM F
-*
-*  Create The Batch Header
-*
DEFINE FILE AAFILE
BATCH_HEADER1/A40 = '$$$MSC515        UPD O/P DOC    YFA     ';
BATCH_HEADER2/A40 = '                                        ';
END
TABLE FILE AAFILE
PRINT BATCH_HEADER1 AS ''
      BATCH_HEADER2 AS ''
BY STU_ID NOPRINT   
ON TABLE SAVE AS UPDREV   
IF RECORDLIMIT EQ 1  
END
-*
-*  Select financial aid students who are awarded Pell.
-*
TABLE FILE SWFILE
PRINT SW_FUND BY STU_ID
ON TABLE HOLD AS SWTEMP1
WHERE SW_FUND EQ '(Subcode used for Pell)';
WHERE AWD_YR EQ '&IAWYR';
WHERE (AWD_STAT NE 'C') AND (AWD_STAT NE 'R');
END
-*
-*  Select all eligible financial aid students.
-*
TABLE FILE SAFILE
PRINT ROOT_KEY
IF AWD_YR EQ '&IAWYR'
IF PELL_CNTR GT 0
ON TABLE HOLD AS SATEMP1
END
-*
-*  Select students whose "O/P Doc Rev" field on screen 313 is not equal to Y
-*  and who have been awarded Pell.
-*
JOIN ROOT_KEY IN SATEMP1 TO ROOT_KEY IN SAFILE AS J1
MATCH FILE SATEMP1
PRINT AWD_YR BY STU_ID
WHERE (AWD_YR EQ '&IAWYR') AND (SAR_REVW NE 'Y');
RUN
FILE SWTEMP1
PRINT SW_FUND BY STU_ID
AFTER MATCH HOLD OLD-AND-NEW
END
-RUN
-*
-*  Create batch transactions to update "O/P Doc Rev" field on screen 313.
-*
DEFINE FILE HOLD
BTH_TRANS1/A80 = ('76B'|STU_ID|'  '|'&IAWYR'|'             Y');
END
TABLE FILE HOLD
PRINT BTH_TRANS1 IN 1 AS ''
ON TABLE SAVE AS UPDREV
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage