<![CDATA[
*****************************N O T E S*****************************
Modify PURGEIDS.FEX; put in the term; run. This will create a list
of students that need to be purged.
Copy the resulting transactions (PLAY.FTM) to ADFILE.DAT.
Run ADM_PURGE.COM : PLAY1.FTM -> all transactions except for 15D & 02D;
PLAY2.FTM -> 15D transactions; PLAY3.FTM -> 02D transactions; rename as *.DAT.
Download PLAY6.WP onto PC & run Macro Express to purge information on
screen 205.
Run PLAY1.DAT through SIS batch maintenance cycle.
Run ADM_PURGE.COM.
Download PLAY1.FTM onto PC & run Macro Express to purge information on
screen 209 (32D) & 211 (33D).
Run ADM_PURGE.COM.
Download PLAY1.FTM onto PC & run Macro Express to purge information on
screen 205 (36D); if needed.
Run PLAY1.FTM through SIS batch maintenance cycle.
Run ADM_PURGE.COM & run PLAY1.FTM through SIS batch maintenance cycle as
needed until all transactions have been processed.
Run PLAY2.DAT through SIS batch maintenance cycle.
Modify SI$SOURCE:RCAPSP.LIB as follows :
7500-VALID-APS SECTION.
7500-APS-010.
IF AAW-RQST-FNC = "D"
PERFORM 7800-PROTECT-DELETE
***JMT
***DD IF AAW-PROT-PGM = "Y" OR AA-AP-APPL-NO (AAPLX) NOT = " "
***DD MOVE SPACE TO AAW-ELEM-NO
***DD MOVE "R0222" TO AAW-EMSG-ID
***DD MOVE 1 TO AAW-ERR
***DD GO TO 7500-APS-EXIT
***DD ELSE
***JMT
SUBTRACT 1 FROM AA-AP-CTR
MOVE SPACE TO AA-AP-SEGMENT (AAPLX)
GO TO 7500-APS-140.
IF AAW-RQST-FNC = "A"
XCOBOL ASD060; ASD040; ABD015
Run ADM_PURGE.COM.
Run PLAY2.FTM through SIS batch maintenance cycle.
Remove changes from SI$SOURCE:RCAPSP.LIB; XCOBOL ASD060; ASD040; ABD015
Run PLAY3.DAT through SIS batch maintenance cycle.
*****************************N O T E S*****************************
-*
-* PURGEIDS.FEX
-*
JOIN CLEAR *
FILEDEF AMFL010 DISK SI$DATA:AMFILE.DAT
-SET &ADTERM1 = '19981';
-SET &ADTERM2 = '20001';
-*
-* RETRIEVE STUDENTS WHO HAVE AN APPLICATION FOR THE INPUT TERM
-*
TABLE FILE MMFILE
PRINT APP_TERM BY STU_ID
ON TABLE HOLD AS MMTEMP1
WHERE APP_TERM LE '&ADTERM1';
END
-*
-* REVOVE DUPLICATES
-*
DEFINE FILE MMTEMP1
THS_REC/A1=IF STU_ID NE LAST STU_ID THEN 'Y' ELSE 'N';
END
TABLE FILE MMTEMP1
PRINT APP_TERM BY STU_ID
ON TABLE HOLD AS MMTEMP2
WHERE THS_REC EQ 'Y';
END
-*
-* ELIMINATE THOSE WITH A BR OR FA HOLD FLAG ACTIVE
-*
DEFINE FILE AMFL010
REASON_CD/A1=EDIT(REASON,'9');
END
MATCH FILE MMTEMP2
PRINT APP_TERM BY STU_ID
RUN
FILE AMFL010
PRINT REASON BY STU_ID
WHERE (REASON_CD EQ '4') OR (REASON_CD EQ '3');
AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
-*
-* ELIMINATE THOSE WITH AN APPLICATION FOR A FUTURE TERM
-*
MATCH FILE HOLD
PRINT APP_TERM BY STU_ID
RUN
FILE MMFILE
PRINT APP_STAT_1 BY STU_ID
WHERE APP_TERM GT '&ADTERM2';
AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
-*
-* CHECK TO SEE IF STUDENT HAS EVER ENROLLED/GRADED
-*
JOIN STU_ID IN HOLD TO STU_ID IN AAFILE AS J1
DEFINE FILE HOLD
SUPER_JN_KEY/A14=TERM_STAT_ARRAY_1|STU_ID;
END
TABLE FILE HOLD
PRINT STU_ID BY SUPER_JN_KEY
ON TABLE HOLD AS MMTEMP3
WHERE TERM_STAT_ARRAY_1 NE '';
END
-*
JOIN SUPER_JN_KEY IN MMTEMP3 TO KEY IN RTFILE AS J2
DEFINE FILE MMTEMP3
CHK_FLD/A1=EDIT(SECTION_ID,'$$$$9');
END
TABLE FILE MMTEMP3
PRINT SUPER_JN_KEY BY STU_ID
ON TABLE HOLD AS MMTEMP4
WHERE (OFFICIAL_GRADE NE '' OR SPE_STATUS EQ 'E') AND (CHK_FLD LT '5');
END
-*
-* REVOVE DUPLICATES
-*
DEFINE FILE MMTEMP4
THS_REC/A1=IF STU_ID NE LAST STU_ID THEN 'Y' ELSE 'N';
END
TABLE FILE MMTEMP4
PRINT SUPER_JN_KEY BY STU_ID
ON TABLE HOLD AS MMTEMP5
WHERE THS_REC EQ 'Y';
END
-*
MATCH FILE HOLD
PRINT APP_TERM BY STU_ID
RUN
FILE MMTEMP5
PRINT SUPER_JN_KEY BY STU_ID
AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
-*
JOIN CLEAR *
JOIN STU_ID IN HOLD TO STU_ID IN AAFILE AS J1
TABLE FILE HOLD
PRINT STU_ID BY STU_NAME NOPRINT
ON TABLE HOLD AS MMTEMP6
END
-*
DEFINE FILE MMTEMP6
OUT_REC/A14=STU_ID|'&ADTERM2';
END
TABLE FILE MMTEMP6
PRINT OUT_REC AS '' IN 1
ON TABLE SAVE AS PLAY
END
JOIN CLEAR *
$!
$! ADM_PURGE.COM
$!
$! THIS COMMAND PROCEDURE RUNS THE ADMISSIONS PURGE PROCESS.
$!
$ COPY ADFILE.MFD; ADFILE.MAS;
$!
$! RETRIEVE THE ENROLLMENT TERM TO BE USED.
$!
$ OPEN/READ input_file ADFILE.DAT
$ READ input_file in_record
$ ADTERM = F$EXTRACT(9,5,in_record)
$ CLOSE input_file
$!
$! EXECUTE FOCUS PROGRAM TO CHECK INPUT STUDENT IDS & TO
$! CREATE ALL BATCH TRANSACTIONS BUT 15D & 02D.
$!
$ COM_FILE = "SYS$LOGIN:FOCTEMP.COM"
$!
$ OPEN/WRITE output_file 'COM_FILE'
$!
$ WRITE output_file "$ DEFINE FOC$DIR1 SI$DATA"
$ WRITE output_file "$ DEFINE FOC$DIR2 SI$FEX,SI$MFD"
$ WRITE output_file "$ ASSIGN SI$DATA:XFOC01.DAT XFOC01"
$ WRITE output_file "$ FOCUS"
$ WRITE output_file "EXEC ADM_PURGE1"
$ WRITE output_file "''ADTERM'"
$ WRITE output_file "FIN"
$ WRITE output_file "$ EXIT"
$ CLOSE output_file
$!
$ SUBMIT 'COM_FILE'
$ SYNCHRONIZE FOCTEMP
$ RENAME PLAY.FTM PLAY1.FTM
$!
$! SEND OUT E-MAILS ON THOSE STUDENTS WHO WILL NOT BE PURGED.
$!
$ USER = F$EDIT(F$GETJPI("","USERNAME"),"UPCASE,COLLAPSE")
$!
$ IF (F$SEARCH("PLAY1.WP;") .NES. "")
$ THEN
$ MAIL/SUBJECT="Student Id not in SIS" PLAY1.WP 'USER'
$ ENDIF
$!
$ IF (F$SEARCH("PLAY2A.WP;") .NES. "")
$ THEN
$ MAIL/SUBJECT="Student has BR or FA hold flag in SIS" -
PLAY2A.WP 'USER'
$ ENDIF
$!
$ IF (F$SEARCH("PLAY5A.WP;") .NES. "")
$ THEN
$ MAIL/SUBJECT="Student has application for future term in SIS" -
PLAY5A.WP 'USER'
$ ENDIF
$!
$ IF (F$SEARCH("PLAY3A.WP;") .NES. "")
$ THEN
$ MAIL/SUBJECT="Student is active in current term in SIS" -
PLAY3A.WP 'USER'
$ ENDIF
$!
$ IF (F$SEARCH("PLAY4A.WP;") .NES. "")
$ THEN
$ MAIL/SUBJECT="Student has been enrolled & graded in SIS" -
PLAY4A.WP 'USER'
$ ENDIF
$!
$! EXECUTE FOCUS PROGRAM TO CREATE 15D BATCH TRANSACTIONS.
$!
$ OPEN/WRITE output_file 'COM_FILE'
$!
$ WRITE output_file "$ DEFINE FOC$DIR1 SI$DATA"
$ WRITE output_file "$ DEFINE FOC$DIR2 SI$FEX,SI$MFD"
$ WRITE output_file "$ ASSIGN SI$DATA:XFOC01.DAT XFOC01"
$ WRITE output_file "$ FOCUS"
$ WRITE output_file "EXEC ADM_PURGE2"
$ WRITE output_file "FIN"
$ WRITE output_file "$ EXIT"
$ CLOSE output_file
$!
$ SUBMIT 'COM_FILE'
$ SYNCHRONIZE FOCTEMP
$ RENAME PLAY.FTM PLAY2.FTM
$!
$! EXECUTE FOCUS PROGRAM TO CREATE 02D BATCH TRANSACTIONS.
$!
$ OPEN/WRITE output_file 'COM_FILE'
$!
$ WRITE output_file "$ DEFINE FOC$DIR1 SI$DATA"
$ WRITE output_file "$ DEFINE FOC$DIR2 SI$FEX,SI$MFD"
$ WRITE output_file "$ ASSIGN SI$DATA:XFOC01.DAT XFOC01"
$ WRITE output_file "$ FOCUS"
$ WRITE output_file "EXEC ADM_PURGE3"
$ WRITE output_file "FIN"
$ WRITE output_file "$ EXIT"
$ CLOSE output_file
$!
$ SUBMIT 'COM_FILE'
$ SYNCHRONIZE FOCTEMP
$ RENAME PLAY.FTM PLAY3.FTM
$!
$ IF (F$SEARCH("PLAY6.WP;") .NES. "")
$ THEN
$ MAIL/SUBJECT="Students purged from Admissions in SIS" -
PLAY6.WP 'USER'
$ ENDIF
$!
$ EXIT
JOIN CLEAR *
-*
-* ADM_PURGE1.FEX
-*
SET PAGE=NOPAGE
SET LINES=999999
FILEDEF ADFILE DISK ADFILE.DAT
FILEDEF AMFL010 DISK SI$DATA:AMFILE.DAT
FILEDEF PLAY DISK PLAY.FTM APPEND
-PROMPT &ADTERM/A5.ENTER THE FIVE DIGIT TERM FOR PROCESS (CCYYX) :
-*
-* SORT INPUT FILE OF STUDENT IDS TO BE PURGED
-*
TABLE FILE ADFILE
PRINT D2 BY D1
ON TABLE HOLD AS ADTEMP1
END
TABLE FILE ADTEMP1
PRINT D1
ON TABLE SAVE AS PLAY7
END
-*
-* CHECK TO SEE IF IDS EXIST IN SIS & CREATE AN E-MAIL IF ANY DO NOT
-*
JOIN D1 IN ADTEMP1 TO STU_ID IN AAFILE AS J1
TABLE FILE ADTEMP1
PRINT D1 AS 'Student Id'
ON TABLE SAVE AS PLAY1 FORMAT WP
IF ROOT_KEY EQ ' '
END
-*
-* CHECK TO SEE IF BR OR FA HOLD FLAG IS ACTIVE
-*
JOIN D1 IN ADTEMP1 TO STU_ID IN AMFL010 AS J2
DEFINE FILE ADTEMP1
REASON_CD/A1=EDIT(REASON,'9');
END
TABLE FILE ADTEMP1
PRINT REASON BY D1
ON TABLE HOLD AS PLAY2
WHERE (REASON_CD EQ '4') OR (REASON_CD EQ '3');
END
-*
-* CREATE AN E-MAIL IF ANY STUDENT HAS AN ACTIVE BR OR FA HOLD FLAG
-*
JOIN D1 IN PLAY2 TO STU_ID IN AAFILE AS J3
TABLE FILE PLAY2
PRINT REASON AS 'Hold Reason'
BY STU_NAME
BY D1 AS 'Student Id'
ON TABLE SAVE AS PLAY2A FORMAT WP
END
-*
-* SAVE THOSE WHO EXIST IN SIS AND DO NOT HAVE A BR HOLD FLAG ACTIVE
-*
TABLE FILE ADTEMP1
PRINT D2 BY D1
ON TABLE HOLD AS ADTEMP2
WHERE ROOT_KEY NE ' ';
WHERE REASON_CD NE '4';
WHERE REASON_CD NE '3';
END
-*
-* CHECK TO SEE IF THERE IS AN APPLICATION FOR A FUTURE TERM
-*
JOIN CLEAR *
JOIN D1 IN ADTEMP2 TO STU_ID IN MMFILE AS J1
TABLE FILE ADTEMP2
PRINT APP_TERM BY D1
ON TABLE HOLD AS PLAY5
WHERE APP_TERM GT '&ADTERM';
END
-*
-* CREATE AN E-MAIL IF ANY STUDENT HAS AN APPLICATION FOR A FUTURE TERM
-*
JOIN D1 IN PLAY5 TO STU_ID IN AAFILE AS J2
TABLE FILE PLAY5
PRINT APP_TERM AS 'Application,Term'
BY STU_NAME
BY D1 AS 'Student Id'
ON TABLE SAVE AS PLAY5A FORMAT WP
END
-*
-* REVOVE DUPLICATES
-*
TABLE FILE ADTEMP2
PRINT D2 BY D1
ON TABLE HOLD AS ADTEMP2A
WHERE APP_TERM GT '&ADTERM';
END
-*
DEFINE FILE ADTEMP2A
THS_REC/A1=IF D1 NE LAST D1 THEN 'Y' ELSE 'N';
END
TABLE FILE ADTEMP2A
PRINT THS_REC BY D1
ON TABLE HOLD AS ADTEMP2B
WHERE THS_REC EQ 'Y';
END
-*
-* SAVE THOSE WHO DO NOT HAVE AN APPLICATION FOR A FUTURE TERM
-*
MATCH FILE ADTEMP2
PRINT D2 BY D1
RUN
FILE ADTEMP2B
PRINT THS_REC BY D1
AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
-*
TABLE FILE HOLD
PRINT D2 BY D1
ON TABLE HOLD AS ADTEMP3B
END
-*
-* CHECK TO SEE IF ACTIVE FOR THE CURRENT TERM; THOSE TAKING
-* NON-CONTINUING EDUCATION COURSES
-*
JOIN CLEAR *
JOIN TEMP_KEY WITH D1 IN ADTEMP3B TO KEY IN RTFILE AS J1
DEFINE FILE ADTEMP3B
TEMP_KEY/A14='&ADTERM'|D1;
CHK_FLD/A1=EDIT(SECTION_ID,'$$$$9');
END
TABLE FILE ADTEMP3B
PRINT SECTION_ID BY D1
ON TABLE HOLD AS PLAY3
WHERE KEY NE ' ';
WHERE SPE_STATUS EQ 'E' AND CHK_FLD LT '5';
END
-*
-* CREATE AN E-MAIL IF ANY STUDENT IS ACTIVE FOR THE CURRENT TERM
-*
JOIN D1 IN PLAY3 TO STU_ID IN AAFILE AS J2
TABLE FILE PLAY3
PRINT SECTION_ID AS 'Course'
BY STU_NAME
BY D1 AS 'Student Id'
ON TABLE SAVE AS PLAY3A FORMAT WP
END
-*
-* SAVE THOSE WHO ARE NOT ACTIVE FOR THE CURRENT TERM OR ONLY TAKING
-* NON-CONTINUING EDUCATION COURSES
-*
TABLE FILE ADTEMP3B
PRINT D2 BY D1
ON TABLE HOLD AS ADTEMP3C
WHERE KEY NE ' ';
WHERE CHK_FLD GE '5';
END
-*
TABLE FILE ADTEMP3B
PRINT D2 BY D1
ON TABLE HOLD AS ADTEMP3D
WHERE KEY EQ ' ';
END
-RUN
-VMS COPY ADTEMP3C.FTM,ADTEMP3D.FTM ADTEMP3E.FTM
-*
FILEDEF ADTEMP3D DISK ADTEMP3E.FTM
TABLE FILE ADTEMP3D
PRINT D2 BY D1
ON TABLE HOLD AS ADTEMP3F
END
-*
-* REVOVE DUPLICATES
-*
DEFINE FILE ADTEMP3F
THS_REC/A1=IF D1 NE LAST D1 THEN 'Y' ELSE 'N';
END
TABLE FILE ADTEMP3F
PRINT D2 BY D1
ON TABLE HOLD AS ADTEMP4
WHERE THS_REC EQ 'Y';
END
-*
-* CHECK TO SEE IF STUDENT HAS EVER ENROLLED/GRADED
-*
JOIN CLEAR *
JOIN D1 IN ADTEMP4 TO STU_ID IN AAFILE AS J1
DEFINE FILE ADTEMP4
SUPER_JN_KEY/A14=TERM_STAT_ARRAY_1|D1;
END
TABLE FILE ADTEMP4
PRINT D1 BY SUPER_JN_KEY
ON TABLE HOLD AS ADTEMP5
WHERE TERM_STAT_ARRAY_1 NE '';
END
-*
JOIN SUPER_JN_KEY IN ADTEMP5 TO KEY IN RTFILE AS J2
DEFINE FILE ADTEMP5
REC_TRM/A5=EDIT(SUPER_JN_KEY,'99999');
CHK_FLD/A1=EDIT(SECTION_ID,'$$$$9');
END
TABLE FILE ADTEMP5
PRINT REC_TRM SECTION_ID OFFICIAL_GRADE BY D1
ON TABLE HOLD AS PLAY4
WHERE (OFFICIAL_GRADE NE '' OR SPE_STATUS EQ 'E') AND (CHK_FLD LT '5');
END
-*
-* CREATE AN E-MAIL IF ANY STUDENT HAS EVER ENROLLED/GRADED
-*
JOIN D1 IN PLAY4 TO STU_ID IN AAFILE AS J3
TABLE FILE PLAY4
PRINT REC_TRM AS 'Term' SECTION_ID AS 'Course' OFFICIAL_GRADE AS 'Grade'
BY STU_NAME
BY D1 AS 'Student Id'
ON TABLE SAVE AS PLAY4A FORMAT WP
END
-*
-* REVOVE DUPLICATES
-*
TABLE FILE ADTEMP5
PRINT SUPER_JN_KEY BY D1
ON TABLE HOLD AS ADTEMP5A
WHERE (OFFICIAL_GRADE NE '' OR SPE_STATUS EQ 'E') AND (CHK_FLD LT '5');
END
-*
DEFINE FILE ADTEMP5A
THS_REC/A1=IF D1 NE LAST D1 THEN 'Y' ELSE 'N';
END
TABLE FILE ADTEMP5A
PRINT THS_REC BY D1
ON TABLE HOLD AS ADTEMP5B
IF THS_REC EQ 'Y'
END
-*
-* SAVE THOSE STUDENTS WHO HAVE NEVER ENROLLED
-*
MATCH FILE ADTEMP4
PRINT D2 BY D1
RUN
FILE ADTEMP5B
PRINT THS_REC BY D1
AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
-*
JOIN CLEAR *
JOIN D1 IN HOLD TO STU_ID IN AAFILE AS J1
DEFINE FILE HOLD
SUPER_JN_KEY/A14=TERM_STAT_ARRAY_1|D1;
END
TABLE FILE HOLD
PRINT D1 BY SUPER_JN_KEY
ON TABLE HOLD AS ADTEMP6
WHERE TERM_STAT_ARRAY_1 NE '';
END
-*
-* CREATE THE BATCH HEADER
-*
-SET &HDRKEY = '$$$MSC301 PURGE ADM 1 YRE';
]]>
-INCLUDE (SIS Batch Header).SEG
<![CDATA[
JOIN CLEAR *
-*
-* CREATE BATCH TRANSACTIONS TO DROP ALL COURSES FOR STUDENTS WHO NEVER
-* ATTENDED
-*
JOIN SUPER_JN_KEY IN ADTEMP6 TO KEY IN RTFILE AS J1
DEFINE FILE ADTEMP6
OUT_RECORD1/A80=('45B'|D1|'DRP'|TERM|SECTION_ID);
END
TABLE FILE ADTEMP6
PRINT OUT_RECORD1
ON TABLE SAVE AS PLAY
WHERE SPE_STATUS EQ 'D';
END
-*
-* GET STUDENTS WHO WERE ACTIVATED BUT NOT ENROLLED IN A TERM
-*
TABLE FILE ADTEMP6
PRINT D1 BY SUPER_JN_KEY
ON TABLE HOLD AS ADTEMP6A
WHERE SPE_STATUS EQ 'E';
END
-*
-* REVOVE DUPLICATES
-*
DEFINE FILE ADTEMP6A
THS_REC/A1=IF SUPER_JN_KEY NE LAST SUPER_JN_KEY THEN 'Y' ELSE 'N';
END
TABLE FILE ADTEMP6A
PRINT D1 BY SUPER_JN_KEY
ON TABLE HOLD AS ADTEMP6B
IF THS_REC EQ 'Y'
END
-*
MATCH FILE ADTEMP6
PRINT D1 BY SUPER_JN_KEY
RUN
FILE ADTEMP6B
PRINT D1 BY SUPER_JN_KEY
AFTER MATCH HOLD AS ADTEMP6C OLD-NOT-NEW
END
-RUN
-*
-* CREATE BATCH TRANSACTIONS TO DELETE ALL ACTIVE TERMS IN WHICH A
-* STUDENT WAS NOT ENROLLED
-*
DEFINE FILE ADTEMP6C
OUT_RECORD/A80=('49D'|D1|' '|EDIT(SUPER_JN_KEY,'99999'));
END
TABLE FILE ADTEMP6C
PRINT OUT_RECORD
ON TABLE SAVE AS PLAY
END
-*
-* CREATE BATCH TRANSACTIONS TO DELETE ALL HIGH SCHOOL INFORMATION
-*
JOIN CLEAR *
JOIN D1 IN HOLD TO STU_ID IN RBFILE AS J1
DEFINE FILE HOLD
ALPHA_HS_INST/A7=EDIT(HS_INSTITUTION);
ALPHA_HS_BEGIN_DT/A6=IF EDIT(HS_BEGIN_DT) EQ '000000' THEN '001020'
ELSE EDIT(HS_BEGIN_DT);
ALPHA_HS_END_DT/A6=EDIT(HS_END_DT);
-*
OUT_RECORD/A80=('32D'|D1|ALPHA_HS_INST|EDIT(ALPHA_HS_BEGIN_DT,'$$$$99')|
EDIT(ALPHA_HS_BEGIN_DT,'9999'));
END
TABLE FILE HOLD
PRINT OUT_RECORD
ON TABLE SAVE AS PLAY
WHERE HS_INSTITUTION NE 0000000;
WHERE RB020_ORDER LE HIGH_SCHOOL_CNTR;
END
-*
-* CREATE BATCH TRANSACTIONS TO DELETE ALL COLLEGE INFORMATION
-*
DEFINE FILE HOLD
ALPHA_COLL_CD/A7=EDIT(CO_INSTITUTION);
ALPHA_CO_BEGIN_DT/A6=EDIT(CO_BEGIN_DT);
-*
OUT_RECORD/A80=('33D'|D1|ALPHA_COLL_CD|EDIT(ALPHA_CO_BEGIN_DT,'$$$$99')|
EDIT(ALPHA_CO_BEGIN_DT,'9999'));
END
TABLE FILE HOLD
PRINT OUT_RECORD
ON TABLE SAVE AS PLAY
WHERE CO_INSTITUTION NE 0000000;
WHERE RB040_ORDER LE COLLEGE_CNTR;
END
-*
-* CREATE BATCH TRANSACTIONS TO DELETE ALL TEST SCORES
-*
DEFINE FILE HOLD
TEST_DT/A8=EDIT(QUERY_TEST_DT);
OUT_RECORD/A80=('31D'|D1|TEST_CODE|EDIT(TEST_DT,'$$$$99')|
EDIT(TEST_DT,'$$$$$$99')|EDIT(TEST_DT,'9999'));
END
TABLE FILE HOLD
PRINT OUT_RECORD
ON TABLE SAVE AS PLAY
WHERE TEST_CODE NE '';
WHERE RB030_ORDER LE TEST_SCORE_CNTR;
END
-*
-* CREATE BATCH TRANSACTIONS TO DELETE ALL ADMISSIONS APPLICATIONS
-*
JOIN CLEAR *
JOIN D1 IN HOLD TO STU_ID IN MMFILE AS J1
DEFINE FILE HOLD
OUT_RECORD/A80=('35X'|D1|APP_TERM|COLLEGE_1|DEGREE_1|MAJOR_1);
END
TABLE FILE HOLD
PRINT OUT_RECORD
ON TABLE SAVE AS PLAY
WHERE APP_TERM NE '';
WHERE MM030_ORDER LE AP_SEG_CNTR;
END
-*
-* CREATE BATCH TRANSACTIONS TO DELETE ALL ADMISSIONS INFORMATION
-*
DEFINE FILE HOLD
OUT_RECORD/A80=('36D'|D1);
END
TABLE FILE HOLD
PRINT OUT_RECORD
ON TABLE SAVE AS PLAY
WHERE STU_ID NE '';
END
-*
-* CREATE BATCH TRANSACTIONS TO DELETE ALL ADVISOR INFORMATION
-*
JOIN CLEAR *
JOIN D1 IN HOLD TO STU_ID IN AAFILE AS J1
DEFINE FILE HOLD
OUT_RECORD/A80=('10B'|D1|' * *');
END
TABLE FILE HOLD
PRINT OUT_RECORD
ON TABLE SAVE AS PLAY
WHERE (ADVISOR_ID_1 NE 000000000) OR (ADVISOR_ID_2 NE 000000000);
WHERE AA050_ORDER LE SR_CNTR;
END
-*
-* CREATE BATCH TRANSACTIONS TO DELETE ALL REGISTRATION TERMS
-*
DEFINE FILE HOLD
SUPER_JN_KEY/A14=TERM_STAT_ARRAY_1|D1;
END
TABLE FILE HOLD
PRINT D1 BY SUPER_JN_KEY
ON TABLE HOLD AS HLDTMP1
WHERE TERM_STAT_ARRAY_1 NE '';
END
-*
JOIN CLEAR *
JOIN SUPER_JN_KEY IN HLDTMP1 TO KEY IN RTFILE AS J1
DEFINE FILE HLDTMP1
OUT_RECORD/A80=('40D'|D1|' '|TERM|COLLEGE_SEC|' '|DEGREE_SEC|MAJOR_1_SEC);
END
TABLE FILE HLDTMP1
PRINT OUT_RECORD
ON TABLE SAVE AS PLAY
WHERE MAJOR_1_SEC NE '';
END
-*
-* CREATE BATCH TRANSACTIONS TO DELETE ALL INITIAL STATISTICS
-*
JOIN CLEAR *
JOIN D1 IN HOLD TO STU_ID IN RAFILE AS J1
DEFINE FILE HOLD
OUT_RECORD/A80=('58D'|D1|' '|CAREER);
END
TABLE FILE HOLD
PRINT OUT_RECORD
ON TABLE SAVE AS PLAY
WHERE CAREER NE '';
WHERE RA020_ORDER LE INIT_STATS_CNTR;
END
-*
-* CREATE BATCH TRANSACTIONS TO DELETE ALL HOLDS/COMMENTS
-*
JOIN CLEAR *
JOIN D1 IN HOLD TO STU_ID IN AMFL010 AS J1
DEFINE FILE HOLD
ALPHA_DATE/A8=EDIT(HOLD_EFF_DATE);
OUT_RECORD/A80=('16D'|D1|' '|HOLD_COMMENT_KEY|
EDIT(ALPHA_DATE,'$$$$99')|EDIT(ALPHA_DATE,'$$$$$$99')|
EDIT(ALPHA_DATE,'9999')|ENTRY_OFFICE|REASON);
END
TABLE FILE HOLD
PRINT OUT_RECORD
ON TABLE SAVE AS PLAY
WHERE HOLD_COMMENT_KEY NE '';
END
-*
-* CREATE BATCH TRANSACTIONS TO DELETE ALL TRANSFER CREDIT ACTIVITY
-*
JOIN CLEAR *
JOIN D1 IN HOLD TO STU_ID IN RXFILE AS J1
DEFINE FILE HOLD
OUT_RECORD/A80=('50D'|D1|CAREER|INSTITUTION|EXTR_COURSE);
END
TABLE FILE HOLD
PRINT OUT_RECORD
ON TABLE SAVE AS PLAY
WHERE STUDY_ABROAD NE 'Y';
WHERE CAREER NE '';
END
-*
-* CREATE BATCH TRANSACTIONS TO DELETE ALL FOREIGN CREDIT ACTIVITY
-*
DEFINE FILE HOLD
OUT_RECORD/A80=('51D'|D1|CAREER|INSTITUTION|EXTR_COURSE);
END
TABLE FILE HOLD
PRINT OUT_RECORD
ON TABLE SAVE AS PLAY
WHERE STUDY_ABROAD EQ 'Y';
WHERE CAREER NE '';
END
-*
JOIN CLEAR *
JOIN CLEAR *
-*
-* ADM_PURGE2.FEX
-*
SET PAGE=NOPAGE
SET LINES=999999
FILEDEF HOLD DISK HOLD.FTM
FILEDEF PLAY DISK PLAY.FTM APPEND
-*
-* CREATE THE BATCH HEADER
-*
-SET &HDRKEY = '$$$MSC302 PURGE ADM 2 YRE';
]]>
-INCLUDE (SIS Batch Header).SEG
<![CDATA[
-*
-* CREATE BATCH TRANSACTIONS TO DELETE ALL MATRICULATION RECORDS
-*
JOIN D1 IN HOLD TO STU_ID IN AAFILE AS J1
DEFINE FILE HOLD
OUT_RECORD/A80=('15D'|D1|' '|ENTRY_TERM|COLLEGE|AP_DEG|MAJOR);
END
TABLE FILE HOLD
PRINT OUT_RECORD
ON TABLE SAVE AS PLAY
WHERE COLLEGE NE 'CE';
WHERE AA060_ORDER LE AP_CNTR;
END
JOIN CLEAR *
JOIN CLEAR *
-*
-* ADM_PURGE3.FEX
-*
SET PAGE=NOPAGE
SET LINES=999999
FILEDEF HOLD DISK HOLD.FTM
FILEDEF PLAY DISK PLAY.FTM APPEND
-*
-* CREATE THE BATCH HEADER
-*
-SET &HDRKEY = '$$$MSC303 PURGE ADM 3 YRE';
]]>
-INCLUDE (SIS Batch Header).SEG
<![CDATA[
-*
-* CREATE BATCH TRANSACTIONS TO DELETE STUDENT FROM SIS
-*
DEFINE FILE HOLD
OUT_RECORD/A80=('02D'|D1);
END
TABLE FILE HOLD
PRINT OUT_RECORD
ON TABLE SAVE AS PLAY
END
-*
-* CREATE A LIST OF DELETED STUDENTS FOR ADMISSIONS
-*
JOIN D1 IN HOLD TO STU_ID IN AAFILE AS J1
TABLE FILE HOLD
PRINT D1 AS 'Student Id'
BY STU_NAME
ON TABLE SAVE AS PLAY6 FORMAT WP
END
JOIN CLEAR *
]]>
This page hosted by 
Get your own Free Homepage
