Typical DCL Command Procedure to run the program :

$!
$!  FA_UP_ADMS_2000.COM
$!
$!      Description:    Creates batch transactions to "clear" ADMS code on
$!			screen 306 for those who meet the criteria.  This 
$!			program is for the 1999-2000 award year.      
$!
$!  CREATE TEMPORARY COMMAND PROCEDURE THE RUN FOCUS JOB.
$!
$ WF := WRITE FILE
$ COM_FILE = "SYS$LOGIN:FOCTEMP.COM"
$!
$ OPEN/WRITE FILE 'COM_FILE' 
$ WF "$ SET DEFAULT SYS$LOGIN"
$ WF "$ DEFINE FOC$DIR1 SI$DATA"
$ WF "$ DEFINE FOC$DIR2 SI$MFD"
$ WF "$ FOCUS"
$ WF "EXEC SI$FOCUS:FA_UP_ADMS_2000"
$ WF "FIN"
$ WF "$ EXIT"
$ CLOSE FILE
$ @'COM_FILE'
$!
$!  MOVE RESULTING BATCH TRANSACTIONS TO MAINTENANCE CYCLE FEED FILE.
$!
$ CONVERT/APPEND SYS$LOGIN:UPADMS.FTM SI$DATA:AIB2FL.DAT
$!
$!  CLEAN UP.
$!
$ DELETE/LOG SYS$LOGIN:*.FTM;*
$ DELETE/LOG SYS$LOGIN:*.MAS;*
$ DELETE/LOG SYS$LOGIN:*.WP;*
$ DELETE/LOG SYS$LOGIN:FOCTEMP.COM;*
$ EXIT


FOCUS program :

-*begin doc
-*
-*FEX:  FA_UP_ADMS
-*
-*      This produces a list of students who need to have the
-*      ADMS code marked as complete on screen 306.  The update 
-*      is done via batch transactions.
-*
-*INPUT
-*      AWD_YR : AWARD YEAR
-*      AWD_PD : AWARD PERIOD
-*      TERM_1 : 1ST TERM FOR OUR ACADEMIC YEAR
-*      TERM_2 : 2ND TERM FOR OUR ACADEMIC YEAR
-*      TERM_3 : 3RD TERM FOR OUR ACADEMIC YEAR
-*
-*end doc
-**********************************************************************
SET COMPUTE = OLD
SET PAGE = NOPAGE
SET LINES = 999999
-SET &AWD_YR = '2000';
-SET &AWD_PD = '2000A';
-SET &TERM_1 = '19991';
-SET &TERM_2 = '19992';
-SET &TERM_3 = '19993';
JOIN CLEAR *
FILEDEF UPADMS DISK UPADMS.FTM APPEND LREC 80 RECFM F
-*
-*  Create The Batch Header
-*
DEFINE FILE AAFILE
BATCH_HEADER1/A40 = '$$$MSC514        CLR ADMS CODE  YFA     ';
BATCH_HEADER2/A40 = '                                        ';
END
TABLE FILE AAFILE
PRINT BATCH_HEADER1 AS ''
      BATCH_HEADER2 AS ''
BY STU_ID NOPRINT   
ON TABLE SAVE AS UPADMS   
IF RECORDLIMIT EQ 1  
END
-*
-*  Select all students who have an uncompleted ADMS code on screen 306
-*  and have been accepted for the current academic year by Admissions.
-*
MATCH FILE STFILE
PRINT AWD_YR BY STU_ID
WHERE AWD_YR EQ '&AWD_YR';
WHERE TRK_STAT EQ '';
WHERE TRK_FORM EQ 'ADMS';
WHERE ST020_ORDER LE TRK_CNTR;
RUN
FILE MMFILE
PRINT COLLEGE_3 BY STU_ID
WHERE COLLEGE_3 NE '';
WHERE (APP_TERM EQ '&TERM_1') OR (APP_TERM EQ '&TERM_2') OR 
      (APP_TERM EQ '&TERM_3'); 
-*
-*  Eliminate all majors not eligible for financial aid.
-*
WHERE (MAJOR_3 NE 'ZZUK') AND (MAJOR_3 NE 'CE62') AND (MAJOR_3 NE 'CE65') AND 
      (MAJOR_3 NE 'CE68') AND (MAJOR_3 NE 'CE81') AND (MAJOR_3 NE 'CONT') AND 
      (MAJOR_3 NE 'CE') AND (MAJOR_3 NE 'WFIT') AND (MAJOR_3 NE 'PQBA') AND 
      (MAJOR_3 NE 'SCBA') AND (MAJOR_3 NE 'TRBA') AND (MAJOR_3 NE 'ZZBA') AND 
      (MAJOR_3 NE 'JTCL') AND (MAJOR_3 NE 'UNDC') AND (MAJOR_3 NE 'GEDX') AND 
      (MAJOR_3 NE 'JTGE') AND (MAJOR_3 NE 'TRGE') AND (MAJOR_3 NE 'BUSA') AND 
      (MAJOR_3 NE 'TRUD') AND (MAJOR_3 NE 'ZZUD') AND (MAJOR_3 NE 'TRUN') AND 
      (MAJOR_3 NE 'ZZUN') AND (MAJOR_3 NE 'TRUP') AND (MAJOR_3 NE 'ZZUP') AND 
      (MAJOR_3 NE 'TRUT') AND (MAJOR_3 NE 'ZZUT') AND (MAJOR_3 NE 'ZZUW') AND 
      (MAJOR_3 NE 'TRUW');
WHERE MM030_ORDER LE AP_SEG_CNTR;
AFTER MATCH HOLD OLD-AND-NEW
END
-RUN
-*
-*  Create batch transactions to update screen 306.
-*
DEFINE FILE HOLD
BTH_TRANS/A80 = ('72B'|STU_ID|'      &AWD_PD ADMS         C');
END
TABLE FILE HOLD
PRINT BTH_TRANS AS '' BY STU_ID NOPRINT
ON TABLE SAVE AS UPADMS   
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage