FOCUS program :

-*begin doc
-*
-*FEX:	FA-WITHDRAWN
-*
-*	This produces a listing of FA students who have completely
-*	withdrawn for the term specified.
-*
-*INPUT
-*    	ENR_TERM : ENROLLMENT TERM TO SELECT FROM
-*    	AWD_YR   : AWARD YEAR TO SELECT FROM
-*
-*USAGE
-*	Used to assist with refunds and repayments for each term.
-*
-*end doc
-**********************************************************************
SET LINES=50
-PROMPT &ENR_TERM/A5.ENTER THE FIVE DIGIT ENROLLMENT TERM (CCYYX) :
-PROMPT &AWD_YR/A4.ENTER THE FOUR DIGIT AWARD YEAR (CCYY) :
JOIN CLEAR *
-*
-*  Select award corresponding to the input enrollment term.
-*
DEFINE FILE SWFILE
THS_TRM/A1=EDIT('&ENR_TERM','$$$$9');
END
TABLE FILE SWFILE
PRINT AWD_YR BY STU_ID
WHERE (THS_TRM EQ '1' AND (OFFER_AMT GT 0 OR ACCPT_AMT GT 0)) OR
      (THS_TRM EQ '2' AND (OFFERED_2ND_AMT GT 0 OR ACCEPTED_2ND_AMT GT 0)) OR
      (THS_TRM EQ '3' AND (OFFERED_3RD_AMT GT 0 OR ACCEPTED_3RD_AMT GT 0));
WHERE AWD_YR EQ '&AWD_YR';
ON TABLE HOLD AS SWTEMP1
END
-*
-*  Remove duplicates
-*
DEFINE FILE SWTEMP1
THS_REC/A1=IF STU_ID NE LAST STU_ID THEN 'Y' ELSE 'N';
END
TABLE FILE SWTEMP1
PRINT AWD_YR BY STU_ID
WHERE THS_REC EQ 'Y';
ON TABLE HOLD AS SWTEMP2
END
-*
-*  Select students who withdrew based upon grades.
-*
JOIN JN_KEY WITH STU_ID IN SWTEMP2 TO KEY IN RTFILE AS J1
DEFINE FILE SWTEMP2
JN_KEY/A14='&ENR_TERM'|STU_ID;
THS_GRD/A1=EDIT(OFFICIAL_GRADE,'9$$');
THS_QUAL/A1=EDIT(STATUS_QUALIFIER,'9$');
END
TABLE FILE SWTEMP2
PRINT TERM BY STU_ID BY HIGHEST THS_GRD 
WHERE TERM EQ '&ENR_TERM';
WHERE RT020_ORDER LE STU_PGM_ENTRY_CNTR; 
WHERE THS_QUAL NE 'D';
ON TABLE HOLD AS SWTEMP3
END
-*
TABLE FILE SWTEMP3
SUM THS_GRD BY STU_ID 
ON TABLE HOLD AS SWTEMP4
END
-*
-*  Select students who withdrew based upon hours.
-*
MATCH FILE SWTEMP4
PRINT THS_GRD BY STU_ID
WHERE THS_GRD EQ 'W';
RUN
FILE SWTEMP2
PRINT CURR_ATTEMPTED_HRS BY STU_ID
WHERE CURR_ATTEMPTED_HRS EQ 0;
WHERE STU_PGM_ENTRY_CNTR GE 1;
WHERE TERM EQ '&ENR_TERM';
AFTER MATCH HOLD OLD-OR-NEW
END
-RUN
-*
-*  Produce report.
-*
JOIN STU_ID IN HOLD TO STU_ID IN AAFILE AS J2
DEFINE FILE HOLD
STUD_CTR/I5=IF STU_ID NE ' ' THEN 1 ELSE 0;
END
TABLE FILE HOLD
-*
"DATE: &DATE  TIME: &TOD  Report Name: FA-WITHDRAWN"
" "
"Students Awarded Financial Aid For Term Who Have Completely Withdrawn"
"Term: &ENR_TERM <+44 Award Year: &AWD_YR"
" "
" "
-*
PRINT STU_ID AS 'Student ID' IN 50 BY STU_NAME IN 1
ON TABLE SUBFOOT
"</2 GRAND TOTAL OF STUDENTS: <CT.STUD_CTR "
ON TABLE HOLD AS REPORT FORMAT WP
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage