FOCUS program :
-* Description: To create the Admissions Profile Report for IB schools
-*
-* SI$FEX:IB_SCHOOL_CODES.DOC contains the file of international
-* baccalaureate high school codes.
-*
FILEDEF D_IBSCHS DISK SI$FEX:IB_SCHOOL_CODES.DOC
SET LINES/PAGE=63, LINES=53, MORE=OFF, ALL=PASS, ASNAMES=ON, NODATA=' '
-*
JOIN CLEAR *
TABLE FILE MMFILE
PRINT STU_ID
COMMUN_FLAG_12
APP_TERM
BY STU_ID NOPRINT
IF APP_TERM EQ '(Application Term)'
IF AP_SEG_CNTR GT 0
ON TABLE HOLD AS (FOCEXEC name)H0
END
-*
-IF &RECORDS EQ 0 THEN GOTO STOPRUN;
-*
JOIN STU_ID IN (FOCEXEC name)H0 TO STU_ID IN RBFILE AS J1
-*
DEFINE FILE (FOCEXEC name)H0
INST_A/A7 = EDIT(HS_INSTITUTION,'9999999');
IB_INST/A7=DECODE INST_A(D_IBSCHS ELSE '0000000');
END
TABLE FILE (FOCEXEC name)H0
PRINT STU_ID
COMMUN_FLAG_12
BY STU_ID NOPRINT
IF IB_INST NE '0000000'
IF HIGH_SCHOOL_CNTR GT 0
ON TABLE HOLD AS (FOCEXEC name)HA
END
-*
JOIN STU_ID IN (FOCEXEC name)HA TO STU_ID IN MMFILE AS J10
-*
DEFINE FILE (FOCEXEC name)HA
RQMNT/A2 = RQMNT_RULE_1;
RQED/A1 = EDIT(RQMNT,'9$');
END
-*
TABLE FILE (FOCEXEC name)HA
PRINT STU_ID
COMMUN_FLAG_12
APP_TERM
RQED
BY STU_ID NOPRINT
IF RQED EQ 'F'
IF APP_TERM EQ '(Application Term)'
IF AP_SEG_CNTR GT 0
ON TABLE HOLD AS (FOCEXEC name)H1
END
-*
JOIN STU_ID IN (FOCEXEC name)H1 TO STU_ID IN MMFILE AS J2
-*
TABLE FILE (FOCEXEC name)H1
PRINT STU_ID
RESIDENT_STAT
APP_STAT_1
APP_STAT_3
APP_STAT_DT_3
MM_LETTER_CODE
RQMNT_RULE_1
RQED
BY STU_ID NOPRINT
IF RQED EQ 'F'
IF APP_TERM EQ '(Application Term)'
IF AP_SEG_CNTR GT 0
ON TABLE HOLD AS (FOCEXEC name)H2
END
-*
-IF &RECORDS EQ 0 THEN GOTO STOPRUN;
-*
JOIN CLEAR *
JOIN STU_ID IN (FOCEXEC name)H1 TO STU_ID IN MMFILE AS J3
-*
TABLE FILE (FOCEXEC name)H1
PRINT STU_ID
MAJOR_1
BY STU_ID NOPRINT
ON TABLE HOLD AS (FOCEXEC name)H3
END
-*
-IF &RECORDS EQ 0 THEN GOTO STOPRUN;
-*
JOIN CLEAR *
JOIN STU_ID IN (FOCEXEC name)H1 TO STU_ID IN (FOCEXEC name)H2 AS J4
JOIN STU_ID IN (FOCEXEC name)H1 TO STU_ID IN (FOCEXEC name)H3 AS J5
JOIN STU_ID IN (FOCEXEC name)H1 TO STU_ID IN ADFILE AS J6
-*
TABLE FILE (FOCEXEC name)H1
PRINT STU_ID
RESIDENT_STAT
MAJOR_1
APP_STAT_1
APP_STAT_3
APP_STAT_DT_3
MM_LETTER_CODE
COMMUN_FLAG_12
STATE
RQMNT_RULE_1
RQED
BY STU_ID NOPRINT
WHERE ADDR_TYPE_1 EQ 'P' OR ADDR_TYPE_2 EQ 'P' OR ADDR_TYPE_3 EQ 'P'
OR ADDR_TYPE_4 EQ 'P' OR ADDR_TYPE_5 EQ 'P';
ON TABLE HOLD AS (FOCEXEC name)H4
END
-*
JOIN CLEAR *
JOIN STU_ID IN (FOCEXEC name)H4 TO STU_ID IN RBFILE AS J7
-*
DEFINE FILE (FOCEXEC name)H4
ACT_SCORE/I4 = IF TEST_CODE EQ 'ACT' THEN TEST_SCORE_5 ELSE 0;
SAT_SCORE_V/I4 = IF (TEST_CODE EQ 'SAT') THEN TEST_SCORE_1 ELSE 0;
SAT_SCORE_M/I4 = IF (TEST_CODE EQ 'SAT') THEN TEST_SCORE_2 ELSE 0;
ACT_CODE/A5 = IF TEST_CODE EQ 'ACT' THEN TEST_CODE ELSE ' ';
SAT_CODE/A5 = IF TEST_CODE EQ 'SAT' THEN TEST_CODE ELSE ' ';
-*
EDIT_ACT_A/A4 = EDIT(TEST_SCORE_5,'9999');
EDIT_SAT_M/A4 = EDIT(SAT_SCORE_M,'9999');
EDIT_SAT_V/A4 = EDIT(SAT_SCORE_V,'9999');
EDIT_ACT_I/I4 = EDIT(EDIT_ACT_A);
EDIT_SAT_IM/I4 = EDIT(EDIT_SAT_M);
EDIT_SAT_IV/I4 = EDIT(EDIT_SAT_V);
EDIT_ACT/A4 = EDIT(EDIT_ACT_I);
SAT_MATH/A4 = EDIT(EDIT_SAT_IM);
SAT_VERB/A4 = EDIT(EDIT_SAT_IV);
-*
END
-*
TABLE FILE (FOCEXEC name)H4
PRINT STU_ID
ACT_CODE
ACT_SCORE
EDIT_ACT
EDIT_ACT_I
IF TEST_CODE EQ 'ACT'
IF TEST_SCORE_5 GT 0
ON TABLE SET ALL OFF
ON TABLE HOLD AS (FOCEXEC name)H5
END
-*
TABLE FILE (FOCEXEC name)H4
PRINT STU_ID
SAT_CODE
SAT_SCORE_V
SAT_SCORE_M
SAT_MATH
SAT_VERB
EDIT_SAT_IM
EDIT_SAT_IV
IF TEST_CODE EQ 'SAT'
IF TEST_SCORE_1 GT 0
IF TEST_SCORE_2 GT 0
ON TABLE SET ALL OFF
ON TABLE HOLD AS (FOCEXEC name)H6
END
-*
DEFINE FILE (FOCEXEC name)H5
CNT/I4 = IF STU_ID EQ LAST STU_ID THEN (CNT + 1) ELSE 1;
END
-*
TABLE FILE (FOCEXEC name)H5
PRINT STU_ID
ACT_CODE
ACT_SCORE
EDIT_ACT
EDIT_ACT_I
CNT
BY STU_ID
BY HIGHEST 1 ACT_SCORE
BY HIGHEST 1 CNT
ON TABLE SET ALL OFF
ON TABLE HOLD AS (FOCEXEC name)H7
END
-*
DEFINE FILE (FOCEXEC name)H6
CNT/I4 = IF STU_ID EQ LAST STU_ID THEN (CNT + 1) ELSE 1;
END
-*
TABLE FILE (FOCEXEC name)H6
PRINT STU_ID
SAT_CODE
SAT_SCORE_V
SAT_VERB
EDIT_SAT_IV
CNT
BY STU_ID
BY HIGHEST 1 SAT_SCORE_V
BY HIGHEST 1 CNT
ON TABLE SET ALL OFF
ON TABLE HOLD AS (FOCEXEC name)H8
END
-*
TABLE FILE (FOCEXEC name)H6
PRINT STU_ID
SAT_CODE
SAT_SCORE_M
SAT_MATH
EDIT_SAT_IM
CNT
BY STU_ID
BY HIGHEST 1 SAT_SCORE_M
BY HIGHEST 1 CNT
ON TABLE SET ALL OFF
ON TABLE HOLD AS (FOCEXEC name)H9
END
-*
JOIN CLEAR *
JOIN STU_ID IN (FOCEXEC name)H4 TO STU_ID IN RBFILE AS J8
-*
DEFINE FILE (FOCEXEC name)H4
INSTITUTION_A/A7 = EDIT(HS_INSTITUTION,'9999999');
END
-*
TABLE FILE (FOCEXEC name)H4
PRINT INSTITUTION_A
STU_ID
RANK_PERCENTILE
BY INSTITUTION_A
ON TABLE HOLD AS (FOCEXEC name)I1
END
-*
-*IF &RECORDS EQ 0 THEN GOTO STOPRUN;
-*
JOIN CLEAR *
JOIN INSTITUTION_A IN (FOCEXEC name)I1 TO INSTITUTION IN AIFILE AS J9
-*
TABLE FILE (FOCEXEC name)I1
PRINT INSTITUTION_A
INSTIT_NAME
RANK_PERCENTILE
BY STU_ID
ON TABLE HOLD AS (FOCEXEC name)I2
END
-*
JOIN CLEAR *
JOIN STU_ID IN (FOCEXEC name)H4 TO STU_ID IN (FOCEXEC name)H7 AS K1
JOIN STU_ID IN (FOCEXEC name)H4 TO STU_ID IN (FOCEXEC name)H8 AS K2
JOIN STU_ID IN (FOCEXEC name)H4 TO STU_ID IN (FOCEXEC name)H9 AS K0
JOIN STU_ID IN (FOCEXEC name)H4 TO STU_ID IN (FOCEXEC name)I2 AS K3
JOIN STU_ID IN (FOCEXEC name)H4 TO STU_ID IN AAFILE AS K4
-*
DEFINE FILE (FOCEXEC name)H4
SAT_SCORE/I4 = (EDIT_SAT_IM + EDIT_SAT_IV);
SAT_SCORE_A/A4 = EDIT(SAT_SCORE,'9999');
SAT_SCORE_I/I4 = EDIT(SAT_SCORE_A);
EDIT_SAT/A4 = EDIT(SAT_SCORE_I);
END
-*
TABLE FILE (FOCEXEC name)H4
PRINT STU_ID
ACT_CODE
ACT_SCORE
EDIT_ACT
EDIT_ACT_I
SAT_CODE
SAT_SCORE
EDIT_SAT
INSTIT_NAME
RANK_PERCENTILE
STU_NAME
ETHNIC_ORIGIN
SEX
BY STU_ID NOPRINT
ON TABLE HOLD AS (FOCEXEC name)I3
END
-*
-IF &RECORDS EQ 0 THEN GOTO STOPRUN;
-*
-*
JOIN CLEAR *
JOIN STU_ID IN (FOCEXEC name)H4 TO STU_ID IN (FOCEXEC name)I3 AS K5
-*
-*
TABLE FILE (FOCEXEC name)H4
PRINT STU_ID
STU_NAME
ETHNIC_ORIGIN
SEX
MAJOR_1
STATE
EDIT_SAT
EDIT_ACT
INSTIT_NAME
RANK_PERCENTILE
APP_STAT_1
APP_STAT_3
MM_LETTER_CODE
COMMUN_FLAG_12
APP_STAT_DT_3
RESIDENT_STAT
SAT_SCORE
EDIT_ACT_I
ACT_SCORE
SAT_SCORE
BY INSTIT_NAME
BY HIGHEST EDIT_SAT
BY STU_NAME
ON TABLE HOLD AS (FOCEXEC name)I9
END
-*
DEFINE FILE (FOCEXEC name)I9
-*
-*
APP_PA1/I1 = IF (APP_STAT_3 EQ 'AC' OR 'AP' OR 'AR' OR 'AU') AND
(COMMUN_FLAG_12 EQ '2') THEN 1 ELSE 0;
APP_CA2/I1 = IF (APP_STAT_3 EQ 'AC' OR 'AP' OR 'AR' OR 'AU') AND
(COMMUN_FLAG_12 EQ '1') THEN 1 ELSE 0;
APP_PWL3/I1 = IF (APP_STAT_3 EQ ' ') AND
(APP_STAT_1 EQ 'HO') AND
(COMMUN_FLAG_12 EQ '2') THEN 1 ELSE 0;
APP_CWL4/I1 = IF (APP_STAT_3 EQ ' ') AND
(APP_STAT_1 EQ 'HO') AND
(COMMUN_FLAG_12 EQ '1') THEN 1 ELSE 0;
APP_PSTEP5/I1 = IF (APP_STAT_3 EQ 'AS') AND
(COMMUN_FLAG_12 EQ '2') THEN 1 ELSE 0;
APP_CSTEP6/I1 = IF (APP_STAT_3 EQ 'AS') AND
(COMMUN_FLAG_12 EQ '1') THEN 1 ELSE 0;
APP_PLEAP7/I1 = IF (APP_STAT_3 EQ 'AI') AND
(COMMUN_FLAG_12 EQ '2') THEN 1 ELSE 0;
APP_CLEAP8/I1 = IF (APP_STAT_3 EQ 'AI') AND
(COMMUN_FLAG_12 EQ '1') THEN 1 ELSE 0;
APP_PR9/I1 = IF (APP_STAT_3 EQ ' ') AND
(APP_STAT_1 EQ 'RJ') AND
(COMMUN_FLAG_12 EQ '2') THEN 1 ELSE 0;
APP_CR10/I1 = IF (APP_STAT_3 EQ ' ') AND
(APP_STAT_1 EQ 'RJ') AND
(COMMUN_FLAG_12 EQ '1') THEN 1 ELSE 0;
APP_NAT11/I1 = IF (APP_STAT_3 EQ ' ' OR 'NC') AND
(COMMUN_FLAG_12 EQ ' ' OR '3') THEN 1 ELSE 0;
APP_SDM12/I1 = IF (APP_STAT_3 EQ ' ') AND
(COMMUN_FLAG_12 EQ '3') THEN 1 ELSE 0;
APP_W13/I1 = IF APP_STAT_3 EQ 'WD' OR 'WA' OR 'WB' THEN 1 ELSE 0;
-*
GROUP/I2 = IF APP_PA1 EQ 1 THEN 1
ELSE
IF APP_CA2 EQ 1 THEN 2
ELSE
IF APP_PWL3 EQ 1 THEN 3
ELSE
IF APP_CWL4 EQ 1 THEN 4
ELSE
IF APP_PSTEP5 EQ 1 THEN 5
ELSE
IF APP_CSTEP6 EQ 1 THEN 6
ELSE
IF APP_PLEAP7 EQ 1 THEN 7
ELSE
IF APP_CLEAP8 EQ 1 THEN 8
ELSE
IF APP_PR9 EQ 1 THEN 9
ELSE
IF APP_CR10 EQ 1 THEN 10
ELSE
IF APP_NAT11 EQ 1 THEN 11
ELSE
IF APP_SDM12 EQ 1 THEN 12
ELSE
IF APP_W13 EQ 1 THEN 13;
-*
STUID/A11 = EDIT(STU_ID,'999-99-9999');
DECISION_DT/MDY = APP_STAT_DT_3;
STAT/A2 = IF GROUP EQ 1 OR 2 OR 5 OR 6 OR 7 OR 8 OR 11 OR 12 OR 13
THEN APP_STAT_3
ELSE APP_STAT_1;
-*
T_MALE/I4 = IF SEX EQ 'M' THEN (T_MALE + 1) ELSE (T_MALE + 0);
T_FEMALE/I4 = IF SEX EQ 'F' THEN (T_FEMALE + 1) ELSE (T_FEMALE + 0);
T_ORIGIN_W/I4 = IF ETHNIC_ORIGIN EQ '6' THEN (T_ORIGIN_W + 1)
ELSE (T_ORIGIN_W + 0);
T_ORIGIN_B/I4 = IF ETHNIC_ORIGIN EQ '2' THEN (T_ORIGIN_B + 1)
ELSE (T_ORIGIN_B + 0);
T_ORIGIN_O/I4 = IF ETHNIC_ORIGIN NE '2' OR '6' THEN (T_ORIGIN_O + 1)
ELSE (T_ORIGIN_O + 0);
T_RES_I/I4 = IF RESIDENT_STAT EQ 'R' THEN (T_RES_I + 1)
ELSE (T_RES_I + 0);
T_RES_O/I4 = IF RESIDENT_STAT NE 'R' THEN (T_RES_O + 1)
ELSE (T_RES_O + 0);
T_STU_CNT/I4 = T_STU_CNT + 1;
TRUE_SAT_STU/I4 = IF SAT_SCORE GT 0 THEN (TRUE_SAT_STU + 1)
ELSE (TRUE_SAT_STU + 0);
TRUE_RANK_STU/I4 = IF RANK_PERCENTILE GT 0 THEN (TRUE_RANK_STU + 1)
ELSE (TRUE_RANK_STU + 0);
-*
T_PCT_MALE/F6.0 = (T_MALE/T_STU_CNT)*100;
T_PCT_FEMALE/F6.0 = (T_FEMALE/T_STU_CNT)*100;
T_PCT_W/F6.0 = (T_ORIGIN_W/T_STU_CNT)*100;
T_PCT_B/F6.0 = (T_ORIGIN_B/T_STU_CNT)*100;
T_PCT_O/F6.0 = (T_ORIGIN_O/T_STU_CNT)*100;
T_PCT_RES_I/F6.0 = (T_RES_I/T_STU_CNT)*100;
T_PCT_RES_O/F6.0 = (T_RES_O/T_STU_CNT)*100;
T_SAT_SCORE/I8 = T_SAT_SCORE + SAT_SCORE;
T_RANK_PERCENTILE/I8 = T_RANK_PERCENTILE + RANK_PERCENTILE;
T_MEAN_SAT/F8.2S = T_SAT_SCORE/TRUE_SAT_STU;
T_MEAN_PCT/F6.2S = T_RANK_PERCENTILE/TRUE_RANK_STU;
END
-*
-*
TABLE FILE (FOCEXEC name)I9
HEADING CENTER
" "
"Admissions Profile Report (IB Schools) for (Application Term)"
" "
" "
PRINT STUID AS 'ID'
STU_NAME/A18 AS 'Student Name'
ETHNIC_ORIGIN AS 'Ethnic'
SEX AS 'Gender'
MAJOR_1 AS 'Major'
STATE AS 'State'
SAT_SCORE AS 'SAT'
EDIT_ACT AS 'ACT'
INSTIT_NAME/A17 AS 'High School'
RANK_PERCENTILE AS 'Rank'
STAT AS 'Status'
MM_LETTER_CODE AS 'Code'
COMMUN_FLAG_12 AS 'Flag'
DECISION_DT AS 'Decision, Date'
BY INSTIT_NAME NOPRINT
BY HIGHEST EDIT_SAT NOPRINT
BY STU_NAME NOPRINT
-*
ON INSTIT_NAME SUBHEAD
" "
" "
ON TABLE SUBFOOT
" "
" "
" "
" "
"<+10 G R A N D T O T A L S "
" "
"<+5 Male:<T_MALE <+25 <T_PCT_MALE %"
"<+5 Female:<T_FEMALE <+25 <T_PCT_FEMALE %"
"<+5 White:<T_ORIGIN_W <+25 <T_PCT_W %"
"<+5 Black:<T_ORIGIN_B <+25 <T_PCT_B %"
"<+5 Other:<T_ORIGIN_O <+25 <T_PCT_O %"
"<+5 Resident:<T_RES_I <+25 <T_PCT_RES_I %"
"<+5 Non Resident:<T_RES_O <+25 <T_PCT_RES_O %"
"<+5 Mean SAT:<T_MEAN_SAT"
"<+5 Mean PCT:<T_MEAN_PCT"
"<+5 Total Student:<T_STU_CNT"
ON TABLE SAVE AS (FOCEXEC name)R1 FORMAT WP
END
-*
TABLE FILE (FOCEXEC name)I9
HEADING CENTER
" "
"Admissions Profile Report (IB schools) for (Application Term)"
" "
" "
PRINT STUID AS 'ID'
STU_NAME/A18 AS 'Student Name'
ETHNIC_ORIGIN AS 'Ethnic'
SEX AS 'Gender'
MAJOR_1 AS 'Major'
STATE AS 'State'
SAT_SCORE AS 'SAT'
EDIT_ACT AS 'ACT'
INSTIT_NAME/A17 AS 'High School'
RANK_PERCENTILE AS 'Rank'
STAT AS 'Status'
MM_LETTER_CODE AS 'Code'
COMMUN_FLAG_12 AS 'Flag'
DECISION_DT AS 'Decision, Date'
BY MAJOR_1 NOPRINT
BY HIGHEST EDIT_SAT NOPRINT
BY STU_NAME NOPRINT
IF STAT NE 'HO' OR 'RJ' OR ' '
IF COMMUN_FLAG_12 EQ '2' OR '4'
-*
ON MAJOR_1 SUBHEAD
" "
" "
ON TABLE SUBFOOT
" "
" "
" "
" "
"<+10 G R A N D T O T A L S "
" "
"<+5 Male:<T_MALE <+25 <T_PCT_MALE %"
"<+5 Female:<T_FEMALE <+25 <T_PCT_FEMALE %"
"<+5 White:<T_ORIGIN_W <+25 <T_PCT_W %"
"<+5 Black:<T_ORIGIN_B <+25 <T_PCT_B %"
"<+5 Other:<T_ORIGIN_O <+25 <T_PCT_O %"
"<+5 Resident:<T_RES_I <+25 <T_PCT_RES_I %"
"<+5 Non Resident:<T_RES_O <+25 <T_PCT_RES_O %"
"<+5 Mean SAT:<T_MEAN_SAT"
"<+5 Mean PCT:<T_MEAN_PCT"
"<+5 Total Student:<T_STU_CNT"
ON TABLE SAVE AS (FOCEXEC name)R2 FORMAT WP
END
JOIN CLEAR *
-*
-GOTO CLEANUP;
-*
-STOPRUN
-TYPE
-TYPE
-TYPE
-TYPE
-TYPE ********NO RECORDS FOUND********
-TYPE ************STOP RUN************
-TYPE
-TYPE
-TYPE
-TYPE
-CLEANUP
VMS IF F$SEARCH("(FOCEXEC name)H%.FTM") .NES. "" THEN DEL (FOCEXEC name)H%.FTM;*
VMS IF F$SEARCH("(FOCEXEC name)H%.MAS") .NES. "" THEN DEL (FOCEXEC name)H%.MAS;*
VMS IF F$SEARCH("(FOCEXEC name)I%.FTM") .NES. "" THEN DEL (FOCEXEC name)I%.FTM;*
VMS IF F$SEARCH("(FOCEXEC name)I%.MAS") .NES. "" THEN DEL (FOCEXEC name)I%.MAS;*
-EXIT
This page hosted by 
Get your own Free Homepage