FOCUS program :

-*begin doc
-*
-*FEX:  FA-READY-TO-AWARD
-*
-*      This produces a list of financial aid students who are
-*      eligible to be awarded.
-*
-*INPUT
-*      Financial Aid Award Period
-*
-*end doc
-**********************************************************************
-*
JOIN CLEAR *
SET LINES=56
-PROMPT &AWPD/A5.ENTER THE FIVE DIGIT AWARD PERIOD (CCYYX) :
-*
-*  Select all students whose tracking is complete.
-*
DEFINE FILE STFILE
IMCNT/I9  = IF TRK_STAT EQ 'C' OR 'W' THEN 0 ELSE 1;
AWYR/A4   = EDIT('&AWPD','9999');
END
TABLE FILE STFILE
SUM IMCNT AWYR BY STU_ID 
IF TRK_CNTR GT 0
WHERE (AWD_YR EQ AWYR) AND (AWD_PER EQ '&AWPD');
ON TABLE HOLD AS STTEMP1
END
-*
-*  Select all students who have already been awarded.
-*
DEFINE FILE SWFILE
AWYR/A4 = EDIT('&AWPD','9999');
END
TABLE FILE SWFILE
PRINT AWD_YR BY STU_ID
WHERE (OFFER_AMT GT 0) OR (OFFERED_2ND_AMT GT 0) OR
      (OFFERED_3RD_AMT GT 0);
WHERE AWD_YR EQ AWYR;
ON TABLE HOLD AS SWTEMP1
END
-*
-*  Remove duplicates.
-*
DEFINE FILE SWTEMP1
THS_REC/A1=IF STU_ID NE LAST STU_ID THEN 'Y' ELSE 'N';
END
TABLE FILE SWTEMP1
PRINT AWD_YR BY STU_ID
WHERE THS_REC EQ 'Y';
ON TABLE HOLD AS SWTEMP2
END
-*
-*  Select all students whose tracking is complete, but who have not 
-*  already been awarded.
-*
MATCH FILE STTEMP1
PRINT IMCNT AWYR BY STU_ID
WHERE IMCNT LT 1;
RUN
FILE SWTEMP2
PRINT AWD_YR BY STU_ID
AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
-*
DEFINE FILE HOLD
SAKEY/A13 = AWYR|STU_ID;
END
TABLE FILE HOLD
PRINT IMCNT STU_ID BY SAKEY
ON TABLE HOLD AS STTEMP2
END
-*
-*  Select all students who are eligible to be awarded financial aid.
-*
JOIN SAKEY IN STTEMP2 TO KEY IN SAFILE AS J1
TABLE FILE STTEMP2
PRINT PKG_STAT IMCNT BY STU_ID
IF AWD_PER EQ '&AWPD'
WHERE SA002_ORDER LE 2;
WHERE (OPT_1 NE 'NE') AND (OPT_2 NE 'NE') AND (OPT_3 NE 'NE') AND 
      (OPT_4 NE 'NE') AND (OPT_5 NE 'NE') AND (OPT_6 NE 'NE');
WHERE PK_RAP_CODE NE '4';
ON TABLE HOLD AS STTEMP3
END
-*
-*  Produce report.
-*
JOIN STU_ID IN STTEMP3 TO STU_ID IN AAFILE AS J2
DEFINE FILE STTEMP3
STUD_CTR/I5=IF STU_ID  NE ' ' THEN 1 ELSE 0;
END
TABLE FILE STTEMP3
"DATE: &DATE  TIME: &TOD  Report Name: FA-READY-TO-AWARD"
"Students who are eligible to be awarded financial aid for award period &AWPD"
" "
" "
PRINT STU_ID AS 'Student ID' PKG_STAT AS 'Pack.,Status'
BY STU_NAME
ON TABLE SUBFOOT
"</2 GRAND TOTAL OF STUDENTS: <CT.STUD_CTR "
ON TABLE HOLD AS REPORT FORMAT WP
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage