FOCUS program :

-SET &IAWDYR = (Financial Aid Award Year);
-SET &IAWPD = (Financial Aid Award Period);
JOIN CLEAR *
-*
-*  THIS WILL CHECK THE HOUSING CODE AND WILL CHECK TO
-*  SEE IF A STUDENT HAS ALREADY BEEN AWARDED.
-*
DEFINE FILE SAFILE
  JN_KEY1/A13 = ('&IAWDYR'|INSTIT_SA|SID_SA);
END
TABLE FILE SAFILE
  PRINT SID_SA
    BY JN_KEY1
  ON TABLE HOLD AS SATEMP2
  IF PKG_SEG_CTR GT 0
  IF HOUSING_STAT EQ ' ' OR '3'
  IF AWD_YR_SA EQ '&IAWDYR'
END
-*
JOIN JN_KEY1 IN SATEMP2 TO KEY IN SAFILE AS J1
DEFINE FILE SATEMP2
  JN_KEY2/A11 = (INSTIT_SA|SID_SA);
END
TABLE FILE SATEMP2
  PRINT JN_KEY1 JN_KEY2 SID_SA PKG_AWPD
  ON TABLE HOLD AS SATEMP1
  IF PKG_STAT_CD EQ ' '
  IF PKG_AWPD EQ '&IAWPD'
  WHERE (SA_020_ORDER LE 2);
END
-*
JOIN CLEAR *
SET FOCSTACK=32
-RUN
JOIN JN_KEY2 IN SATEMP1 TO ROOT_KEY_AA IN AAFILE AS J2
JOIN JN_KEY1 IN SATEMP1 TO ROOT_KEY_SA IN SAFILE AS J1
MATCH FILE SATEMP1
  PRINT AWD_YR_SA PKG_AWPD
    BY SID_SA AS SID_CODE
  IF PL_INFO_SRC EQ 'P' OR '0' OR '1' OR '2'
  IF PELL_S_MRTL EQ 'U'
  IF PL_STU_DEPS EQ 'N'
  IF RESD_STAT_AA EQ 'RM'
  IF PELL_SEG_CTR GT 0
RUN
FILE STFILE
  SUM TRK_AWD_YR
    BY SID_ST AS SID_CODE
  IF TRK_AWD_YR EQ '&IAWDYR'
  IF TRK_AWPD EQ '&IAWPD'
  IF TRK_FORM EQ 'UAPP'
  WHERE (ST_020_ORDER LE TRK_CTR_ST);
  AFTER MATCH HOLD OLD-AND-NEW
END
-*
-RUN
FILEDEF PLAY DISK PLAY.FTM APPEND
DEFINE FILE HOLD
  BTH_TRANS1/A26 = ('75A'|SID_CODE|'  '|AWD_YR_SA|PKG_AWPD|'     '|'01'); 
  BTH_TRANS2/A35 = '01015 01700 00375 00960 00000 00655';
END
TABLE FILE HOLD
  PRINT BTH_TRANS1 IN 1 AS '' BTH_TRANS2 AS ''
  ON TABLE SAVE AS PLAY
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage