FOCUS program :

-*begin doc
-*
-*FEX:	FA-TERM-STATISTICS
-*
-*INPUT
-*      ENR_TERM : ENROLLMENT TERM TO SELECT FROM
-*   	  AWD_YR   : AWARD YEAR TO SELECT FROM
-*      AWD_PD   : AWARD PERIOD TO SELECT FROM
-*
-*end doc
-**********************************************************************
SET LINES=50
-PROMPT &ENR_TERM/A5.ENTER THE FIVE DIGIT ENROLLMENT TERM (CCYYX) :
-PROMPT &AWD_YR/A4.ENTER THE FOUR DIGIT AWARD YEAR (CCYY) :
-PROMPT &AWD_PD/A5.ENTER THE FIVE DIGIT AWARD PERIOD (CCYYX) :
-*
JOIN CLEAR *
-*
-* Get financial aid students
-*
TABLE FILE SAFILE
PRINT AWD_YR BY STU_ID
WHERE (AWD_AMT GT 0) AND (AWD_PER EQ '&AWD_PD') AND
      (AWD_YR EQ '&AWD_YR');
ON TABLE HOLD AS SATEMP1
END
-*
-* Get overall GPA 
-*
JOIN STU_ID IN SATEMP1 TO KEY IN RAFILE AS J1
TABLE FILE SATEMP1
PRINT COLL_HIST_GPA BY STU_ID
ON TABLE HOLD AS SATEMP2
IF CAREER_STU EQ 'T'
END
-*
-* Get course information for students
-*
JOIN JN_KEY WITH STU_ID IN SATEMP2 TO KEY IN RTFILE AS J2
DEFINE FILE SATEMP2
JN_KEY/A14='&ENR_TERM'|STU_ID;
CUR_HRS/P05.2C = IF OFFICIAL_GRADE EQ 'A' OR 'B' OR 'C' OR 'D' 
                 THEN CRS_ATTEMPTED_HRS ELSE 0;
RMD_HRS/P05.2C = IF OFFICIAL_GRADE EQ 'A*' OR 'B*' OR 'C*' OR 'D*'
                                   OR 'SC' 
                 THEN CRS_ATTEMPTED_HRS ELSE 0;
END
TABLE FILE SATEMP2
PRINT CURR_ATTEMPTED_HRS CUR_HRS RMD_HRS
      CRS_ATTEMPTED_HRS SECTION_ID SPE_STATUS OFFICIAL_GRADE 
      COLL_HIST_GPA CURR_GPA SPE_EARNED_HOURS
BY STU_ID
ON TABLE HOLD AS SATEMP3
IF TERM EQ '&ENR_TERM'
END
-*
-* Get name and format report
-*
JOIN STU_ID IN SATEMP3 TO KEY IN AAFILE AS J3
DEFINE FILE SATEMP3
STUD_NAME/A25 = SUBSTR(32,STU_NAME,1,25,25,STUD_NAME);
STUD_CTR/I5=IF E01  NE ' ' THEN 1 ELSE 0;
END
TABLE FILE SATEMP3
"DATE: &DATE  TIME: &TOD            Report Name: FA-TERM-STATISTICS"
"Student's FAM Credit Hours"
"Term: &ENR_TERM    Award Period: &AWD_PD     Award Year: &AWD_YR"
" "
"          Name              SSN          Comp %    Term GPA   Overall GPA"
" "
-*
SUM CRS_ATTEMPTED_HRS AS 'ATTHRS' NOPRINT SPE_EARNED_HOURS AS 'SPEHRS' NOPRINT
COMPUTE COMP_PCT/P05.1C = IF CRS_ATTEMPTED_HRS GT 0 
     THEN SPE_EARNED_HOURS/CRS_ATTEMPTED_HRS * 100 ELSE 0; NOPRINT
BY STUD_NAME NOPRINT
-*
PRINT SECTION_ID AS '' IN +10 SPE_STATUS AS '' OFFICIAL_GRADE AS '' 
      CRS_ATTEMPTED_HRS AS '' 
BY STUD_NAME NOPRINT
BY OFFICIAL_GRADE NOPRINT
-*
ON STUD_NAME SUBFOOT
"<1 Attempted Hrs: <CURR_ATTEMPTED_HRS <28 Curriculum Hrs: <ST.CUR_HRS
<55 Remedial Hrs: <ST.RMD_HRS"
"</1  "
-*
ON STUD_NAME SUBHEAD
"<1 <STUD_NAME <27 <STU_ID <41  <COMP_PCT <52 <CURR_GPA <65 <COLL_HIST_GPA"
-*
ON TABLE HOLD AS REPORT FORMAT WP
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage