FOCUS program :

-*begin doc
-*
-*FEX:	AM-APP-ADMIT-WO-CLASSES-LABELS
-*
-*	This produces labels for students who have been admitted but did
-*	not register for classes.
-*
-*INPUT
-*	TERM
-*
-*USAGE
-*	Used after registration to send letters to students.
-*
-*end doc
-**********************************************************************
SET LINES=56
JOIN CLEAR *
-PROMPT &TERM/A5.ENTER THE FIVE DIGIT TERM FOR APPLICANT LABELS (CCYYX) :
-*
-*  Select students who applied, but were not accepted in Admissions.
-*
TABLE FILE MMFILE
PRINT APP_TERM BY STU_ID 
WHERE APP_TERM EQ '&TERM';
WHERE MAJOR_3 NE '';
WHERE MM030_ORDER EQ 1;
ON TABLE HOLD AS MMTEMP1
END
-*
-*  Select students who had enrolled, but dropped all of their classes 
-*  and none of the sections were retained.
-*
TABLE FILE RTFILE
PRINT COLLEGE BY STU_ID
WHERE TERM EQ '&TERM';
WHERE COLLEGE NE 'CE';
WHERE CURR_ATTEMPTED_HRS EQ 0;
WHERE STU_PGM_ENTRY_CNTR EQ 0;
ON TABLE HOLD AS RTTEMP1
END
-* 
-*  Select students who had enrolled, but dropped all of their classes, 
-*  the sections were retained and none of them were CE courses.
-* 
DEFINE FILE RTFILE
MY_SPE/A3=IF COLLEGE_SPE EQ 'CE' THEN 'AAA' ELSE COLLEGE_SPE;
END
TABLE FILE RTFILE
PRINT TERM BY STU_ID BY MY_SPE
WHERE TERM EQ '&TERM';
WHERE CURR_ATTEMPTED_HRS EQ 0;
WHERE RT020_ORDER LE STU_PGM_ENTRY_CNTR;
ON TABLE HOLD AS RTTEMP2
END
-* 
TABLE FILE RTTEMP2
SUM MY_SPE BY STU_ID
ON TABLE HOLD AS RTTEMP3
END
-*
DEFINE FILE RTTEMP3
THS_REC/A1=IF MY_SPE EQ 'AAA' THEN 'Y' ELSE 'N';
END
TABLE FILE RTTEMP3
PRINT MY_SPE BY STU_ID
WHERE THS_REC EQ 'N';
ON TABLE HOLD AS RTTEMP4
END
-*
-*  Combine the files created above.
-*
MATCH FILE RTTEMP1
PRINT COLLEGE BY STU_ID 
RUN
FILE RTTEMP4
PRINT MY_SPE BY STU_ID 
AFTER MATCH HOLD OLD-OR-NEW
END
-RUN
-*
MATCH FILE MMTEMP1
PRINT APP_TERM BY STU_ID 
RUN
FILE HOLD
PRINT COLLEGE MY_SPE BY STU_ID
AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
-*
-*  Eliminate students who are enrolled for the current term (just
-*  to double-check).
-*
MATCH FILE HOLD
PRINT APP_TERM BY STU_ID 
RUN
FILE RTFILE
PRINT TERM BY STU_ID 
IF TERM EQ '&TERM'
IF CURR_ATTEMPTED_HRS GT 0
AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
-*
-*  Produce labels from the final list.
-*
JOIN STU_ID IN HOLD TO STU_ID IN AAFILE AS J2
JOIN STU_ID IN HOLD TO STU_ID IN ADFILE AS J3
DEFINE FILE HOLD
-INCLUDE SI$FOCUS:NAMEPARS.SEG
UP_NAME/A32=UPCASE(32,STU_NAME,UP_NAME);
STA_ZIP/A9=STATE|'  '|EDIT(ZIP_CODE_DPBC,'99999');
END
TABLE FILE HOLD                                                          
PRINT FUL_NAME STREET_1 STREET_2 CITY STA_ZIP UP_NAME
BY UP_NAME NOPRINT
ON TABLE HOLD AS LABELS
IF AD020_ORDER EQ 1
END                                                                           
JOIN CLEAR *

This page hosted by Get your own Free Homepage