ACTOR OilDrum 16566
{
  Health 20
  Radius 10
  Height 34
  +SOLID
  +SHOOTABLE
  +NOBLOOD
  +ACTIVATEMCROSS
  +DONTGIB
  +NOICEDEATH
  +OLDRADIUSDMG
  DeathSound "world/barrelx"
  Obituary "$OB_BARREL"
  States
  {
  Spawn:
    OILD A 6
    Loop
  Death:
    OILD A 5 BRIGHT
    OILD A 5 BRIGHT A_Scream
    OILD B 5 BRIGHT
    OILD C 5 BRIGHT A_Explode
    OILC CCCCC 0 BRIGHT A_SpawnItemEx ("BarrelFlames", random (0, 40), random (0, 40), 0, 0, 0, 0, random (0, 360)) 
    OILD D 10 BRIGHT
    OILD D 1050 BRIGHT A_BarrelDestroy
    OILD D 5 A_Respawn
    Wait
  }
}

ACTOR BarrelFlames 16567
{
  Radius 16
  Height 24
  ReactionTime 75
  damagetype "fire"
  renderstyle Add
  Projectile
  +NODAMAGETHRUST
  +BLOODLESSIMPACT
  -NOGRAVITY
  -DROPOFF
  -MISSILE
  -ACTIVATEIMPACT
  -ACTIVATEPCROSS
  
  States
  {
  Spawn:
    OILS A 0 bright
    OILS A 4 bright A_PlaySoundEx ("BarrelFire/Loop", "SoundSlot5", 1)
    OILS A 0 bright A_PlaySoundEx ("BarrelFire/Start", "SoundSlot6")
    OILS BC 4 bright
  FireLoop:
    OILF AB 4 bright
    OILF C 4 bright A_Explode (5, 40)
    OILF C 0 bright A_CountDown
    Loop
  Death:
    OILS CB 4 bright
    OILS A 4 bright A_StopSoundEx ("SoundSlot5")
    Stop
  }
}

/////////////////////////////
// LAVA EMBER        ////////
// for UTNT          ////////
// by Tormentor667   ////////
/////////////////////////////

Actor BaseEmber
{
 +Missile
 +NoBlockmap
 +NoInteraction
 -Solid
 Radius 0
 Height 0
 RenderStyle Add
 Alpha 0.01
 Scale 0.06
 Gravity 0.25
 States
 {
  Spawn:
   EMBR AAAA 1 Bright A_FadeIn(0.25)
   TNT1 A 0 A_Jump(80,8)
   TNT1 A 0 A_Jump(80,6)
   TNT1 A 0 A_Jump(80,4)   
   TNT1 A 0 A_Jump(80,2)   
   EMBR AAAAA 8 Bright
   EMBR AAAAAAAAAAAAAAAAAAAA 1 Bright A_FadeOut(0.06)
   Stop
 }
}

actor EmberSpawner 240
{
//$Category SpecialEffects
	+NoBlockMap +NoGravity +NoSector +NoInteraction +NoClip -Solid +CLIENTSIDEONLY
        states
        {
        Spawn:
           Active:
        	TNT1 A 0
        	TNT1 A 0 A_JumpIf(Args[1], "Circle")
        	TNT1 A 2 A_SpawnItemEx ("BaseEmber", random(-Args[0], Args[0]), random(-Args[0], Args[0]), random(0, 8), (0.1)*Random(1, 3), 0, (0.1)*Random(1, 10), random(0,360), 129, Args[2]) 
        	Loop
           Circle:
        	TNT1 A 0
        	TNT1 A 2 A_SpawnItemEx ("BaseEmber", random(-Args[0], Args[0]), 0, random(0, 8), (0.1)*Random(1, 3), 0, (0.1)*Random(1, 10), Random(0, 360), 129, Args[2]) 
        	Loop
           Inactive:
		TNT1 A 1
		Loop
        }     
        
}

