Clock Paradox and Accelerated Motion in Special Relativity

by Vladimir L. Kalashnikov

[email protected]

Abstract: The pedagogical analysis of the accelerated motion and clock paradox in framework of the special relativity is presented. Following for A. A. Logunov's statements we caution against an incorrect and too broad interpretation of the equivalence principle for accelerated motion.

Usually, the sense of the theory of special relativity is reduced to the description of the uniform motion and corresponding Lorentzian transformations. The pure geometrical interpretation of theory is attributed to the general relativity with its assumption concerning general coordinates transformations. This is not correct opinion. Both theories are the theories of a space-time and admit the arbitrary permissible coordinate transformations. In a sense, the "general relativity" is not good name for the theory whose main meaning is the interpretation of the gravitation as a curvature of the space-time. The difference between considered theories concerns the space-time structure: the flat pseudo-Euclidian (topologically simple) manifold of special relativity and the curved Riemannian (topologically nontrivial) manifold of general relativity. The gravitation is the curvature and, as result of its tensor nature, we can not "turn off" it in some finite region by means of any coordinate transformations. Therefore the equivalence principle has only local and heuristic meaning: the observer always can distinguish the gravitation from the acceleration. It should be emphasized, that the acceleration is not allied to curvature of space-time and, as result, it can be described in framework of special relativity.

Here we will consider a simple example of the uniformly accelerated motion. Suggested references are J. L. Synge, Relativity: the general theory, Amsterdam (1960) , L.D. Landau, E.M. Lifshitz, The classical theory of fields, Pergamon Press, Oxford (1962) . Our consideration is ruled by A. A. Logunov's statements ( Lectures on relativity and gravitation: modern analysis of problem, Moscow, Nauka (1987) (in Russian)).

> restart:
with(tensor):
with(difforms):

Let us start with the relativistic low of motion:

> Diff(v/sqrt(1-v^2/c^2),t) = w;

Here v and w are the velocity and acceleration relatively rest observer, respectively. The solution of this equation taking into account the initial velocity v0 is

> e1 := int(lhs(%),t) = int(rhs(%),t) + v0;

The elementary transformations result in

> e2 := simplify( (lhs(e1)/c)^2 + 1 ) = (rhs(e1)/c)^2 + 1;

Hence we have for the moving co-ordinates:

> Diff(x(t),t) = rhs(e1)/sqrt(rhs(e2));

In the vector form:

> eq := diff(r(t),t) = (w*t+v0)/sqrt(1+(w_s^2*t^2+2*w_v0*t+v0_s^2)/c^2);#this is vector form of the previous expression, w_v0 is the scalar product of vectors w and v0, w_s and v_s are their lengths

By solving we can obtain the following expression:

> dsolve(%,r(t));#result

or r(t) = w [ - 1] + ( v0 - w ( v0 w )/ ) + _C , where is the length of vector w , _C is the constant of integration.

One can find the expression for proper time of moving observer:

> d(tau) = d(t)*sqrt(1-v^2/c^2); #this is definition of proper time
# or
d(tau) = d(t)*1/sqrt(rhs(e2));

In the vector form the right-hand side of this expression can be rewritten as

> 1/(sqrt((w_s^2*t^2+2*w_v0+v0_s^2)/(c^2)+1));

Then the proper time is

> tau = int(%,t) + _C;

or t = + _C .

Now we can write the expressions of transition from inertial coordinates ( T , X , Y , Z ) to uniformly accelerated ones ( t , x , y , z ). Let's the accelerated system moves along X -axis, the directions of axes are equal, v0 = 0 and X = x = Y = y = Z = z = 0 at t = 0.

> defform(f=0,c=const,w=const,X=0,T=0,x=0,t=0):
X - c^2*(sqrt(1+w^2*T^2/c^2)-1)/w;# low of motion of point of origin of accelerated coordinates
d(x) = d( % );# motion with r=x, x0=0, v0=0, and t=T (time of rest system)

> subs({T=t,d(T)=d(t)},%);# transition to time t

> s1 := solve(%,d(X));# space differential in rest (inertial) system through accelerated coordinates

Hence we have the expression for the interval describing space-time properties of accelerated coordinates. If in the inertial system d(s)²=d(T)²-d(X)²-d(Y)² -d(Z)², then a new interval is:

> expand(s1^2):
d(s)^2 = c^2*d(t)^2 - % - d(y)^2 - d(z)^2:
collect(%,{d(x),d(x)^2,d(t)^2,d(y)^2,d(z)^2});# result

or d(s)² = . This metric is not form-invariant to the initial (inertial) Galilean metric that results in the difference between physical processes in the accelerated and inertial coordinates. The metric tensor in our case is:

> coord := [t, x, y, z]:# accelerated coordinates
g_compts := array(symmetric,sparse,1..4,1..4):# metric components
g_compts[1,1] := 1/(1+w^2*t^2/(c^2)):# component of interval attached to d(t)^2
g_compts[1,2] := -w*t/c/sqrt(1+w^2*t^2/(c^2)):# component of interval attached to d(x)*d(t)
g_compts[2,2] := -1:# component of interval attached to d(x)^2
g_compts[3,3] := -1:# component of interval attached to d(y)^2
g_compts[4,4] := -1:# component of interval attached to d(z)^2

g1 := create([-1,-1], eval(g_compts));# covariant metric tensor
g1_inv := invert( g1, 'detg' ):# contravariant metric tensor

The nonzero Christoffel symbols G_j,k ⁱ for this metric is

> D1g := d1metric( g1, coord ):
Cf1_1 := Christoffel1 ( D1g ):
Cf2_1 := Christoffel2( g1_inv, Cf1_1 ):
displayGR(Christoffel2,%);

It should be noted, that the correct dimensional expression is G_0,0¹ = because of inserts 1/c as x⁰ = ct . We can see the geometrical sense of the relativity of the acceleration: the acceleration connects with the Christoffel symbols ( = = , i =1,2,3, uⁱ is the spatial part of 4-velocity), but the Christoffel symbols obey the inhomogeneous transformational low and, as result, the acceleration is relative, i. e. it can be "turned off" by coordinate transformation. It should be noted, that our system does not concern any gravitational processes because of the space-time is obviously flat:

> D2g := d2metric( D1g, coord ):
RMN := Riemann( g1_inv, D2g, Cf1_1 ):
displayGR(Riemann,%);

This demands to restrict the meaning of the equivalence principle to the heuristic device (see first part in our Introduction to relativistic astrophysics and cosmology through Maple).

Now let 's choose as the time coordinate the proper time of accelerated system and make some transformations:

> # we choose the time of accelerated system:
c*ln(w*T/c+sqrt(1+w^2*T^2/c^2))/w = c*arcsinh(w*T/c)/w;# identity
t = c*arcsinh(w*T/c)/w;

> sinh(w*t/c) = sinh( arcsinh(w*T/c) );# sinh of previous expression
d( lhs(%) ) = d( rhs(%) );
s2 := solve(%%,T);# this is T
s3 := solve(%%,d(T));# this is d(T)

> # expression of d(X) through accelerated coordinates
X-c^2*(sqrt(1+w^2*T^2/(c^2))-1)/w;# low of motion of point of origin of accelerated coordinates
d(x) = d( subs(T=s2,%) );
s4 := solve(%,d(X));# this is d(X)

Thus the interval in the accelerated coordinates is:

> d(s)^2 = c^2*s3^2 - s4^2 - d(y)^2 - d(z)^2:
simplify(%,trig,radical):
collect(%,{d(t)^2,d(x)^2,d(x),d(y)^2,d(z)^2});# result

or d(s)² = :

> coord := [t, x, y, z]:# accelerated coordinates
g_compts := array(symmetric,sparse,1..4,1..4):# metric components
g_compts[1,1] := 1:# component of interval attached to d(t)^2
g_compts[1,2] := -sinh(w*t/c):# component of interval attached to d(x)*d(t)
g_compts[2,2] := -1:# component of interval attached to d(x)^2
g_compts[3,3] := -1:# component of interval attached to d(y)^2
g_compts[4,4] := -1:# component of interval attached to d(z)^2

g2 := create([-1,-1], eval(g_compts));# covariant metric tensor
g2_inv := invert( g2, 'detg' ):# contravariant metric tensor

The Christoffel symbols are

> D1g := d1metric( g2, coord ):
Cf1_2 := Christoffel1 ( D1g ):
Cf2_2 := Christoffel2( g2_inv, Cf1_2 ):
displayGR(Christoffel2,%);

in obviously flat space-time:

> D2g := d2metric( D1g, coord ):
RMN := Riemann( g2_inv, D2g, Cf1_2 ):
displayGR(Riemann,%);

The obtained expressions are sufficient for the consideration of the so-called "clock paradox". As it is know, this paradox concerns the difference between clock reading of rest ( T ) and moving ( t ) observers due to the moving induced time slowing-down in special relativity: T = . But the inertial motion is relative and we can not decide whose clock "lags". Such decision will result from the comparison of clocks after the return home of "traveler". But such return breaks the inertial character of motion. There is an opinion, that the accelerations demand to use the general relativity for the description of this situation. It is not correct. Let's T₁ , t₁ and T₂ , t₂ are the durations of accelerated (acceleration and deceleration of traveler) and inertial sections of motion, respectively. The way there and back takes T = 4 T₁ + 2 T₂ and t = 4 t₁ + 2 t₂ in rest (always inertial) and moving (traveler's) coordinates, respectively. Let's consider the travel from the point of view of inertial (first) observer. From the definition of the proper time t (see above, we have to replace t and t by t and T , respectively), we have for second observer (traveler):

> # 1) acceleration
t_1 := c*ln(w*T_1/c+sqrt(1+w^2*T_1^2/(c^2)))/w;

> # 2) inertial motion
V := w*T_1/sqrt(1+w^2*T_1^2/c^2):# velocity of inertial motion
t_2 := simplify( T_2*sqrt(1-V^2/c^2) );

> # taking into account the reverse motion:
t_proper := 4*t_1 + 2*t_2;

> # the time's difference between clocks of second and first observers is
t_diff := t_proper - 4*T_1 - 2*T_2;

This is a negative value:

> plot3d(subs({c=1,T_1=10*T_2},t_diff),w=0..1,T_2=0..10,axes=boxed, title=`time difference`);

that means the time lag of the moving clock.

Now let's consider this situation from the point of view of traveler. His clock rests in the origin of coordinates. But the first clock moves in the space-time with metric g1 by geodesic line. Then the low of motion obeys the following equations:

> geodesic_eqns( coord, s, Cf2_1 );

So . Here the additional c in denominator results from x⁰ = ct and u is the 4-velocity. As u^x = and = , we have:

> diff(u(t),t) + w/(1+w^2*t^2/c^2)^(3/2) = 0;
dsolve({%,u(0)=0},u(t)):
simplify(%,radical,symbolic);# velocity of motion (in negative direction of x!)

> diff(x(t),t) = -w*t/sqrt(1+w^2*t^2/c^2);
dsolve({%,x(0)=0},x(t)):
sol := simplify(%);

Now let's find the proper time of first (inertial) observer from the metric: dt = = dt . Hence

> d(t)*sqrt(get_compts(g1)[1,1] + 2*get_compts(g1)[1,2]*diff(rhs(sol),t)/c - diff(rhs(sol),t)^2/c^2):
d(tau) = simplify(%);

So t₁ = t₁ . The proper time of second clock, which is in rest relatively accelerated system, is dT₁ = dt .

> t_1 := 't_1':
Int(sqrt(get_compts(g1)[1,1]),t=0..t_1);
value(%):
simplify(%,radical,symbolic);

That is . After acceleration we have the section of inertial motion with v= (low of motion is x = v t ). But here we have some problem: we can not use the Lorenzian transformations because of they correspond to the Galilean (diagonal) metric and the transformation of g1 into such metric is discontinuous. Let's introduce the nondiagonal metric d(s)² = :

> coord := [t, x, y, z]:
g_compts := array(symmetric,sparse,1..4,1..4):# metric components
g_compts[1,1] := 1-v^2/c^2:# component of interval attached to d(t)^2
g_compts[1,2] := -v/c:# component of interval attached to d(x)*d(t)
g_compts[2,2] := -1:# component of interval attached to d(x)^2
g_compts[3,3] := -1:# component of interval attached to d(y)^2
g_compts[4,4] := -1:# component of interval attached to d(z)^2

g3 := create([-1,-1], eval(g_compts));# covariant metric tensor
g3_inv := invert( g3, 'detg' ):# contravariant metric tensor

This metric is obviously inertial:

> D1g := d1metric( g3, coord ):
Cf1_3 := Christoffel1 ( D1g ):
Cf2_3 := Christoffel2( g3_inv, Cf1_3 ):
displayGR(Christoffel2,%);

and continuously is transformed into g1 , when t = t₁. In this metric the geodesic motion of first clock gives the low of motion:

> geodesic_eqns( coord, s, Cf2_3 );

and

> d(t)*sqrt(get_compts(g3)[1,1] + 2*get_compts(g3)[1,2]*(-v)/c - (-v)^2/c^2):# D(x)(0)=-v
d(tau) = simplify(%);

So t₂ =t₂ . The proper time of second clock is dT₂ = dt :

> t_2 := 't_2':
Int(sqrt(get_compts(g3)[1,1]),t=0..t_2);
value(%):
simplify(subs(v=w*t_1/sqrt(1+w^2*t_1^2/c^2),%),radical,symbolic);

As result, the difference between second and first clocks is:

> t_diff := 4*c/w*ln(w*t_1/c+sqrt(1+w^2*t_1^2/(c^2))) + 2*t_2/(sqrt(1+w^2*t_1^2/c^2)) - 4*t_1 - 2*t_2;

This expression is equal to above obtained one. Hence the time difference is an invariant and there is no any paradox . In order to emphasize this fact, let's consider the limit t₁ --> 0, w --> so that v is the finite value (instant accelerations).

> v^2 = x/(1+x/c^2);# x=w^2*t_1^2
sol := solve(%,x);
4*c*ln(sqrt(sol)/c+sqrt(1+sol/(c^2)))/w+2*t_2/(sqrt(1+sol/(c^2)))-2*t_2:#time difference
simplify(%,radical,symbolic):
expand(%):
limit(%,w=infinity);

That is 2 t₂( - 1). This expression corresponds to one, which can be obtained from the special relativity in the case of inertially moving clocks. But in our case the observers are not equal and the obtained expression is the invariant!

So, we consider a pure geometrical interpretation of the acceleration as the non-zero Christoffel symbols in a flat pseudo-Euclidian space-time. This allows the description of the accelerated motion in framework of special relativity. We didn't restrict oneself to Galilean (diagonal) metric and gave the invariant description of the so-called "clock paradox".

2001�Kalashnikov