1 ' *** GADGET *** MINI-RTC ***
5 VAC:ONERRORGOTO4000:OPEN"COM0:4,E,7,1,N,N,N,N,N"AS#1
10 GOSUB100:LI=10000:GOSUB2000:GOSUB1000:GOSUB3000:GOSUB2000:IFW=0;END
20 BEEP:IFKEY=""THEN20
30 LI=10300:GOSUB2000:END
100 LI=10400:GOSUB2000:I=0:PRINT:PRINT"Attente de connexion";
110 I=I+1:PRINTCSR20;I;:PRINT#1,CHR$(30)STR$(I);:A$=KEY:IFA$=""THEN110
120 PRINT:PRINT"Connecte";:RETURN
999 END
1000 PRINT:PRINT"PSEUDO:";:PRINT#1,CHR$(31)CHR$(85)CHR$(68)"TON PSEUDO: ."CHR$(18)CHR$(79)" + "CHR$(27)CHR$(93)"ENVOI"CHR$(31)CHR$(85)CHR$(80)CHR$(17);
1010 A$=INPUT$(1,#1):A=ASC(A$)
1020 IFA=19;GOSUB1100:GOTO1040
1030 IFA>31ANDA<128;B$=B$+A$:PRINT#1,A$;:IFLEN(B$)=15;F=1
1040 IFF=0THEN1010
1050 PRINT#1,CHR$(13)CHR$(24)CHR$(20);:PRINTB$;:RETURN
1100 A$=INPUT$(1,#1):A=ASC(A$)
1110 IFA=71ANDB$<>"";B$=LEFT$(B$,LEN(B$)-1):PRINT#1,CHR$(8);".";CHR$(8);
1120 IFA=65;F=1
1130 RETURN
1999 END
2000 RESTORE LI
2010 A$="":READ$:A$=LEFT$($,1):IFA$="*";PRINT#1,MID$($,2);:GOTO2010
2015 IFA$="$";PRINT#1," "B$" ";:GOTO2010
2020 IFA$<>"";PRINT#1,CHR$(VAL("&H"+$));:GOTO2010
2030 RETURN
3000 RESTORE#
3010 READ#$:E$=LEFT$($,1):IFER=1;LI=10100:PRINT:PRINT"Non connu";:RETURN
3020 IFE$=""AND$=E$+B$THEN3030ELSE3010
3030 LI=10200:W=1:PRINT:PRINT"Certifie";:RETURN
4000 IFERL=3010ANDERR=22;ER=1:RESUMENEXT
4010 IFERR=31;CLS:PRINT"Interface non connectee..";:PRINT:INPUT"Pseudo:";B$:ES=1:RESUMENEXT
4020 CLS:PRINT"Error"ERR" ligne"ERL;:END
10000 DATA0C,1F,40,41,18,1F,44,49,1B,4F,*SERVEUR,1F,48,45,*Le serveur est indisponible pour le moment ! Tape tout de meme un pseudo afin que je puisse savoir        qui tu es.,1F,40,44,1B,5D,*Ce prg tourne sur CASIO FX-850P !,
10100 DATA1F,50,48,*A bientot,$,*...,1F,52,46,*Rappelle une autre fois au:,1F,55,45,1B,5C,1B,4D,*40-63-10-81 (de ,1B,48,*22h00,1B,49,* a ,1B,48,*7h00,1B,49,* ),1B,39,67,
10200 DATA1F,50,41,*Hehe,$,*alors ca va ?,1F,51,41,*Tu veux te connecter ? Je sais qu'on    te connait bien et il va te prendre en  vocal...Decroche ton combine et attends qu'il te reprenne en vocal !,1F,57,49,1B,5D,1B,48,*Je l'appelle ! ,1B,5C,1B,49,
10300 DATA1F,4E,4B,1B,5D,1B,48,1B,4F,*COUCOU !,1F,57,49,18,1B,39,67,
10400 DATA0C,1B,39,6F,1B,39,68,
