FOCUS program :

-*begin doc
-*
-*FEX:  FA-AUDIT-HRS
-*
-*input
-*      Term
-*      Award Year
-*
-*
-*      This report lists students who are on financial aid who have 
-*      grade(s) of AU (audit). 
-*
-*
-*end doc
-*
SET LINES=56
-PROMPT &ENR_TERM/A5.ENTER THE FIVE DIGIT ENROLLMENT TERM (CCYYX) :
-PROMPT &AWD_YR/A4.ENTER THE FOUR DIGIT AWARD YEAR (CCYY) :
JOIN CLEAR *
-*
-*  Select students awarded for input award year/term.
-*
DEFINE FILE SWFILE
THS_TRM/A1=EDIT('&ENR_TERM','$$$$9');
END
TABLE FILE SWFILE
PRINT AWD_YR BY STU_ID
WHERE (THS_TRM EQ '1' AND (OFFER_AMT GT 0 OR ACCPT_AMT GT 0)) OR
      (THS_TRM EQ '2' AND (OFFERED_2ND_AMT GT 0 OR ACCEPTED_2ND_AMT GT 0)) OR
      (THS_TRM EQ '3' AND (OFFERED_3RD_AMT GT 0 OR ACCEPTED_3RD_AMT GT 0));
WHERE AWD_YR EQ '&AWD_YR';
ON TABLE HOLD AS SWTEMP1
END
-*
-*  Remove duplicates
-*
DEFINE FILE SWTEMP1
THS_REC/A1=IF STU_ID NE LAST STU_ID THEN 'Y' ELSE 'N';
END
TABLE FILE SWTEMP1
PRINT AWD_YR BY STU_ID
WHERE THS_REC EQ 'Y';
ON TABLE HOLD AS SWTEMP2
END
-*
-*  Take list created above and get students who have a 
-*  grade of AU (audit).
-*
MATCH FILE SWTEMP2
PRINT AWD_YR BY STU_ID
RUN
FILE RTFILE
PRINT TERM BY STU_ID
WHERE OFFICIAL_GRADE EQ 'AU';
WHERE TERM EQ '&ENR_TERM';
WHERE RT020_ORDER LE STU_PGM_ENTRY_CNTR;
AFTER MATCH HOLD OLD-AND-NEW
END
-RUN
-*
-*  Produce report.
-*
JOIN STU_ID IN HOLD TO STU_ID IN AAFILE AS J2
TABLE FILE HOLD
HEADING CENTER
"DATE: &DATE  TIME: &TOD  Report Name: FA-AUDIT-HRS"
"Financial Aid Students with grade(s) of AU (audit)"
" "
PRINT STU_ID AS 'Student ID' IN 50 BY STU_NAME IN 1
ON TABLE HOLD AS REPORT FORMAT WP
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage