FOCUS Program :

-*    Description: To create the Prospective Applicants Report By State
-*                 The report produced is for a specified state sorted
-*                 by high school then by last name of prospect.
-*
  JOIN CLEAR *
  SET MORE=OFF, ALL=PASS, ASNAMES=ON, NODATA=' '
-*
  TABLE FILE MMFILE
  PRINT INSTITUTION
        PRE_APP_TERM
  BY STU_ID
  IF PRSPCT_LVL EQ 'F'
  IF PRE_APP_TERM EQ '(Application Term)'
  IF PR_SEG_CNTR GT 0
  ON TABLE HOLD AS (FOCEXEC name)H0
  END
-*
-IF &RECORDS EQ 0 THEN GOTO STOPRUN;
-*
  JOIN STU_ID IN (FOCEXEC name)H0 TO STU_ID IN AAFILE AS J1
-*
  DEFINE FILE (FOCEXEC name)H0
  INST_CODE/A7=EDIT(INSTITUTION);
  END
  TABLE FILE (FOCEXEC name)H0
  PRINT STU_ID
        INST_CODE
        PRE_APP_TERM
        STU_NAME
  BY INSTITUTION
  ON TABLE HOLD AS (FOCEXEC name)H1
  END
-*
  JOIN INST_CODE IN (FOCEXEC name)H1 TO INSTITUTION IN AIFILE AS J2
-*
  TABLE FILE (FOCEXEC name)H1
  PRINT INSTITUTION
        INSTIT_NAME
        PRE_APP_TERM
        STU_NAME
        INST_CODE
  BY STU_ID
  ON TABLE HOLD AS (FOCEXEC name)H2
  END
-*
  JOIN STU_ID IN (FOCEXEC name)H2 TO STU_ID IN ADFILE AS J3
-*
  TABLE FILE (FOCEXEC name)H2
  PRINT STU_ID
        INSTIT_NAME
        PRE_APP_TERM
        STREET_1
        STREET_2
        CITY STATE ZIP_CODE
        PHONE
        INST_CODE
  BY INSTITUTION
  BY STU_NAME
  IF STATE EQ '(Input State)'
  WHERE ADDR_TYPE_1 EQ 'P' OR ADDR_TYPE_2 EQ 'P' OR ADDR_TYPE_3 EQ 'P'
        OR ADDR_TYPE_4 EQ 'P' OR ADDR_TYPE_5 EQ 'P';
  ON TABLE HOLD AS (FOCEXEC name)H3
  END
-*
  DEFINE FILE (FOCEXEC name)H3
  INST_STU_KEY/A50=(INST_CODE|STU_NAME);
  END
  TABLE FILE (FOCEXEC name)H3
  PRINT STU_ID
        INSTITUTION
        INSTIT_NAME
        PRE_APP_TERM
        STU_NAME
        STREET_1
        STREET_2
        CITY STATE ZIP_CODE
        PHONE
  BY INST_STU_KEY
  ON TABLE HOLD AS (FOCEXEC name)H4
  END
-*
  DEFINE FILE (FOCEXEC name)H4
  TAG_NUM/I4=IF INST_STU_KEY EQ LAST INST_STU_KEY THEN 1 ELSE TAG_NUM + 1;
  END
  TABLE FILE (FOCEXEC name)H4
  PRINT STU_ID
        INSTITUTION
        INSTIT_NAME
        PRE_APP_TERM
        STU_NAME
        STREET_1
        STREET_2
        CITY STATE ZIP_CODE
        PHONE
        TAG_NUM
  BY INSTITUTION
  BY STU_NAME
  ON TABLE HOLD AS (FOCEXEC name)H5
  END
-*
  DEFINE FILE (FOCEXEC name)H5
  PHONE_OUT/A13=IF PHONE EQ '' OR '0000000000' THEN ' ' ELSE 
        EDIT(PHONE,'(999)999-9999');
  CITY_OUT/A40=(CITY||(', '|STATE)||('  '|ZIP_CODE));
  OUT_INST_NAME/A35=IF INSTIT_NAME EQ '' THEN 'NONE' ELSE 
        MXCASE(32,INSTIT_NAME,OUT_INST_NAME);  
  SECOND_LINE/A40=IF STREET_2 EQ '' THEN CITY_OUT ELSE STREET_2;
  THIRD_LINE/A40=IF STREET_2 EQ '' THEN PHONE_OUT ELSE CITY_OUT;
  FOURTH_LINE/A40=IF STREET_2 EQ '' THEN '' ELSE PHONE_OUT;
  SKIP_LINE/A10=' ';
  OUT_STATE/A30=MXCASE(30,XSFOCT(30,'AD255',STATE,'',OUT_STATE),OUT_STATE);
  FOLD_INST/A60=IF TAG_NUM EQ 1 THEN ('Institution : '|OUT_INST_NAME)
        ELSE IF (INSTITUTION EQ LAST INSTITUTION) THEN '' ELSE
        ('Institution : '|OUT_INST_NAME);
  END
  TABLE FILE (FOCEXEC name)H5
  HEADING
  " "
  "<+15 Admissions Prospective Applicants Report for (Application Term)"
  "<+15 For State : <OUT_STATE "
  " "
  "     Name                             Address/Phone"
  " "
  PRINT FOLD_INST AS '' IN 1
        OVER SKIP_LINE AS '' IN 1
        OVER STU_NAME AS '' IN 3
        STREET_1 AS '' 
        OVER SECOND_LINE AS '' IN 39
        OVER THIRD_LINE AS '' IN 39
        OVER FOURTH_LINE AS '' IN 39
  BY INSTIT_NAME NOPRINT
  BY STU_NAME NOPRINT
  ON TABLE SAVE AS (FOCEXEC name)R1 FORMAT WP
  END
-*
-GOTO CLEANUP;
-*
-STOPRUN
-TYPE
-TYPE
-TYPE
-TYPE
-TYPE         ********NO RECORDS FOUND********
-TYPE         ************STOP RUN************
-TYPE
-TYPE
-TYPE
-TYPE
-CLEANUP
  VMS IF F$SEARCH("(FOCEXEC name)H%.FTM") .NES. "" THEN DEL (FOCEXEC name)H%.FTM;*
  VMS IF F$SEARCH("(FOCEXEC name)H%.MAS") .NES. "" THEN DEL (FOCEXEC name)H%.MAS;*
-EXIT

This page hosted by Get your own Free Homepage