Introduction to relativistic astrophysics and cosmology through Maple

Vladimir L. Kalashnikov ,

Belarussian Polytechnical Academy,

[email protected]

www.geocities.com/optomaplev

Abstract: The basics of the relativistic astrophysics including the celestial mechanics in weak field, black holes and cosmological models are illustrated and analyzed by means of Maple 6

Application Areas/Subjects: Science, Astrophysics, General Relativity, Tensor Analysis, Differential geometry, Differential equations

Relativistic stars and black holes

Schwarzschild black hole

Now we return to Schwarzschild metric.

> get_compts(sch);

One can see two singularities: r =2 M and r =0. What is a sense of first singularity? When we cross the horizon, and (i.e. and ) change signs. The space and time exchange the roles! The fall gets inevitable as the time flowing. As consequence, when particle or signal cross the gravitational radius, they cannot escape the falling on r =0. This fact can be illustrated by infinite value of acceleration on r= 2 M , which is - ( G are the Christoffel symbols):

> D1sch := d1metric( sch, coord ):
Cf1 := Christoffel1 ( D1sch ):
displayGR(Christoffel1,%);

> -get_compts(Cf1)[1,1,2]/get_compts(sch)[1,1];#radial component of acceleration

Such particles and signals will be expelled from the cause-effect chain of universe. Therefore an imaginary surface r = is named " event horizon ".

The absence of true physical singularity for r = can be illustrated in the following way. The invariant of Riemann tensor is

> schinv := invert( sch, 'detg' ):
D2sch := d2metric( D1sch, coord ):
Cf1 := Christoffel1 ( D1sch ):
RMN := Riemann( schinv, D2sch, Cf1 ):
raise(schinv,RMN,1):#raise of indexes in Riemann tensor
raise(schinv,%,2):
raise(schinv,%,3):
RMNinv := raise(schinv,%,4):
prod(RMN,RMNinv,[1,1],[2,2],[3,3],[4,4]);

and has no singularity on horizon. This is only coordinate singularity and its sense is the lack of rigid coordinates inside horizon. True physical singularity is r =0 and has the character of the so-called space-like singularity (the inavitable singularity for the observer crossing horizon).

Now try to embed the instant equator section of curved space into flat space (see above):

> z(r)[1] = int(sqrt(2*r*M-4*M^2)/(-r+2*M),r);
z(r)[2] = int(-sqrt(2*r*M-4*M^2)/(-r+2*M),r);

> plot3d({subs({M=1,r=sqrt(x^2+y^2)},rhs(%%)),subs({M=1,r=sqrt(x^2+y^2)},rhs(%))},x=-10..10,y=-10..10,axes=boxed,style=PATCHCONTOUR,grid=[100,100],title=`Schwarzschild black hole`);

This is the black hole, which looks as a neck of battle (Einstein-Rosen bridge): the inside way to horizon and the outside way to horizon are the ways between different but identically asymptotically flat universes ("wormhole" through 2-dimensional sphere with minimal radius 2 M ). But since the static geometry is not valid upon horizon (note, that here t-->t+dt is not time translation), this scheme is not stable.

Let's try to exclude the above-mentioned coordinate singularity on the horizon by means of coordinate change. For example, we consider the null geodesics ( =0) in Schwarzschild space-time corresponding to radial motion of photons: = . Hence (see above considered expression for ):

> t = combine( int(-1/(1-R[g]/r),r) );

Then if v is the constant, which defines the radial coordinate for fixed t , we have

> t = -r - R[g]*ln( abs(-r/R[g]+1) ) + v;#module allows to extend the expression for r<R[g]

Differentiation of this equation with subsequent substitution of in expression for interval in Schwarzschild metric produce

> defform(f=0,w1=1,w2=1,w3=1,v=1,R[g]=0,r=0,v=0);
d(t)^2 = expand( subs( d(R[g])=0,d( -r-R[g]*ln( r/R[g]-1 )+v ) )^2 );# differentials in new coordinates
subs( d(t)^2=rhs(%),sch_compts[1,1]*d(t)^2 ) + sch_compts[2,2]*d(r)^2 + sch_compts[3,3]*d(theta)^2 + sch_compts[4,4]*d(phi)^2:
collect( simplify( subs(R[g]=2*M,%) ),{d(r)^2,d(v)^2});#new metric

So, we have a new linear element (in the so-called Eddington-Finkelstein coordinates ) = - ( ) + 2 dvdr + ( is the spherical part). The corresponding metric has the regular character in all region of r (except for r =0). It should be noted, that the regularization was made by transition to "light coordinate" v therefore such coordinates can not be realized physically, but formally we continued analytically the coordinates to all r >0. We can see, that for future directed (i.e. >0) null ( =0) or time like ( <0) worldlines dr <0 for r < that corresponds to above-mentioned conclusion about inevitable fall on singularity.

In the conclusion, we consider the problem of the deviation from spherical symmetry for static black hole. Such deviation can be described by the characteristic of quadrupole momentum q . Erez and Rosen found the corresponding static metric with axial symmetry:

> coord := [t, lambda, mu, phi]:
er_compts := array(symmetric,sparse,1..4,1..4):# metric components
er_compts[1,1] := -exp(2*psi):# coefficient of d(t)^2 in interval
er_compts[2,2] := M^2*exp(2*gamma-2*psi)*(lambda^2-mu^2)/(lambda^2-1):# coefficient of d(lambda)^2 in interval
er_compts[3,3] := M^2*exp(2*gamma-2*psi)*(lambda^2-mu^2)/(1-mu^2):# coefficient of d(mu)^2 in interval
er_compts[4,4] := M^2*exp(-2*psi)*(lambda^2-1)*(1-mu^2):# coefficient of d(phi)^2 in interval
er := create([-1,-1], eval(er_compts));# axially symmetric metric

where

> f1 := psi = 1/2*( (1+q*(3*lambda^2-1)*(3*mu^2-1)/4)*ln((lambda-1)/(lambda+1))+3/2*q*lambda*(3*mu^2-1) );
f2 := gamma = 1/2*(1+q+q^2)*ln((lambda^2-1)/(lambda^2-mu^2))-3/2*q*(1-mu^2)*(lambda*ln((lambda-1)/(lambda+1))+2)+9/4*q^2*(1-mu^2)*( (lambda^2+mu^2-1-9*lambda^2*mu^2)*(lambda^2-1)/16*ln((lambda-1)/(lambda+1))^2+(lambda^2+7*mu^2-5/3-9*mu^2*lambda^2)*lambda*ln((lambda-1)/(lambda+1))/4+1/4*lambda^2*(1-9*mu^2)+(mu^2-1/3) );
f3 := lambda = r/M-1;
f4 := mu = cos(theta);

In the case q =0 we have

> get_compts(er):
map2(subs,{psi=rhs(f1),gamma=rhs(f2)},%):
map2(subs,q=0,%):
map2(subs,{lambda=rhs(f3),mu=rhs(f4)},%):
map(simplify,%);

That is the Schwarzschild metric with regard to f3 and f4 .

Now let's find the horizon in the general case of nonzero quadrupole momentum. For static field ( =0) the corresponding condition is =0. Then

> map2(subs,psi=rhs(f1),er):
er2 := map2(subs,gamma=rhs(f2),%):
get_compts(er2)[1,1];

That is r =2 M ( l =1). But the result for invariant of curvature is:

> erinv := invert( er2, 'detg' ):
D1er := d1metric( er2, coord ):
D2er := d2metric( D1er, coord ):
Cf1 := Christoffel1 ( D1er ):
RMN := Riemann( erinv, D2er, Cf1 ):
raise(erinv,RMN,1):#raise of indexes in Riemann tensor
raise(erinv,%,2):
raise(erinv,%,3):
RMNinv := raise(erinv,%,4):
prod(RMN,RMNinv,[1,1],[2,2],[3,3],[4,4]):
get_compts(%):
series(%,q=0,2):#expansion on q
convert(%,polynom):
res := simplify(%):

In the spherical case the result corresponds to above obtained:

> factor( subs(q=0,res) ):#spherical symmetry
subs(lambda=1,%);# this is 48*M^2/r^6

There is no singularity. But for nonzero q (let's choose m =0 for sake of simplification):

> subs(mu=0,res):
#L'Hospital's rule for calculation of limit
limit(diff(numer(%),lambda),lambda=1);
limit(diff(denom(%),lambda),lambda=1);

Hence, there is a true singularity on horizon that can be regarded as the demonstration of the impossibility of static axially symmetric black hole with nonzero quadrupole momentum. Such momentum will be "taken away" by the gravitational waves in the process of the black hole formation.

Reissner-Nordstrom black hole (charged black hole)

The generalization of Schwarzschild metric on the case of spherically symmetric vacuum solution of bounded Einstein-Maxwell equations results in

> coord := [t, r, theta, phi]:
rn_compts := array(symmetric,sparse,1..4,1..4):# metric components
rn_compts[1,1] := -(1-2*M/r+Q^2/r^2):# coefficient of d(t)^2 in interval
rn_compts[2,2] := 1/(1-2*M/r+Q^2/r^2):# coefficient of d(r)^2 in interval
rn_compts[3,3]:=g_matrix[3,3]:# coefficient of d(theta)^2 in interval
rn_compts[4,4]:=g_matrix[4,4]:# coefficient of d(phi)^2 in interval
rn := create([-1,-1], eval(rn_compts));# Reissner-Nordstrom (RN) metric

Here Q is the electric charge. The metric has three singularities: r =0 and

> denom(get_compts(rn)[2,2]) = 0;
r_p := solve(%, r)[1];
r_n := solve(%%, r)[2];

Let's calculate the invariant of curvature:

> rninv := invert( rn, 'detg' ):
D1rn := d1metric( rn, coord ):
D2rn := d2metric( D1rn, coord ):
Cf1 := Christoffel1 ( D1rn ):
RMN := Riemann( rninv, D2rn, Cf1 ):
raise(rninv,RMN,1):#raise of indexes in Riemann tensor
raise(rninv,%,2):
raise(rninv,%,3):
RMNinv := raise(rninv,%,4):
prod(RMN,RMNinv,[1,1],[2,2],[3,3],[4,4]);

> solve(get_compts(%),r);#nonphysical roots for numerator with nonzero Q

That is the situation like to one in Schwarzschild metric and two last singularities have a coordinate character. Now let us plot the signs of two first terms in linear element (we plot inverse value for second term in order to escape the divergence due to coordinate singularities).

> plot({subs({M=1,Q=1/2},get_compts(rn)[1,1]),\
subs({M=1,Q=1/2},1/get_compts(rn)[2,2])},\
r=0.1..2, title=`signs of first and second terms of linear element`);

One can see the radical difference from the Schwarzschild black hole. The space and time terms exchange the roles in region r_n < r < r_p (between so-called inner and outer horizons with =0). But there are the usual signs in the vicinity of physical singularity, i. e. it has a time-like character and the falling observer can avoid this singularity.

Next difference is the lack of coordinate singularities for < . In this case we have the so-called naked singularity. One can demonstrate that there is no such singularity as result of usual collapse of charged shell with mass M and charge Q . The total energy (in Newtonian limit but with correction in framework of special relativity, M_0 is the rest mass) is

> en := M(r) = M_0 + Q^2/r - M(r)^2/r;#we use the geometric units of charge so that the Coulomb low is G*Q_1*Q_2/r^2
sol := solve(en,M(r));

The choice of the solution is defined by the correct asymptotic = M_0 :

> if limit(sol[1],r=infinity)=M_0 then true_sol := sol[1] fi:
if limit(sol[2],r=infinity)=M_0 then true_sol := sol[2] fi:
true_sol;

> diff(true_sol,r):
subs(M_0=solve(en,M_0),%):
simplify(%,radical,symbolic);

So, = . The collapse is possible if M decreases with decreasing R (domination of gravity over the Coulomb interaction in the process of collapse) that is possible, when > . It should be noted, that the limit

> limit(true_sol,r=0);

resolves the problem of the infinite proper energy of charged particle.

Now we will consider the pressure free collapse of charged sphere of dust by analogy with Schwarzschild metric.

> r := 'r':
E := 'E':
subs( r=r(t),get_compts(rn) ):
d(s)^2 = %[1,1]*d(t)^2 + %[2,2]*d(r)^2;#RN metric
-d(tau)^2 = collect(subs( d(r)=diff(r(t),t)*d(t),rhs(%) ),d(t));#tau is the proper time for the observer on the surface of sphere
%/d(tau)^2;
subs({d(t)=E/(1-2*M/r(t)+Q^2/r^2),d(tau)=1},%);#we used d(t)/d(tau)=E/(1-2*M/r+Q^2/r^2)
pot_1 := factor( solve(%,(diff(r(t),t))^2) ):#"potential" for remote observer
pot_2 := simplify(pot_1*(E/(1-2*M/r(t)+Q^2/r^2))^2):#"potential for collapsing observer" d/d(t)=(d/d(tau))*(1-2*M/r+Q^2/r^2)/E

> plot({subs({E=0.5,M=1,Q=1/2,r(t)=r},pot_2),0*r},r=0.11..3,axes=boxed,title=`(dr/dtau)^2 vs r for collapsing observer`);

The difference from Schwarzschild collapse is obvious: the observer crosses the outer and inner horizons but does not reach the singularity because of the collapsar explodes as white hole due to repulsion with consequent recollapse and so on.

And at last, we consider the "extreme" case = .

> subs(Q^2=M^2, get_compts(rn));
factor(%[1,1]);

So, we have one coordinate singularity in r = M . What happen with second horizon? Let's find the distance between horizons for fixed t and angular coordinates for RN-metric:

> get_compts(rn):
d(s)^2 = %[2,2]*d(r)^2;#RN metric
# or
d(s)^2 = d(r)^2/expand( (1-r_p/r)*(1-r_n/r) );#second representation of expression

Hence, when r_p-->r_n ( --> 0)

> r_p := 'r_p':
r_n := 'r_n':
s = Int(1/sqrt((1-r_p/r)*(1-r_n/r)),r=r_n..r_p) ;
simplify( value(rhs(%)),radical,symbolic );

we have s--> . So, there is the infinitely long Einstein-Rosen bridge (charged string) between horizons that means a lack of wormhole between asymptotically flat universes. This fact can be illustrated by means of embedding of equatorial section of static RN space in flat Euclidian space (see above).

> d(r)^2/(1-1/r)^2 = (1+diff(z(r),r)^2)*d(r)^2;#equality of radial elements of intervals, M=1
diff(z(r),r) = solve(%,diff(z(r),r))[1];
dsolve(%,z(r));# embedding

> plot3d(subs(r=sqrt(x^2+y^2),2*sqrt(2*r-1)+ln(sqrt(2*r-1)-1)-ln(sqrt(2*r-1)+1)),x=-10..10,y=-10..10,axes=boxed,style=PATCHCONTOUR,grid=[100,100],title=`extreme RN black hole`);#we expressed arctanh through ln

The asymptotic behavior of RN-metric as r--> is Minkowski. For investigation of the situation r-->M let introduce the new coordinate (see, for example, P.K. Townsend, "Black Holes", arXiv: gr-gc/9707012):

> rn_assym := subs( {r=M*(1+lambda),Q^2=M^2},get_compts(rn) );

> m1 := series(rn_assym[1,1],lambda=0,3);# we keep only leading term in lambda
m2 := series(rn_assym[2,2],lambda=0,3);# we keep only leading term in lambda
d(s)^2 = convert(m1,polynom)*d(t)^2 +M^2*convert(m2,polynom)*d(lambda)^2 + M^2*d(Omega)^2;#d(Omega) is spherical part

This is the Robinson-Bertotti metric . The last term describes two-dimensional sphere with radius M (these dimensions are compactified in the vicinity of horizon) and the first terms corresponds to anti-de Sitter space-time (see below) with constant negative curvature.

Kerr black hole (rotating black hole)

In the general form the stationary rotating black hole is described by so-called Kerr-Newman metric, which in the Boyer-Linquist coordinates can be presented as:

> coord := [t, r, theta, phi]:
kn_compts :=
array(sparse,1..4,1..4):# metric components, a=J/M, J is the angular momentum

kn_compts[1,1] :=
-(Delta-a^2*sin(theta)^2)/Sigma:# coefficient of d(t)^2

kn_compts[1,4] :=
-2*a*sin(theta)^2*(r^2+a^2-Delta)/Sigma:# coefficient of d(t)*dphi

kn_compts[2,2] :=
Sigma/Delta:# coefficient of d(r)^2

kn_compts[3,3] :=
Sigma:# coefficient of d(theta)^2

kn_compts[4,4] :=
(((r^2+a^2)^2-Delta*a^2*sin(theta)^2)/Sigma)*sin(theta)^2:# coefficient of d(phi)^2

kn := create([-1,-1], eval(kn_compts));# Kerr-Newman (KN) metric

#where

sub_1 := Sigma = r^2+a^2*cos(theta)^2;
sub_2 := Delta = r^2-2*M*r+a^2+sqrt(Q^2+P^2);# P is the magnetic (monopole) charge

In the absence of charges, this results in Kerr metric. The obvious singularities are (except for an usual singularity of spherical coordinates q =0):

> r_p := solve( subs({Q=0,P=0},rhs(sub_2))=0,r )[1];#outer horizon
r_n := solve( subs({Q=0,P=0},rhs(sub_2))=0,r )[2];#inner horizon
solve( subs({Q=0,P=0},rhs(sub_1))=0,theta );

The last produces r =0, q = .

As it was in the case of charged static black hole, there are three different situations: < , = , > .

Let consider the signs of , , ( > ).

> plot3d(subs({M=1,a=1/2,P=0,Q=0},subs({Sigma=rhs(sub_1),Delta=rhs(sub_2)},get_compts(kn)[1,1])),\
r=0.1..4,theta=0..Pi,color=red):

plot3d(subs({M=1,a=1/2,P=0,Q=0,theta=2*Pi/3},subs({Sigma=rhs(sub_1),Delta=rhs(sub_2)},1/get_compts(kn)[2,2])),\
r=0.1..4,theta=0..Pi,color=green):

display(%,%%,title=`signs of first and second diagonal elements of metric`,axes=boxed);

plot3d(subs({M=1,a=1/2,P=0,Q=0},subs({Sigma=rhs(sub_1),Delta=rhs(sub_2)},get_compts(kn)[4,4])),\
r=-0.01..0.01,theta=Pi/2-0.01..Pi/2+0.01,color=blue,title=`four diagonal element of metric in vicinity of singularity`,axes=boxed);

One can see, that the approach to r =0 in the line, which differs from q = , corresponds to usual signs of diagonal elements of metric, i.e. the observer crosses r =0 and comes into region r <0 without collision with singularity. But from the second picture we can see the change of the -sign for r <0. Now f is the time like coordinate. But this coordinate has circle character and, as consequence, we find oneself in the world with closed time lines. The approach to r =0 in the line of q = produces the change of -sign, i.e. we find a true singularity in this direction. These facts demonstrate that the singularity in Kerr black hole has a more complicated character than in above considered black holes.

The more careful consideration gives the following results:

1) < . There exists no horizon ( r_p and r_n are complex), but the singularity in r =0, q = keeps. To remove the coordinate singularity in q =0 we introduce the Kerr-Schild coordinates with linear element

> macro(ts=`t*`):
ks_le := d(s)^2 = -d(ts)^2 + d(x)^2 + d(y)^2 + d(z)^2 + (2*M*r^3/(r^4+a^2*z^2))*( (r*(x*d(x)+y*d(y))-a*(x*d(y)-y*d(x)))/(r^2+a^2)+z*d(z)/r+d(ts) )^2;
x + I*y = (r + I*a)*sin(theta)*exp(I*(Int(1,phi)+Int(a/Delta,r)));
z = r*cos(theta);
ts = Int(1,t) + Int((r^2+a^2/Delta),r) - r;

which is reduced to Minkowski metric by M--> 0.

> int(subs( {P=0,Q=0},subs(Delta=rhs(sub_2),a/Delta) ),r):
x+I*y=(r+I*a)*sin(theta)*exp(I*(phi+%));

When r =0, q = the singularity is the ring = , z = 0.

2) > . As before we have the ring singularity, but there are the horizons r_p and r_n . As a additional feature of Kerr metric we note here the existence of coordinate singularity:

> get_compts(kn)[1,1]=0;
subs( Delta=rhs( sub_2 ),numer( lhs(%) ) ):
solve( subs({Q=0,P=0},%) = 0,r );

The crossing of ellipsoid r _ 1 = produces the change of -sign. As it was for Schwarzschild black hole this fact demonstrates the lack of static coordinates under this surface, which is called "ergosphere " and the region between r_p and r_1 is the ergoregion. The absence of singularity for suggests that the nonstatic behavior results from entrainment of observer by black hole rotation, but not from fall on singularity, as it takes place for observer under horizon in Schwarzschild black hole.

Conclusion

So, the elementary analysis by means of basic Maple 6 functions allows to obtain the main results of black hole physics including conditions of collapsar formation, the space-time structure of static spherically symmetric charged and uncharged black holes and stationary axially symmetric black hole.