FOCUS program :

-*begin doc
-*
-*FEX:  AM-DECSTAT-SEL-MJR
-*
-*      This produces a list of applicants, admitted students, enrolled
-*      students for a selected major.
-*
-*INPUT
-*      Term
-*      Major
-*
-*USAGE
-*      Used to determine numbers for advisors/department heads on an
-*      as needed basis.
-*
-*end doc
-**********************************************************************
-PROMPT &TERM/A5.ENTER THE FIVE DIGIT TERM FOR APPLICANT REPORT (CCYYX) :
-PROMPT &MAJOR/A2.ENTER THE MAJOR FOR APPLICANT REPORT :
SET LINES=56
JOIN CLEAR *
TABLE FILE MMFILE
PRINT APP_TERM APP_STAT_3 MAJOR_1 MAJOR_3
      COLLEGE_1 COLLEGE_3 APP_STAT_1 APP_DT APP_STAT_DT_3
BY STU_ID
WHERE APP_TERM EQ '&TERM';
ON TABLE HOLD AS MMTEMP1
END
-*
DEFINE FILE RTFILE
IN_RT/A1='Y';
END
MATCH FILE MMTEMP1
PRINT APP_TERM APP_STAT_3 MAJOR_1 MAJOR_3
      COLLEGE_1 COLLEGE_3 APP_STAT_1 APP_DT APP_STAT_DT_3
BY STU_ID
RUN
FILE RTFILE
PRINT IN_RT BY STU_ID
WHERE TERM EQ '&TERM';
AFTER MATCH HOLD OLD
END
-RUN
-*
JOIN STU_ID IN HOLD TO STU_ID IN AAFILE AS J1
DEFINE FILE HOLD
STUD_CTR/I5=IF STU_ID NE ' ' THEN 1 ELSE 0;
D_STAT/A10 = IF (APP_STAT_3 EQ ' ') THEN 'APPLIED' ELSE
             IF ((APP_STAT_3 EQ 'CC' OR 'CN' OR 'WA') AND  
                 (IN_RT EQ 'Y')) THEN 'ENROLLED' ELSE 'ADMITTED';
-*
APP_FOR_MJ1/A2=IF (D_STAT EQ 'APPLIED') THEN EDIT(MAJOR_1,'99')
               ELSE EDIT(MAJOR_3,'99');
APP_FOR_MJ2/A2=IF (D_STAT EQ 'APPLIED') THEN EDIT(MAJOR_1,'$$99')
               ELSE EDIT(MAJOR_3,'$$99');
CURR_COLL/A3=IF (D_STAT EQ 'APPLIED') THEN COLLEGE_1
               ELSE COLLEGE_3;
CURR_MAJOR/A4=APP_FOR_MJ1|APP_FOR_MJ2;
END
TABLE FILE HOLD
PRINT STU_NAME CURR_COLL CURR_MAJOR APP_STAT_3
      APP_STAT_1 APP_DT APP_STAT_DT_3 D_STAT APP_TERM 
      APP_FOR_MJ2 APP_FOR_MJ1
BY STU_ID
WHERE (APP_FOR_MJ2 EQ '&MAJOR');
ON TABLE HOLD AS MMTEMP2
END
-*
JOIN STU_ID IN MMTEMP2 TO STU_ID IN ADFILE AS J2
TABLE FILE MMTEMP2
PRINT STU_NAME CURR_COLL CURR_MAJOR APP_STAT_3
      APP_STAT_1 APP_DT APP_STAT_DT_3 D_STAT APP_TERM 
      APP_FOR_MJ2 APP_FOR_MJ1 PHONE
BY STU_ID
WHERE AD020_ORDER EQ 1;
ON TABLE HOLD AS MMTEMP3
END
-*
DEFINE FILE MMTEMP3
SSN/A11 = EDIT (STU_ID, '999-99-9999');
PHONE/A13 = EDIT (PHONE, '(999)999-9999');
STUD_CTR/I5=IF STU_ID NE ' ' THEN 1 ELSE 0;
YR/A4 = EDIT (APP_TERM,'9999$');
TM/A1 = EDIT (APP_TERM,'$$$$9');
TRM/A6 = DECODE TM (1 'Fall' 2 'Spring' 3 'Summer');
END
TABLE FILE MMTEMP3            
"Report Name: AM-DECSTAT-SEL-MJR"
" "
"Students Who Have Applied To College For Term: <APP_TERM "
" "
"                                               <D_STAT Students"
"                                               <TRM Term <YR"
" "                           
PRINT STU_NAME AS 'Student Name' SSN AS 'Student ID' PHONE AS 'Phone'
      CURR_COLL AS 'College' CURR_MAJOR AS 'Major' 
      D_STAT AS 'Decision,Status'
      APP_STAT_3 AS 'Appl,Status' APP_DT AS 'Appl,Date'
      APP_STAT_DT_3 AS 'Appl,Status,Date-3'
BY D_STAT NOPRINT
BY CURR_COLL NOPRINT
BY APP_FOR_MJ2 NOPRINT
BY APP_FOR_MJ1 NOPRINT
BY STU_NAME NOPRINT
ON D_STAT SUBFOOT
"</1 TOTAL FOR DECISION STATUS <D_STAT IS <ST.STUD_CTR"
ON TABLE SUBFOOT
"</2 GRAND TOTAL OF STUDENTS: <CT.STUD_CTR"
ON TABLE HOLD AS REPORT FORMAT WP
END                                                                           
JOIN CLEAR *

This page hosted by Get your own Free Homepage