FOCUS program :

-*begin doc
-*
-*FEX:  FA-HOURS
-*
-*      This produces a listing of all FA students who have dropped or 
-*      added hours.
-*
-*INPUT
-*      ENR_TERM : ENROLLMENT TERM TO SELECT FROM
-*      AWD_YR   : AWARD YEAR TO SELECT FROM
-*      AWD_PD   : AWARD PERIOD TO SELECT FROM
-*
-*USAGE
-*      Used to adjust student's award so he is paid the correct amount 
-*      of financial aid.
-*
-*end doc
-**********************************************************************
SET LINES=50
-PROMPT &ENR_TERM/A5.ENTER THE FIVE DIGIT ENROLLMENT TERM (CCYYX) :
-PROMPT &AWD_YR/A4.ENTER THE FOUR DIGIT AWARD YEAR (CCYY) :
-PROMPT &AWD_PD/A5.ENTER THE FIVE DIGIT AWARD PERIOD (CCYYX) :
JOIN CLEAR *
-SET &S = EDIT(&ENR_TERM,'$$$$9');
-*
-*  Select students awarded for input award year.
-*
TABLE FILE SAFILE
PRINT AWD_YR BY STU_ID
IF AWD_YR EQ '&AWD_YR'
IF PKG_CNTR GT 0
ON TABLE HOLD AS SATEMP1
END
-*
-*  Determine the financial aid term anticipated hours that corresponds to
-*  the input enrollment term.
-*
JOIN TEMP_KEY WITH STU_ID IN SATEMP1 TO ROOT_KEY IN SAFILE AS J1
DEFINE FILE SATEMP1
TEMP_KEY/A13 = ('&AWD_YR'|STU_ID);
RT_KEY/A14 = ('&ENR_TERM'|STU_ID);
-*
TERM_HRS/P07.2C = IF &S EQ 1 THEN ANTIC_TERM_HOURS_1 
                  ELSE IF &S EQ 2 THEN ANTIC_TERM_HOURS_2 
                  ELSE ANTIC_TERM_HOURS_3;
END
TABLE FILE SATEMP1
PRINT STU_ID AWD_YR AWD_PER TERM_HRS AWD_AMT
BY RT_KEY 
WHERE (AWD_AMT GT 0) AND (AWD_PER EQ '&AWD_PD');
ON TABLE HOLD AS SATEMP2
END
-*
-*  Compare the student's financial aid term anticipated hours with
-*  actual hours taken for the input enrollment term.
-*
JOIN RT_KEY IN SATEMP2 TO ROOT_KEY IN RTFILE AS J2
TABLE FILE SATEMP2
PRINT TERM_HRS CURR_ATTEMPTED_HRS AWD_AMT CURR_FAM_HRS
BY STU_ID 
WHERE (TERM_HRS EQ 12 AND CURR_FAM_HRS LT 12) OR
      (TERM_HRS EQ 0 AND CURR_FAM_HRS GE 1) OR
      (TERM_HRS EQ 9 AND (CURR_FAM_HRS LT 9 OR CURR_FAM_HRS GE 12)) OR
      (TERM_HRS EQ 6 AND (CURR_FAM_HRS LT 6 OR CURR_FAM_HRS GE 9)) OR
      (TERM_HRS EQ 3 AND (CURR_FAM_HRS LT 1 OR CURR_FAM_HRS GE 6));
ON TABLE HOLD AS SATEMP3
END
-*
-*  Produce report.
-*
JOIN STU_ID IN SATEMP3 TO STU_ID IN AAFILE AS J3
DEFINE FILE SATEMP3
STUD_NAME/A25 = SUBSTR(32,STU_NAME,1,25,25,STUD_NAME);
STUD_CTR/I5=IF STU_ID  NE ' ' THEN 1 ELSE 0;
END
TABLE FILE SATEMP3
"DATE: &DATE  TIME: &TOD  Report Name: FA-HOURS"
" "
"Students with FAM hours different from expected budget hours"
"Term: &ENR_TERM    Award Period: &AWD_PD     Award Year: &AWD_YR"
" "
" "
-*
PRINT STUD_NAME AS 'Student Name' STU_ID AS 'Student Id' 
      TERM_HRS AS 'FA Anticipated,  Hours' CURR_FAM_HRS AS 'Current,FAM,Hours'
      AWD_AMT AS 'Award,Amount'
BY STUD_NAME NOPRINT
ON TABLE SUBFOOT
"</2 GRAND TOTAL OF STUDENTS: <CT.STUD_CTR "
ON TABLE HOLD AS REPORT FORMAT WP
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage