Typical DCL Command Procedure to run the program :

$!
$!  FA_ATB.COM
$!
$!      Description:    Creates batch transactions to update the 
$!                      ability to benefit field on screen 325.
$!
$!  CREATE TEMPORARY COMMAND PROCEDURE THE RUN FOCUS JOB.
$!
$ WF := WRITE FILE
$ COM_FILE = "SYS$LOGIN:FOCTEMP.COM"
$!
$ OPEN/WRITE FILE 'COM_FILE' 
$ WF "$ SET DEFAULT SYS$LOGIN"
$ WF "$ DEFINE FOC$DIR1 SI$DATA"
$ WF "$ DEFINE FOC$DIR2 SI$MFD"
$ WF "$ FOCUS"
$ WF "EXEC SI$FOCUS:FA_ATB"
$ WF "FIN"
$ WF "$ EXIT"
$ CLOSE FILE
$ @'COM_FILE'
$!
$!  MOVE RESULTING BATCH TRANSACTIONS TO MAINTENANCE CYCLE FEED FILE.
$!
$ CONVERT/APPEND SYS$LOGIN:FAATB.FTM SI$DATA:AIB2FL.DAT
$!
$!  CLEAN UP.
$!
$ DELETE/LOG SYS$LOGIN:*.FTM;*
$ DELETE/LOG SYS$LOGIN:*.MAS;*
$ DELETE/LOG SYS$LOGIN:*.WP;*
$ DELETE/LOG SYS$LOGIN:FOCTEMP.COM;*
$EXIT


FOCUS program :

-*begin doc
-*
-*FEX:  FA21_ATB
-*
-*      This FOCUS program will produce the batch transactions to update
-*      the ability to benefit field on screen 325.
-*
-*INPUT
-*      Award Year
-*      Award Period
-*
-*end doc
-**********************************************************************
-*
JOIN CLEAR *
-SET &AWD_YR = '2000';
-SET &IAWPD = '2000A';
SET LINES=999999                                                                
SET PAGE=NOPAGE                                                                 
FILEDEF FAATB DISK FAATB.FTM APPEND LREC 83 RECFM F
-*
-*  Create The Batch Header
-*
DEFINE FILE AAFILE
BATCH_HEADER1/A40 = '$$$MSC516        FA ATB UPD     YFA     ';
BATCH_HEADER2/A43 = '                                        ';
END
TABLE FILE AAFILE
PRINT BATCH_HEADER1 AS ''
      BATCH_HEADER2 AS ''
BY STU_ID NOPRINT   
ON TABLE SAVE AS FAATB   
IF RECORDLIMIT EQ 1  
END
-*
-*  Select students whose current ability to benefit field is blank.
-*
TABLE FILE SAFILE
PRINT ABIL_BEN BY STU_ID
ON TABLE HOLD AS SATEMP1
WHERE AWD_YR EQ '&AWD_YR';
WHERE PHYS_PK_CNTR GT 0;
WHERE ABIL_BEN EQ ''; 
END
-*
-*  Create batch transactions to fill any empty ability to benefit field
-*  with a "P" (Ability to benefit test passed).
-*
DEFINE FILE SATEMP1
BTH_TRANS/A83 = ('73B'|STU_ID|'      '|'&IAWPD'|'                         '|
'                                  P');
END
TABLE FILE SATEMP1
PRINT BTH_TRANS IN 1 AS ''
ON TABLE SAVE AS FAATB
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage