FOCUS program #1 :

-*begin doc
-*
-*AM-FA-NOAPP
-*
-*	This produces a listing of students who are active in 
-*      Financial Aid but have not applied for Admissions.
-*
-*INPUT
-*	AWARD YEAR
-*
-*end doc
-**********************************************************************
-PROMPT &AYR/A4.ENTER THE FOUR DIGIT AWARD YEAR (CCYY) :
SET LINES=56
JOIN CLEAR *
-*
-*  Select students active in Financial Aid.
-*
TABLE FILE SAFILE
PRINT AWD_YR BY STU_ID
WHERE AWD_YR EQ '&AYR';
ON TABLE HOLD AS SATEMP1
END
-*
-*  Select all Financial Aid students who are being tracked for
-*  Admissions on screen 306.
-*             
JOIN TEMP_KEY WITH STU_ID IN SATEMP1 TO KEY IN STFILE AS J1
DEFINE FILE SATEMP1
TEMP_KEY/A13=('&AYR'|STU_ID);
END
TABLE FILE SATEMP1
PRINT TRK_FORM TRK_STAT AWD_YR
BY STU_ID
WHERE (TRK_FORM EQ 'ADMS') AND (TRK_STAT EQ ' '); 
WHERE ST020_ORDER LE TRK_CNTR;
ON TABLE HOLD AS SATEMP2
END
-*
-*  Select students not active in Admissions
-*
MATCH FILE SATEMP2
PRINT AWD_YR BY STU_ID
RUN
FILE MMFILE
PRINT MM_HOUS_STAT BY STU_ID
AFTER MATCH HOLD OLD-NOT-NEW
END
-RUN
-*
JOIN STU_ID IN HOLD TO KEY IN AAFILE AS J2
JOIN STU_ID IN HOLD TO KEY IN ADFILE AS J3
DEFINE FILE HOLD
PHONE/A13 = EDIT(PHONE,'(999)999-9999');
SSN/A11 = EDIT(STU_ID,'999-99-9999');
END
TABLE FILE HOLD
"Report Name: AM-FA-NOAPP"
" "
"Students Who Active In FINANCIAL AID But Have Not Applied For ADMISSIONS"
" "
PRINT SSN AS 'Student ID' PHONE AS 'Phone'
BY STU_NAME
WHERE AD020_ORDER LE ADDRESS_CTR;
WHERE (ADDR_TYPE_1 EQ 'P') OR (ADDR_TYPE_2 EQ 'P') OR (ADDR_TYPE_3 EQ 'P') OR
      (ADDR_TYPE_4 EQ 'P') OR (ADDR_TYPE_5 EQ 'P'); 
ON TABLE HOLD AS REPORT FORMAT WP
END
JOIN CLEAR *


FOCUS program #2 :

-*begin doc
-*
-*AM-FA-NOTACC
-*
-*	This produces a listing of students who are active in 
-*      Financial Aid but have not been accepted in Admissions.
-*
-*INPUT
-*	AWARD YEAR
-*
-*end doc
-**********************************************************************
-PROMPT &AYR/A4.Enter the award year (CCYY) :
-PROMPT &TERM/A5.Enter the enrollment term (CCYYX) :
SET LINES=56
JOIN CLEAR *
-*
-*  Select students active in Financial Aid.
-*
TABLE FILE SAFILE
PRINT AWD_YR BY STU_ID
WHERE AWD_YR EQ '&AYR';
ON TABLE HOLD AS SATEMP1
END
-*
-*  Select all Financial Aid students who are being tracked for
-*  Admissions on screen 306.
-*             
JOIN TEMP_KEY WITH STU_ID IN SATEMP1 TO KEY IN STFILE AS J1
DEFINE FILE SATEMP1
TEMP_KEY/A13=('&AYR'|STU_ID);
END
TABLE FILE SATEMP1
PRINT TRK_FORM TRK_STAT AWD_YR
BY STU_ID
WHERE (TRK_FORM EQ 'ADMS') AND (TRK_STAT EQ ' '); 
WHERE ST020_ORDER LE TRK_CNTR;
ON TABLE HOLD AS SATEMP2
END
-*
-*  Select students (new or re-admit) not accepted in Admissions
-*
MATCH FILE SATEMP2
PRINT AWD_YR BY STU_ID
RUN
FILE MMFILE
PRINT MAJOR_3 BY STU_ID
WHERE MM030_ORDER LE AP_SEG_CNTR;
WHERE MAJOR_3 EQ '';
WHERE APP_TERM EQ '&TERM';
AFTER MATCH HOLD OLD-AND-NEW
END
-RUN
-*
JOIN STU_ID IN HOLD TO KEY IN AAFILE AS J2
JOIN STU_ID IN HOLD TO KEY IN ADFILE AS J3
DEFINE FILE HOLD
PHONE/A13 = EDIT(PHONE,'(999)999-9999');
SSN/A11 = EDIT(STU_ID,'999-99-9999');
END
TABLE FILE HOLD
"Report Name: AM-FA-NOTACC"
" "
"Students Who Active In FINANCIAL AID But Not Accepted in ADMISSIONS"
" "
PRINT SSN AS 'Student ID' PHONE AS 'Phone'
BY STU_NAME
WHERE AD020_ORDER LE ADDRESS_CTR;
WHERE (ADDR_TYPE_1 EQ 'P') OR (ADDR_TYPE_2 EQ 'P') OR (ADDR_TYPE_3 EQ 'P') OR
      (ADDR_TYPE_4 EQ 'P') OR (ADDR_TYPE_5 EQ 'P'); 
ON TABLE HOLD AS REPORT FORMAT WP
END
JOIN CLEAR *

This page hosted by Get your own Free Homepage