Uni-Basic program :

CRT @(-1):'FINANCIAL AID CWS BALANCE REPORT'
PROMPT ''
CRT @(16,4):'Enter the Academic Year <Ex. 1997> or <E>nd: ':
INPUT ACYR
IF UPCASE(ACYR[1,1]) NE 'E' THEN
  SA.FILE = 'SA.':ACYR
  HEADING "'D'FINANCIAL AID CWS BALANCE REPORT'C' PAGE 'PLL'"
  MAX.AWARD = 0
  ALL.AWARDS = 0
  OPEN '', SA.FILE TO SA.ACYR ELSE STOP 'ERROR'
  OPEN '', 'PEOPLE' TO PEOPLE ELSE STOP 'ERROR'
  EOF = 0
  EXECUTE "SELECT ":SA.FILE:" BY SA.NAME"
  LOOP
    READNEXT SA.ACYR.ID ELSE EOF = 1
  UNTIL EOF
    RESULT = 0
    READ R.SA.ACYR FROM SA.ACYR,SA.ACYR.ID THEN
      MAX.AWARD = DCOUNT(R.SA.ACYR<7>,@VM)
      FOR I = 1 TO MAX.AWARD
        LOCATE 'CWS' IN R.SA.ACYR<7,I> SETTING POS ELSE POS=0
        IF POS THEN RESULT = R.SA.ACYR<8,POS> - R.SA.ACYR<10,POS>
        ALL.AWARDS = ALL.AWARDS + RESULT
      NEXT I
      IF RESULT > 0 THEN
        ID.NO = SA.ACYR.ID
        READ PEOPLE.REC FROM PEOPLE,ID.NO ELSE PEOPLE.REC = ''
        IF TRIM(PEOPLE.REC<3>) <> '' THEN
          FULL.NAME = PEOPLE.REC<2>:" ":PEOPLE.REC<3>[1,1]:" ":PEOPLE.REC<1>
        END ELSE
          FULL.NAME = PEOPLE.REC<2>:" ":PEOPLE.REC<1>
        END
        FULL.NAME = FMT(FULL.NAME[1,32],"L#32")
        PRINT FULL.NAME, SA.ACYR.ID,FMT(OCONV(RESULT,"MD2"),"12R2$,")
      END
    END
  REPEAT
  PRINT
  PRINT "TOTAL UNUSED CWS AWARDS",FMT(OCONV(ALL.AWARDS,"MD2"),"14R2$,")
END

This page hosted by Get your own Free Homepage