#CLASS {Combat}
#ALIAS tg {#IF (%null(%1)) {#SHOW {"tg ~<type~>" eg: set target Vecna. This will setup the variable for backstabbing}} {#VAR CombatTarget {%1};#IF (@zmShow) {#EMOTEA {@zmcurtheme.1 targets@zmcurtheme.7 @CombatTarget}} {#SHOW {Target set as: @CombatTarget (type "tg" for help)}}}}
#ALIAS tg2 {#IF (%null(%1)) {#SHOW {"tg2 ~<type~>" eg: set target Ki~-rin. This will setup the variable for backstabbing}} {#VAR CombatTarget2 {%1};#IF (@zmShow) {#EMOTEA {@zmcurtheme.1 second targets@zmcurtheme.7 @CombatTarget2}} {#SHOW {Target2 set as: @CombatTarget2 (type "tg2" for help)}}}}
#ALIAS tgclear {#VAR CombatTarget {};#VAR CombatTarget2 {};#IF (@zmShow) {#EMOTEA {@zmcurtheme.1 clears his targets}} {#SHOW {Targets cleared}}}
#ALIAS combathelp {#SHOW {%char(10)%ansi(bold,yellow)Combat Version 1.24 by %ansi(bold,red)Kernighan%char(10)%ansi(bold,yellow)Many thanks to %ansi(bold,red)Daerte %ansi(bold,yellow)for his suggestions on ways to improve this script.}}
#VAR CombatTarget {} {}
#VAR CombatTarget2 {} {}
#GAG {~!~!SOUND}
#CLASS 0

#CLASS {Combat|KeyPad}
#KEY {ADD}       {bs @CombatTarget}
#KEY {SHIFT-ADD} {c shockwave @CombatTarget}
#KEY {SHIFT-CTRL-ADD} {c magic @CombatTarget}
#KEY {CTRL-ADD}  {c mal}
#KEY {ALT-ADD}   {mal @CombatTarget}
#KEY {SUB}       {bs @CombatTarget2}
#KEY {SHIFT-SUB} {c shockwave @CombatTarget2}
#KEY {SHIFT-CTRL-SUB} {c magic @CombatTarget2}
#KEY {CTRL-SUB}  {c mal}
#KEY {ALT-SUB}   {mal @CombatTarget2}
#CLASS 0

#CLASS {Combat|Malediction Me}
#ALIAS {AddMalMe} {zmProcsOn;zmenemyname=%1;usermalme=1}
#TRIGGER {(*) smiles triumphantly as the lethal bolt of magic dissolves you.} {AddMalMe "%1"}
#TRIGGER {(*) raises %w hands and strikes you with a burst of power.} {AddMalMe "%1"}
#CLASS 0

#CLASS {Combat|Malediction}
#ALIAS {AddMal} {zmProcsOn;zmtargetname=%1;usermal=1}
#TRIGGER {You focus and send a deadly blast of power at (*).} {AddMal "%1"}
#TRIGGER {Your supercharged bolt of pure magic shatters (*) into sparkling motes of dust.} {AddMal "%1"}
#CLASS 0

#CLASS {Combat|Spell Chat Message}
#ALIAS {spellchat} {#IF (%1 = "off") {#T- {Combat|Spell Messages};#T- {Combat|SpellMe Messages};#VAR spellChat {0};#IF (@zmShow) {#EMOTEA {@zmcurtheme.1 spellChat disabled}} {#SHOW {@zmcurtheme.1 spellChat disabled}}} {#T+ {Combat|Spell Messages};#T+ {Combat|SpellMe Messages};#VAR spellChat {1};#IF (@zmShow) {#EMOTEA {@zmcurtheme.1 spellChat enabled}} {#SHOW {@zmcurtheme.1 spellChat enabled}}}}
#ALIAS spellmechatrep {spellCreateDisplay;#IF (@spellChat) {#IF {@zmShow} {spellMeChatDisplay} {spellMeShowMeDisplay}}}
#ALIAS spellchatrep {spellCreateDisplay;#IF (@spellChat) {#IF {@zmShow} {spellChatDisplay} {spellShowMeDisplay}}}
#ALIAS spellMeShowMeDisplay {#SHOW @CombatSpellMessage@zmRoomInfo}
#ALIAS spellShowMeDisplay {#SHOW @zmcurtheme.6 You see@CombatSpellMessage@zmRoomInfo}
#ALIAS spellMeChatDisplay {#EMOTEALL @CombatSpellMessage@zmRoomInfo}
#ALIAS spellChatDisplay {#EMOTEALL @zmcurtheme.6 sees@CombatSpellMessage@zmRoomInfo}
#ALIAS spellCreateDisplay {zmCreateRoomInfo}
#VAR spellChat {0} {0}
#VAR CombatSpellMessage {""} {""}
#VAR usermal {0} {0}
#VAR usermalme {0} {0}
#ALIAS {ShowMalDisplay} {MalCreateDisplay;#IF {@zmshow} {ChatMalDisplay} {ShowMeMalDisplay};zmClearData}
#ALIAS {ShowEnemyMalDisplay} {MalCreateEnemyDisplay;#IF {@zmshow} {ChatMalEnemyDisplay} {ShowMeMalEnemyDisplay};zmClearData}
#ALIAS {MalCreateDisplay} {zmCreateFireshield;zmCreateTarget;zmCreateCondition;zmCreateHps;zmCreateRoomInfo}
#ALIAS {MalCreateEnemyDisplay} {zmCreateHps;zmMakeDamage;zmCreateRoomInfo}
#ALIAS {ChatMalDisplay} {#EMOTEALL @zmcurtheme.6 just@zmcurtheme.7 MALD@zmDTarget@zmcurtheme.6 to@zmDCondition@zmcurtheme.6%if(@zmFShield," it was "@zmDFire)@zmDHps@zmRoomInfo}
#ALIAS {ChatMalEnemyDisplay} {#EMOTEALL @zmcurtheme.2~:~: @zmcurtheme.1 @zmenemyname@zmcurtheme.6 just @zmcurtheme.7 MALD@zmcurtheme.6 me for @zmcurtheme.1@zmDamage@zmcurtheme.6 damage!%if(@zmmydeath,@zmcurtheme.1 @zmenemyname@zmcurtheme.6 has just@zmcurtheme.1 Obliterated@zmcurtheme.6 me!,@zmDhps)}
#ALIAS {ShowMeMalDisplay} {#SHOW @zmcurtheme.6 You just@zmcurtheme.7 MALD@zmDTarget@zmcurtheme.6 to@zmDCondition@zmcurtheme.6%if(@zmFShield(" it was "@zmDFire)@zmDHps@zmRoomInfo}
#ALIAS {ShowMeMalEnemyDisplay} {#SHOW @zmcurtheme.2~:~: @zmcurtheme.1 @zmenemyname@zmcurtheme.6 just @zmcurtheme.7 MALD@zmcurtheme.6 me for @zmcurtheme.1@zmDamage@zmcurtheme.6 damage!%if(@zmmydeath,@zmcurtheme.1 @zmenemyname@zmcurtheme.6 has just@zmcurtheme.1 Obliterated@zmcurtheme.6 me!,@zmDhps)} 
#CLASS 0

#CLASS {Combat|Spell Messages}
#TRIGGER {^(*) chokes and utters some muffled noises.$} {#var CombatSpellMessage {@zmcurtheme.1 %1@zmcurtheme.6 has been@zmcurtheme.7 PLAGUED};spellchatrep}
#TRIGGER {^Several illusionary duplicates of (*) appear around %2 body.} {#var CombatSpellMessage {@zmcurtheme.1 %1@zmcurtheme.1 has put@zmcurtheme.7 IMAGES UP};spellchatrep}
#TRIGGER {^Dense gray smoke wells up from (*)'s feet, enveloping %w.$} {#var CombatSpellMessage {@zmcurtheme.1 %1@zmcurtheme.6 has@zmcurtheme.7 TELEPORTED};spellchatrep}
#TRIGGER {^(*) briefly reveals a red aura!$} {#var CombatSpellMessage {@zmcurtheme.1 %1@zmcurtheme.6 has been@zmcurtheme.7 CURSED};spellchatrep}
#TRIGGER {^(*)'s illusionary duplicates vanish with a bright spark of energy.$} {#var CombatSpellMessage {@zmcurtheme.1 %1's@zmcurtheme.5 IMAGES@zmcurtheme.6 has been @zmcurtheme.7 DISPELLED};spellchatrep}
#TRIGGER {^The shield of fire around (*)'s body fizzles.$} {#var CombatSpellMessage {@zmcurtheme.1 %1's@zmcurtheme.5 FIRESHIELD@zmcurtheme.6 has been@zmcurtheme.7 DISPELLED};spellchatrep}
#TRIGGER {^(*)'s Mana Shield crackles, fizzles, and dies.$} {#var CombatSpellMessage {@zmcurtheme.1 %1's@zmcurtheme.5 MANA SHIELD@zmcurtheme.6 has been@zmcurtheme.7 DISPELLED};spellchatrep}
#TRIGGER {^(*) seems to be blinded!} {#var CombatSpellMessage {@zmcurtheme.1 %1@zmcurtheme.6 has been@zmcurtheme.7 BLINDED};spellchatrep}
#TRIGGER {^(*) turns %w eyes away and screams!$} {#var CombatSpellMessage {@zmcurtheme.1 %1@zmcurtheme.6 has been@zmcurtheme.7 BLINDED};spellchatrep}
#TRIGGER {^(*) winces as the poison enters %w body.$} {#var CombatSpellMessage {@zmcurtheme.1 %1@zmcurtheme.6 has been@zmcurtheme.7 POISONED};spellchatrep}
#TRIGGER {^(*) becomes very passive and starts following you.$} {#var CombatSpellMessage {@zmcurtheme.1 %1@zmcurtheme.6 has been@zmcurtheme.7 CHARMED@zmcurtheme.6 by my hot bod};spellchatrep}
#TRIGGER {^The white glow around (*)'s body fades.$} {#var CombatSpellMessage {@zmcurtheme.1 %1's@zmcurtheme.5 SANCTUARY@zmcurtheme.6 has been@zmcurtheme.7 DISPELLED};spellchatrep}
#TRIGGER {^(*) is surrounded by a pink outline.$} {#var CombatSpellMessage {@zmcurtheme.1 %1@zmcurtheme.6 has been@zmcurtheme.7 FAERIE FIRED};spellchatrep}
#TRIGGER {^A shimmering rift appears in the air before you and (*) steps out.$} {#var CombatSpellMessage {@zmcurtheme.1 %1@zmcurtheme.6 has@zmcurtheme.7 PHASED INTO@zmcurtheme.6 the room};spellchatrep}
#TRIGGER {^A shimmering rift appears in the air and (*) steps through, disappearing.} {#var CombatSpellMessage {@zmcurtheme.1 %1@zmcurtheme.6 has @zmcurtheme.7 PHASED OUT OF@zmcurtheme.6 the room};spellchatrep}
#TRIGGER {^You focus your concentration, and block an attempt to phase by (*).} {#var CombatSpellMessage {@zmcurtheme.1 I@zmcurtheme.6 just@zmcurtheme.7 BLOCKED@zmcurtheme.1 %1@zmcurttheme.6 from@zmcurtheme.5 PHASING};spellmechatrep}
#TRIGGER {%1 arrives suddenly.} {#Var CombatSpellMessage {@zmcurtheme.1 %1@zmcurtheme.6 has been@zmcurtheme.7 SUMMONED INTO@zmcurtheme.6 the room};spellchatrep}
#TRIGGER {%1 disappears suddenly.} {#Var CombatSpellMessage {@zmcurtheme.1 %1@zmcurtheme.6 has been@zmcurtheme.7 SUMMONED FROM@zmcurtheme.6 the room};spellchatrep}
#TRIGGER {^Your attack merely destroys one of (*)'s illusionary images.$} {#var CombatSpellMessage {@zmcurtheme.6 just @zmcurtheme.7 destroyed@zmcurtheme.6 one of @zmcurtheme.1 %1's@zmcurtheme.7 IMAGES};spellmechatrep}
#CLASS 0

#CLASS {Combat|SpellMe Messages}
#TRIGGER {^You have been blinded!$} {#var CombatSpellMessage {@zmcurtheme.1 I@zmcurtheme.6 have been@zmcurtheme.7 BLINDED};spellmechatrep}
#TRIGGER {^You feel very uncomfortable.$} {#var CombatSpellMessage {@zmcurtheme.1 I@zmcurtheme.6 have been@zmcurtheme.7 CURSED};spellmechatrep}
#TRIGGER {^Your Mana Shield cracks and pops out.$} {#var CombatSpellMessage {@zmcurtheme.1 My@zmcurtheme.5 MANA SHIELD@zmcurtheme.6 has been@zmcurtheme.7 DISPELLED};spellmechatrep}
#TRIGGER {^Your illusionary duplicates vanish with a bright spark of energy.$} {#var CombatSpellMessage {@zmcurtheme.1 My@zmcurtheme.5 IMAGES@zmcurtheme.6 have been@zmcurtheme.7 DISPELLED};spellmechatrep}
#TRIGGER {^Your phantasmal images flare and dissipate as the dragon's breath engulfs them.} {#VAR CombatSpellMessage {@zmcurtheme.1 My@zmcurthem.5 IMAGES@zmcurtheme.6 have been @zmcurtheme.7 DRAGON BREATHED};spellmechatrep}
#TRIGGER {^Your white aura flashes brightly and disappears.$} {#var CombatSpellMessage {@zmcurtheme.1 My@zmcurtheme.5 SANCTUARY@zmcurtheme.6 has been@zmcurtheme.7 DISPELLED};spellmechatrep}
#TRIGGER {^Your shield of fire collapses.$} {#var CombatSpellMessage {@zmcurtheme.1 My@zmcurtheme.5 FIRESHIELD@zmcurtheme.6 has been@zmcurtheme.7 DISPELLED};spellmechatrep}
#TRIGGER {^You choke and utter some muffled noises.$} {#var CombatSpellMessage {@zmcurtheme.1 I@zmcurtheme.6 have been@zmcurtheme.7 PLAGUED};spellmechatrep}
#TRIGGER {^You feel very sick.$} {#var CombatSpellMessage {@zmcurtheme.1 I@zmcurtheme.6 have been@zmcurtheme.7 POISONED};spellmechatrep}
#TRIGGER {^The bright burst of colors has blinded you!$} {#var CombatSpellMessage {@zmcurtheme.1 I@zmcurtheme.6 have been@zmcurtheme.7 BLINDED};spellmechatrep}
#TRIGGER {^(*)'s attack has destroyed one of your illusionary images.$} {#var CombatSpellMessage {@zmcurtheme.1 %1@zmcurtheme.6 just @zmcurtheme.5 destroyed@zmcurtheme.6 one of my @zmcurtheme.7 IMAGES};spellmechatrep}
#TRIGGER {^Your vision returns!} {#var CombatSpellMessage {@zmcurtheme.1 My@zmcurtheme.5 BLINDESS@zmcurtheme.6 has been@zmcurtheme.7 CURED};spellmechatrep}
#TRIGGER {^You feel as if an oppressive aura has been lifted from you.} {#var CombatSpellMessage {@zmcurtheme.1 My@zmcurtheme.5 CURSE@zmcurtheme.6 has been@zmcurtheme.7 LIFTED};spellmechatrep}
#TRIGGER {The white aura around your body fades} {#var CombatSpellMessage {@zmcurtheme.1 ..ooOO Sanc Out OOoo..};spellmechatrep}
#TRIGGER {A glowing white aura surrounds your body.} {#var CombatSpellMessage {@zmcurtheme.1 ..ooOO Sanc Up OOoo..};spellmechatrep}
#CLASS 0

#CLASS {Combat|Melee Chat Message}
#ALIAS {meleechat} {#IF (%1 = "off") {#T- {Combat|Melee Messages};#T- {Combat|MeleeMe Messages};#T- {Combat|Melee Kill};#VAR meleeChat {0};#IF (@zmShow) {#EMOTEA {@zmcurtheme.1 meleeChat disabled}} {#SHOW {@zmcurtheme.1 meleeChat disabled}}} {#T+ {Combat|Melee Messages};#T+ {Combat|MeleeMe Messages};#T+ {Combat|Melee Kill};#VAR meleeChat {1};#IF (@zmShow) {#EMOTEA {@zmcurtheme.1 meleeChat enabled}} {#SHOW {@zmcurtheme.1 meleeChat enabled}}}}
#ALIAS meleechatrep {meleeCreateDisplay;#IF (@meleeChat) {#IF {@zmShow} {meleeChatDisplay} {meleeShowMeDisplay}}}
#ALIAS meleeShowMeDisplay {#SHOW @zmcurtheme.6 You just@CombatChatMessage@zmRoomInfo}
#ALIAS meleeChatDisplay {#EMOTEALL @zmcurtheme.6 just@CombatChatMessage@zmRoomInfo}
#ALIAS meleeCreateDisplay {zmCreateRoomInfo}
#VAR meleeChat {0} {0}
#VAR CombatChatMessage {""} {""}
#CLASS 0

#CLASS {Combat|Melee Messages}
#TRIGGER {You trip (*) and %w falls down!} {#var CombatChatMessage {@zmcurtheme.7 TRIPPED@zmcurtheme.1 %1};meleechatrep}
#TRIGGER {You attempt to disarm (*), but fail.} {#var CombatChatMessage {@zmcurtheme.7 FAILED@zmcurtheme.6 to@zmcurtheme.5 disarm@zmcurtheme.1 %1};meleechatrep}
#TRIGGER {You try to trip (*), but %w leaps out of the way.} {#var CombatChatMessage {@zmcurtheme.7 FAILED@zmcurtheme.6 to@zmcurtheme.5 trip@zmcurtheme.1 %1};meleechatrep}
#TRIGGER {As (*) avoids your bash, you topple over and fall to the ground.} {#var CombatChatMessage {@zmcurtheme.7 FAILED@zmcurtheme.6 to@zmcurtheme.5 bash@zmcurtheme.1 %1};meleechatrep}
#TRIGGER {You bash (*) over the head with the hilt of your weapon.} {#VAR CombatChatMessage {@zmcurtheme.7 BASHED@zmcurtheme.1 %1};meleechatrep}
#TRIGGER {You send (*) sprawling with a powerful bash.} {#VAR CombatChatMessage {@zmcurtheme.7 BASHED@zmcurtheme.1 %1};meleechatrep}
#TRIGGER {You disarm (*) and send * flying!} {#var CombatChatMessage {@zmcurtheme.7 DISARMED@zmcurtheme.1 %1};meleechatrep}
#CLASS 0

#CLASS {Combat|MeleeMe Messages}
#TRIGGER {(*) tries to trip you, but fails.} {#var CombatChatMessage {@zmcurtheme.6 avoided being@zmcurtheme.5 bashed@zmcurtheme.6 by@zmcurtheme.1 %1};meleechatrep}
#TRIGGER {(*) trips you and you fall down!} {#var CombatChatMessage {@zmcurtheme.6 got@zmcurtheme.7 TRIPPED@zmcurtheme.6 by@zmcurtheme.1 %1};meleechatrep}
#TRIGGER {(*) sends you sprawling with a bash from the hilt of %w weapon.} {#var CombatChatMessage {@zmcurtheme.6 got@zmcurtheme.7 BASHED@zcurtheme.6 by@zmcurtheme.1 %1};meleechatrep}
#TRIGGER {(*) sends you sprawling with a powerful bash.} {#var CombatChatMessage {@zmcurtheme.6 got@zmcurtheme.7 BASHED@zmcurtheme.6 by@zmcurtheme.1 %1};meleechatrep}
#TRIGGER {You dodge a bash from (*) who loses %w balance and falls.} {#var CombatChatMessage {@zmcurtheme.6 avoided being@zmcurtheme.5 bashed@zmcurtheme.6 by@zmcurtheme.1 %1};meleechatrep}
#TRIGGER {(*) tries to disarm you, but fails.} {#var CombatChatMessage {@zmcurtheme.6 avoided being@zmcurtheme.5 disarmed@zmcurtheme.6 by@zmcurtheme.1 %1};meleechatrep}
#TRIGGER {(*) disarms you and sends * flying!} {#var CombatChatMessage {@zmcurtheme.6 got@zmcurtheme.7 DISARMED@zmcurtheme.6 by@zmcurtheme.1 %1};meleechatrep}
#CLASS 0

#CLASS {Combat|Melee Kill}
#TRIGGER {Your * kills (*)!} {#var CombatChatMessage {@zmcurtheme.4 ~-@{zmcurtheme.5}SlIcEd@{zmcurtheme.4}~-@{zmcurtheme.6} @zmcurtheme.1 %1@zmcurtheme.6 to@zmcurtheme.7 %item(@zmdeathmsg,%random(1,%numitems(@zmdeathmsg)))};meleechatrep}
#TRIGGER {You kill (*)!} {#var CombatChatMessage {@zmcurtheme.4 ~-@{zmcurtheme.5}WhAcKeD@{zmcurtheme.4}~-@{zmcurtheme.6} a@zmcurtheme.1 %1@zmcurtheme.6 to@zmcurtheme.7 %item(@zmdeathmsg,%random(1,%numitems(@zmdeathmsg)))};meleechatrep}
#TRIGGER {Your shockwave hits (*) with full force, causing an immediate death.} {#var CombatChatMessage {@zmcurtheme.4 ~-@{zmcurtheme.5}ShAtTeRrEd@{zmcurtheme.4}~-@{zmcurtheme.6} a@zmcurtheme.1 %1@zmcurtheme.6 to@zmcurtheme.7 %item(@zmdeathmsg,%random(1,%numitems(@zmdeathmsg)))};meleechatrep}
#CLASS 0

#CLASS {Combat|PK Status}
#TRIGGER {WARNING! You HAVE ENTERED a CHAOTIC PLAYER KILLING Area!} {#VAR RoomStatus {%concat(@zmcurtheme.7,CPK)}}
#TRIGGER {WARNING! You HAVE LEFT a CHAOTIC PLAYER KILLING AREA and ENTERED a NEUTRAL} {#VAR RoomStatus {%concat(@zmcurtheme.8,NPK)}}
#TRIGGER {NOTICE: You are leaving a PLAYER KILLING Area.} {#VAR RoomStatus {%concat(@zmcurtheme.2,LPK)}}
#TRIGGER {WARNING! You HAVE ENTERED a NEUTRAL PLAYER KILLING Area!} {#VAR RoomStatus {%concat(@zmcurtheme.8,NPK)}}
#TRIGGER {^You are in NPK} {#VAR RoomStatus {%concat(@zmcurtheme.8,NPK)}}
#CLASS 0

#CLASS {Combat|Room Name}
#TRIGGER {^%e[1;33m(%*)} {#if (!%pos( "(", %1)) {#if ((%1 !=~ "You see the trap*")AND(%1 !=~ "Surrounding the area is a shimmering shield, distorting everything you see.*")AND(%1 !=~ "Hovering in the room is a large golden orb with the number*")AND(%1 !=~ "You see * struggling caught in a trap*")AND(%1 !=~ "%*is*here")) {PossibleRoomName = {%1}}}} "" {color}
#TRIGGER {Ĵ%1} {#VAR PossibleRoomName {%1}}
#TRIGGER {%1} {#VAR PossibleRoomName {%1}}
#TRIGGER {%1} {#VAR PossibleRoomName {%1}}
#TRIGGER {Obvious exits:} {RoomName = @PossibleRoomName}
#CLASS 0

#CLASS {Combat|Protection}
#ALARM "Prot_Timer" {1} {#if (@ProtTix_Sanc) {#add ProtTix_Sanc -1};#if (@ProtTix_MShield) {#add ProtTix_MShield -1};#if (@ProtTix_FShield) {#add ProtTix_FShield -1};#if (@ProtTix_Images) {#add ProtTix_Images -1}}
#TRIGGER {^Poof! You arrive in the social area.} {#T- Prot_Timer}
#TRIGGER {^Poof! You arrive in the MedLink.} {#T- Prot_Timer}
#TRIGGER {^Poof, You are back to reality.} {#T+ Prot_Timer}
#TRIGGER "get_sanc_tix" {^  sanctuary           : Duration -* (%d) tick} {#VAR sanc {%ansi(bold,white,grey)s};ProtTix_Sanc = %eval((%1*30)+30);#T- get_sanc_tix} "" {disable}
#TRIGGER "get_phant_tix" {^  Phantasmal Images   : Duration -* (%d) ticks, (%d) images} {#VAR phan {%ansi(bold,yellow,grey)P};ProtTix_Images = %eval((%1*30)+30);#VAR ProtTix_NumImages {%2};#T- get_phant_tix} "" {disable}
#CLASS 0

#CLASS {Combat|ProtectionVariables}
#VAR ProtTix_Sanc {0}
#VAR MSP_ACTIVE {0}
#VAR ProtTix_FShield {0}
#VAR ProtTix_MShield {0}
#VAR ProtTix_Images {0}
#VAR ProtTix_NumImages {4}
#VAR RoomStatus {%ansi(bold,cyan)LPK} {%concat(@zmcurtheme.2,LPK)}
#VAR RoomName {A tunnel} {A tunnel}
#VAR PossibleRoomName {A tunnel} {A tunnel}
#CLASS 0

#CLASS {Combat|CompactSpellBar}
#TRIGGER {^A deep red shield of fire surrounds you.} {#VAR fir {%ansi(bold,red,grey)f};#VAR ProtTix_FShield 150}
#TRIGGER {^Your shield of fire collapses.} {#VAR fir {%ansi(bold,grey,grey)f};#VAR ProtTix_FShield 0}
#TRIGGER {^Your shield of fire slowly dissipates....and blinks out.} {#VAR fir {%ansi(bold,grey,grey)f};#VAR ProtTix_FShield 0}
#TRIGGER {spells/sancon} {#VAR sanc {%ansi(bold,white,grey)s};#VAR MSP_ACTIVE 1;#VAR fir {%ansi(bold,grey,grey)f};#T+ get_sanc_tix;sc a}
#TRIGGER {^A glowing white aura surrounds your body.} {#IF {@MSP_ACTIVE = 0} {#VAR sanc {%ansi(bold,white,grey)s};#VAR fir {%ansi(bold,grey,grey)f};#T+ get_sanc_tix;sc a}}
#TRIGGER {^The white aura around your body fades.} {#VAR sanc {%ansi(bold,grey,grey)s};#VAR ProtTix_Sanc 0}
#TRIGGER {^Your white aura flashes brightly and disappears} {#VAR sanc {%ansi(bold,grey,grey)s};#VAR ProtTix_Sanc 0}
#TRIGGER {^Your white aura flashes brightly and vanishes} {#VAR sanc {%ansi(bold,grey,grey)s};#VAR ProtTix_Sanc 0}
#TRIGGER {^A spectral image of a raven emerges from your body, flying away.} {#VAR bls {%ansi(bold,grey,grey)b}}
#TRIGGER {^A spectral raven emerges from your body, forced out by magic.} {#VAR bls {%ansi(bold,grey,grey)b}}
#TRIGGER {^The spectral image of a raven soars down from the Heavens, disappearing into your body.} {#VAR bls {%ansi(bold,green,grey)b}}
#TRIGGER {^You don't feel so well protected.} {#VAR arm {%ansi(bold,grey,grey)a}}
#TRIGGER {^A suit of ethereal armor appears on you and slowly vanishes.} {#VAR arm {%ansi(bold,blue,grey)a}}
#TRIGGER {^You feel less protected.} {#VAR arm {%ansi(bold,grey,grey)a}}
#TRIGGER {^A warm feeling runs through your body.} {#VAR poison {%ansi(bold,grey,grey)p}}
#TRIGGER {^You feel very sick.} {#VAR poison {%ansi(bold,yellow,grey)p}}
#TRIGGER {^Restarted by %0} {allreset} 
#TRIGGER {^You focus and become ONE with the catacombs.....POOF} {#VAR map {%ansi(bold,white,grey)C}}
#TRIGGER {^Your purple mapping aura fades and leaves you exhausted.} {#VAR map {%ansi(bold,grey,grey)C}}
#TRIGGER {^The detect invisible wears off.} {#VAR dei {%ansi(bold,grey,grey)d}}
#TRIGGER {^You feel less perceptive.} {#VAR dei {%ansi(bold,grey,grey)d}}
#TRIGGER {^Your eyes glow dimly for a few seconds.} {#VAR dei {%ansi(bold,magenta,grey)d}}
#TRIGGER {^The detect magic wears off.} {#VAR dem {%ansi(bold,grey,grey)d}}
#TRIGGER {^You can no longer detect magic.} {#VAR dem {%ansi(bold,grey,grey)d}}
#TRIGGER {^You sense the red in your vision disappear} {#VAR dem {%ansi(bold,grey,grey)d}}
#TRIGGER {^Your ability to detect evil auras has been dispelled.} {#VAR dem {%ansi(bold,grey,grey)d}}
#TRIGGER {^Your eyes tingle.} {#VAR dem {%ansi(bold,red,grey)d}}
#TRIGGER {^You are surrounded by a strong magical force shield.} {#VAR shl {%ansi(bold,red,grey)s}}
#TRIGGER {^Your force shield shimmers then fades away.} {#VAR shl {%ansi(bold,grey,grey)s}}
#TRIGGER {^Your magical shield has been dispelled.} {#VAR shl {%ansi(bold,grey,grey)s}}
#TRIGGER {^You can no longer see in the dark.} {#VAR inf {%ansi(bold,grey,grey)i}}
#TRIGGER {^Your sight grows dimmer.} {#VAR inf {%ansi(bold,grey,grey)i}}
#TRIGGER {^Your eyes glow red for a moment.} {#VAR inf {%ansi(bold,white,grey)i}}
#TRIGGER {^You feel a cloak of blindness dissolve.} {#VAR bli {%ansi(bold,grey,grey)b}}
#TRIGGER {blinded you!} {#VAR bli {%ansi(bold,yellow,grey)b}}
#TRIGGER {^You are blinded from the debris blown into your eyes!} {#VAR bli {%ansi(bold,yellow,grey)b}}
#TRIGGER {^Your vision returns!} {#VAR bli {%ansi(bold,grey,grey)b}}
#TRIGGER {^You feel less aware of your surroundings.} {#VAR senl {%ansi(bold,grey,grey)s}} 
#TRIGGER {^You feel less in touch with living things.} {#VAR senl {%ansi(bold,grey,grey)s}}
#TRIGGER {^You feel your awareness improve.} {#VAR senl {%ansi(bold,green,grey)s}}
#TRIGGER {^You feel more vulnerable.} {#VAR pro {%ansi(bold,grey,grey)p}}
#TRIGGER {^You feel less morally protected.} {#VAR pro {%ansi(bold,grey,grey)p}}
#TRIGGER {^You feel the protective veil of darkness vanish.} {#VAR {pro} {%ansi(bold,grey,grey)p}}
#TRIGGER {^You feel the power of vile darkness surge through your body!} {#VAR pro {%ansi(bold,white,grey)p}}
#TRIGGER {^You glow with a pulsating, white light for a few moments.} {#VAR pro {%ansi(bold,white,grey)p}}
#TRIGGER {^Your protective veil of darkness has been shattered.} {#VAR pro {%ansi(bold,grey,grey)p}}
#TRIGGER {^You feel as if an oppressive aura has been lifted from you.} {#VAR crs {%ansi(bold,grey,grey)c}}
#TRIGGER {^You feel better.} {#VAR crs {%ansi(bold,grey,grey)c}}
#TRIGGER {^You feel very uncomfortable} {#VAR crs {%ansi(bold,yellow,grey)c}}
#TRIGGER {^You feel better now.} {#VAR plague {%ansi(bold,grey,grey)p}}
#TRIGGER {^You choke and utter some muffled noises.} {#VAR plague {%ansi(bold,yellow,grey)p}}
#TRIGGER {^You feel your lungs harden and heat up!} {#VAR bre {%ansi(bold,blue,grey)b}}
#TRIGGER {^You gasp and breath in} {#VAR bre {%ansi(bold,blue,grey)b}}
#TRIGGER {^You gasp and breathe in} {#VAR bre {%ansi(bold,blue,grey)b}}
#TRIGGER {^Your lungs feel like they are on fire} {#VAR bre {%ansi(bold,grey,grey)b}}
#TRIGGER {^Your lungs heave and you cough water.} {#VAR bre {%ansi(bold,grey,grey)b}}
#TRIGGER {^You feel your stamina increase greatly.} {#VAR qui {%ansi(bold,yellow,grey)q}}
#TRIGGER {^Your endurance returns to normal.} {#VAR qui {%ansi(bold,grey,grey)q}}
#TRIGGER {^You feel yourself exposed.} {#VAR invis {%ansi(bold,grey,grey)v}}
#TRIGGER {^You make yourself more visible to the people around you.} {#VAR invis {%ansi(bold,grey,grey)v}}
#TRIGGER {^Your comrades obstruct your path to the melee.} {#VAR invis {%ansi(bold,grey,grey)v}}
#TRIGGER {^Your crush %0} {#VAR invis {%ansi(bold,grey,grey)v}}
#TRIGGER {^You slowly vanish from normal vision.} {#VAR invis {%ansi(bold,white,grey)v}}
#TRIGGER {^Your pierce %0} {#VAR invis {%ansi(bold,grey,grey)v}}
#TRIGGER {^Your pound %0} {#VAR invis {%ansi(bold,grey,grey)v}}
#TRIGGER {^Your slash %0} {#VAR invis {%ansi(bold,grey,grey)v}}
#TRIGGER {^Your whip %0} {#VAR invis {%ansi(bold,grey,grey)v}}
#TRIGGER {%0 mutilates you} {#VAR invis {%ansi(bold,grey,grey)v}}
#TRIGGER {^You rush into the fray!} {#VAR invis {%ansi(bold,grey,grey)v}}
#TRIGGER {^You have been KILLED} {allreset;#var CombatChatMessage {@zmcurtheme.7 DIED};meleechatrep}
#TRIGGER {^You're dead now.} {allreset}
#TRIGGER {^A divine force takes pity on your wretched existence} {allreset} 
#TRIGGER {^Your Mana Shield crackles, shrinks momentarily and dissipates.} {#VAR man {%ansi(bold,grey,grey)M};#VAR ProtTix_MShield 0}
#TRIGGER {^Your Mana Shield crackles and fizzles out.} {#VAR man {%ansi(bold,grey,grey)M};#VAR ProtTix_MShield 0}
#TRIGGER {^Your manashield crackles and fizzles out.} {#VAR man {%ansi(bold,grey,grey)M};#VAR ProtTix_MShield 0}
#TRIGGER {^Your Mana Shield cracks and pops out.} {#VAR man {%ansi(bold,grey,grey)M};#VAR ProtTix_MShield 0}
#TRIGGER {^Your magical energy expands and hardens into a crackling blue shield which surrounds you.} {#VAR man {%ansi(bold,cyan,grey)M};#VAR ProtTix_MShield 120}
#TRIGGER {^Your feet rise up off the ground.} {#VAR lev {%ansi(bold,white,grey)l}}
#TRIGGER {^Your levitation wears off.} {#VAR lev {%ansi(bold,grey,grey)l}}
#TRIGGER {^You don't feel lighter than air any more.} {#VAR lev {%ansi(bold,grey,grey)l}}
#TRIGGER {^Your skin does not feel as hard as it used to.} {#VAR stn {%ansi(bold,grey,grey)s}}
#TRIGGER {^Your skin feels like stone no longer.} {#VAR stn {%ansi(bold,grey,grey)s}}
#TRIGGER {^Your skin turns to a stone-like substance.} {#VAR stn {%ansi(bold,white,grey)s}}
#TRIGGER {^Several illusionary images, duplicates of yourself, appear around you.} {#VAR phan {%ansi(bold,yellow,grey)P};#T+ get_phant_tix;sc a}
#TRIGGER {^Your illusionary doubles vanish.} {#VAR phan {%ansi(bold,grey,grey)P};#VAR ProtTix_Images 0;#VAR ProtTix_NumImages 0}
#TRIGGER {^Your phantasmal images flare and dissipate as the dragon's breath engulfs them.} {#VAR phan {%ansi(bold,grey,grey)P};#VAR ProtTix_Images 0;#VAR ProtTix_NumImages 0}
#TRIGGER {^Your illusionary duplicates vanish with a bright spark of energy.} {#VAR phan {%ansi(bold,grey,grey)P};#VAR ProtTix_Images 0;#VAR ProtTix_NumImages 0}
#TRIGGER {^(*)'s attack has destroyed one of your illusionary images.} {#add ProtTix_NumImages -1;#VAR ProtTix_Images 0;#IF {@ProtTix_NumImages = 0} {#VAR phan {%ansi(bold,grey,grey)P}}}
#TRIGGER {^That tasted rather strange!!} {#VAR root {%ansi(bold,magenta,grey)r}}
#TRIGGER {^You choke and cough, spitting up some greenish-brown mucus.} {#VAR root {%ansi(bold,grey,grey)r}}
#TRIGGER {^  armor               : Duration} {#VAR arm {%ansi(bold,blue,grey)a}}
#TRIGGER {^  bless               : Duration} {#VAR bls {%ansi(bold,green,grey)b}}
#TRIGGER {^  blindness           : Duration} {#VAR bli {%ansi(bold,yellow,grey)b}}
#TRIGGER {^  breathe water       : Duration} {#VAR bre {%ansi(bold,blue,grey)b}}
#TRIGGER {^  detect evil         : Duration} {#VAR dem {%ansi(bold,red,grey)d}}
#TRIGGER {^  detect invisibility : Duration} {#VAR dei {%ansi(bold,magenta,grey)d}}
#TRIGGER {^  detect magic        : Duration} {#VAR dem {%ansi(bold,red,grey)d}}
#TRIGGER {^  detect good         : Duration} {#VAR dem {%ansi(bold,red,grey)d}}
#TRIGGER {^  fireshield          : Duration} {#VAR fir {%ansi(bold,red,grey)f}}
#TRIGGER {^  infravision         : Duration} {#VAR inf {%ansi(bold,white,grey)i}}
#TRIGGER {^  invisibility        : Duration} {#VAR invis {%ansi(bold,white,grey)v}}
#TRIGGER {^  levitate            : Duration} {#VAR lev {%ansi(bold,white,grey)l}}
#TRIGGER {^  mana shield         : Duration} {#VAR man {%ansi(bold,cyan,grey)M}}
#TRIGGER {^  protection from evil: Duration} {#VAR pro {%ansi(bold,white,grey)p}}
#TRIGGER {^  protection from good: Duration} {#VAR pro {%ansi(bold,white,grey)p}}
#TRIGGER {^  quickness           : Duration} {#VAR qui {%ansi(bold,yellow,grey)q}}
#TRIGGER {^  sanctuary           : Duration} {#VAR sanc {%ansi(bold,white,grey)s}}
#TRIGGER {^  sense life          : Duration} {#VAR senl {%ansi(bold,green,grey)s}}
#TRIGGER {^  shield              : Duration} {#VAR shl {%ansi(bold,red,grey)s}}
#TRIGGER {^  stone skin          : Duration} {#VAR stn {%ansi(bold,white,grey)s}}
#TRIGGER {^  map catacombs       : Duration} {#VAR map {%ansi(bold,white,grey)C}}
#TRIGGER {^  plague              : Duration} {#VAR plague {%ansi(bold,yellow,grey)p}}
#TRIGGER {^  curse               : Duration} {#VAR crs {%ansi(bold,yellow,grey)c}}
#TRIGGER {^  Phantasmal Images   : Duration -* (%d) ticks, (%d) images} {#VAR phan {%ansi(bold,yellow,grey)P};#VAR ProtTix_NumImages {%2}}
#TRIGGER {^  repaerdnim root     : Duration} {#VAR root {%ansi(bold,magenta,grey)r}}
#TRIGGER {DETECT-INVISIBLE    : From Equipment} {#VAR dei {%ansi(bold,mangeta,grey)d}}
#TRIGGER {SENSE-LIFE          : From Equipment} {#VAR senl {%ansi(bold,green,grey)s}}
#TRIGGER {INFRAVISION         : From Equipment} {#VAR inf {%ansi(bold,white,grey)i}}
#ALIAS allreset {#VAR invis {%ansi(bold,grey,grey)v};#VAR shl {%ansi(bold,grey,grey)s};#VAR map {%ansi(bold,grey,grey)C};#VAR man {%ansi(bold,grey,grey)M};#VAR fir {%ansi(bold,grey,grey)f};#VAR stn {%ansi(bold,grey,grey)s};#VAR sanc {%ansi(bold,grey,grey)s};#VAR bls {%ansi(bold,grey,grey)b};#VAR arm {%ansi(bold,grey,grey)a};#VAR bli {%ansi(bold,grey,grey)b};#VAR inf {%ansi(bold,grey,grey)i};#VAR pro {%ansi(bold,grey,grey)p};#VAR bre {%ansi(bold,grey,grey)b};#VAR lev {%ansi(bold,grey,grey)l};#VAR dei {%ansi(bold,grey,grey)d};#VAR dem {%ansi(bold,grey,grey)d};#VAR senl {%ansi(bold,grey,grey)s};#VAR qui {%ansi(bold,grey,grey)q};#VAR poison {%ansi(bold,grey,grey)p};#VAR plague {%ansi(bold,grey,grey)p};#VAR crs {%ansi(bold,grey,grey)c};#VAR root {%ansi(bold,grey,grey)r};#VAR phan {%ansi(bold,grey,grey)P};#VAR ProtTix_Sanc 0;#VAR ProtTix_FShield 0;#VAR ProtTix_MShield 0;#VAR ProtTix_Images 0;#VAR ProtTix_NumImages 0}
#VAR invis {%ansi(bold,grey,grey)v} {%ansi(bold,grey,grey)v}
#VAR shl {%ansi(bold,grey,grey)s} {%ansi(bold,grey,grey)s}
#VAR map {%ansi(bold,grey,grey)C} {%ansi(bold,grey,grey)C}
#VAR man {%ansi(bold,grey,grey)M} {%ansi(bold,grey,grey)M}
#VAR fir {%ansi(bold,grey,grey)f} {%ansi(bold,grey,grey)f}
#VAR stn {%ansi(bold,grey,grey)s} {%ansi(bold,grey,grey)s}
#VAR sanc {%ansi(bold,grey,grey)s} {%ansi(bold,grey,grey)s}
#VAR bls {%ansi(bold,grey,grey)b} {%ansi(bold,grey,grey)b}
#VAR arm {%ansi(bold,grey,grey)a} {%ansi(bold,grey,grey)a}
#VAR bli {%ansi(bold,grey,grey)b} {%ansi(bold,grey,grey)b}
#VAR inf {%ansi(bold,grey,grey)i} {%ansi(bold,grey,grey)i}
#VAR pro {%ansi(bold,grey,grey)p} {%ansi(bold,grey,grey)p}
#VAR bre {%ansi(bold,grey,grey)b} {%ansi(bold,grey,grey)b}
#VAR lev {%ansi(bold,grey,grey)l} {%ansi(bold,grey,grey)l}
#VAR dei {%ansi(bold,grey,grey)d} {%ansi(bold,grey,grey)d}
#VAR dem {%ansi(bold,grey,grey)d} {%ansi(bold,grey,grey)d}
#VAR senl {%ansi(bold,grey,grey)s} {%ansi(bold,grey,grey)s}
#VAR qui {%ansi(bold,grey,grey)q} {%ansi(bold,grey,grey)q}
#VAR poison {%ansi(bold,grey,grey)p} {%ansi(bold,grey,grey)p}
#VAR plague {%ansi(bold,grey,grey)p} {%ansi(bold,grey,grey)p}
#VAR crs {%ansi(bold,grey,grey)c} {%ansi(bold,grey,grey)c}
#VAR phan {%ansi(bold,grey,grey)P} {%ansi(bold,grey,grey)P}
#VAR root {%ansi(bold,grey,grey)r} {%ansi(bold,grey,grey)r}
#ST {%ansi(bold,black)~<@plague@crs@bli@poison%ansi(bold,black)~>%ansi(bold,black)~<@arm@pro@bls@invis@shl@stn@qui@dei@dem@senl@inf@lev@bre@fir@sanc@man@phan@map@root%ansi(bold,black)~> Sn: %ansi(bold,red)@{ProtTix_Sanc}%ansi(bold,green)s %ansi(bold,black)Im: %ansi(bold,red)@{ProtTix_NumImages} %ansi(bold,black)- %ansi(bold,red)@{ProtTix_Images}%ansi(bold,green)s %ansi(bold,black)MS: %ansi(bold,red)@{ProtTix_MShield}%ansi(bold,green)s %ansi(bold,black)FS: %ansi(bold,red)@{ProtTix_FShield}%ansi(bold,green)s %ansi(bold,black)T1: %ansi(bold,blue,grey)@CombatTarget%ansi(bold,black)  T2: %ansi(bold,blue,grey)@CombatTarget2%ansi(bold,black,black)}
#CLASS 0

#DELCLASS {Combat|CaebColor}

#CLASS {Combat|CaebColor}
#VARIABLE CCTypeList {bold|reset}
#VARIABLE CCNameList {black|blue|green|cyan|red|magenta|yellow|white|reset|bold}
#VARIABLE CCForeList {30|34|32|36|31|35|33|37|0|1}
#VARIABLE CCBackList {40|44|42|46|41|45|43|47}
#FUNCTION CCFore {%item(@CCForeList,%ismember(%1,@CCNameList))}
#FUNCTION CCBack {%item(@CCBackList,%ismember(%1,@CCNameList))}
#FUNCTION CaebColor {%if(%3,@CC3(%1,%2,%3),%if(%2,@CC2(%1,%2),@CC1(%1)))}
#FUNCTION CC1 {%e[@CCFore(%1)m}
#FUNCTION CC2 {%if(%ismember(%1,@CCTypeList),@CC2FC(%1,%2),@CC2BG(%1,%2))}
#FUNCTION CC3 {%e[@CCFore(%1);@CCFore(%2);@CCBack(%3)m}
#FUNCTION CC2FC {%e[@CCFore(%1);@CCFore(%2)m}
#FUNCTION CC2BG {%e[@CCFore(%1);@CCBack(%2)m}

#ALIAS ccalltest {cc1test;cc2fctest;cc2bgtest;cc3test}
#ALIAS cc1test {#FORALL @CCNameList {#SHOW @CaebColor(%i)CC1Test %i}}
#ALIAS cc2fctest {#FORALL @CCTypeList {#FORALL @CCNameList {#SHOW @CaebColor(%i,%j) CC2FCtest %i %j}}}
#ALIAS cc2bgtest {#FORALL @CCNameList {#FORALL @CCNameList {#SHOW @CaebColor(%i,%j) CC2BGtest %i %j}}}
#ALIAS cc3test {#FORALL @CCNameList {#FORALL @CCNameList {#SHOW @CaebColor(bold,%i,%j)CC3Test %i %j}}}
#CLASS 0

#CLASS {Combat|ZMaverick|User Commands}
    #VARIABLE zmShow   {0}
    #ALIAS    zmHelp   {zmtitlehelp;zmstatushelp;zmtoghelp;zmthemehelp;zmaddthemehelp;zmlistthemehelp}
    #ALIAS    zmShow   {#IF (@zmShow) {zmshow = 0;zmMessage ZMaverick ShowMe Enabled} {zmshow = 1;zmMessage ZMaverick ShowChat Enabled}}
    #ALIAS    zmStatus {#IF (@zmShow) {zmMessage Currently Reporting to Chat} {zmMessage Currently Reporting to Show}}
#CLASS 0

#CLASS {Combat|ZMaverick|General Functions}
#ALIAS zmMessage {#SHOW @CaebColor(bold,blue)~(@CaebColor(bold,white)ZMaverick@CaebColor(bold,blue)~) @CaebColor(bold,white) %1}
#ALIAS zmProcsOn {#T+ {Combat|ZMaverick|Shields|FireShield}}
#ALIAS zmProcsOff {#T- {Combat|ZMaverick|Shields|FireShield}}
#CLASS 0

#CLASS {Combat|ZMaverick|Main Trigger}
    #VARIABLE zmoldhps {0} {0}
    #VARIABLE zmnewhps {0} {0}
    #VARIABLE zmnewmana {0} {0}
    #VARIABLE zmoldmana {0} {0}
    #TRIGGER {(%n)hp (%n)m *} {zmoldmana = @zmnewmana;zmnewmana = %2;zmoldhps = @zmnewhps;zmnewhps = %1;#IF {@zmbuserstab} {zmShowDisplay};#IF {@zmbenemystab} {zmShowEnemyDisplay};#IF {@usermal} {ShowMalDisplay};#IF {@usermalme} {ShowEnemyMalDisplay}} "" {nocr|prompt}
#CLASS 0

#CLASS {Combat|ZMaverick|Help}
    #ALIAS zmtitlehelp     {zmmessage Help File}
    #ALIAS zmstatushelp    {#SHOW @CaebColor(bold,green)zmstatus%repeat(" ",4)- @CaebColor(bold,white)Will show you if you are currently reporting to show or to chat.}
    #ALIAS zmtoghelp       {#SHOW @CaebColor(bold,green)zmshow%repeat(" ",6)- @CaebColor(bold,white)Will toggle reporting to show or chat.}
    #ALIAS zmthemehelp     {#SHOW @CaebColor(bold,green)zmtheme%repeat(" ",5)- @CaebColor(bold,white)By itself, shows current theme or if used with a theme will switch to that theme.}
    #ALIAS zmaddthemehelp  {#SHOW @CaebColor(bold,green)zmaddtheme%repeat(" ",2)- @CaebColor(bold,white)Will install a new theme, theme must be a variable list with 7 colors.(NOT IMPLEMENTED YET)}
    #ALIAS zmlistthemehelp {#SHOW @CaebColor(bold,green)zmlisttheme -@CaebColor(bold,white) Will list all installed themes for use with @CaebColor(bold,green)zmtheme@CaebColor(bold,white).}
#CLASS 0

#CLASS {Combat|ZMaverick|Target Condition}
#VARIABLE zmtargcond = {""} {""}
#VARIABLE zmdeathmsg {FUBARRED|ICED|GOONIFIED|SLAIN|PURIFIED|OBLITERATED|DEAD|ASSIMILATED|ASSASSINATED}
#TRIGGER {barely clings to life.}             {zmtargcond = %concat("Barely Clinging ",@zmcurtheme.6,"(",@zmcurtheme.1,"1%~-7%",@zmcurtheme.6,")")}
#TRIGGER {grimaces with pain.}                {zmtargcond = %concat("Grimacing ",@zmcurtheme.6,"(",@zmcurtheme.1,"48%~-54%",@zmcurtheme.6,")")}
#TRIGGER {has a few scratches.}               {zmtargcond = %concat("Scratched ",@zmcurtheme.6,"(",@zmcurtheme.1,"90%~-99%",@zmcurtheme.6,")")}
#TRIGGER {looking welt on the forehead.}      {zmtargcond = %concat("Nasty Welt ",@zmcurtheme.6,"(",@zmcurtheme.1,"83%~-89%",@zmcurtheme.6,")")}
#TRIGGER {has many grievous wounds.}          {zmtargcond = %concat("Grievous Wounds ",@zmcurtheme.6,"(",@zmcurtheme.1,"22%~-28%",@zmcurtheme.6,")")}
#TRIGGER {has quite a few wounds.}            {zmtargcond = %concat("Quite A Few Wounds ",@zmcurtheme.6,"(",@zmcurtheme.1,"55%~-61%",@zmcurtheme.6,")")}
#TRIGGER {has some large, gaping wounds.}     {zmtargcond = %concat("Gaping ",@zmcurtheme.6,"(",@zmcurtheme.1,"36%~-40%",@zmcurtheme.6,")")}
#TRIGGER {has some minor wounds.}             {zmtargcond = %concat("Minor Wounds ",@zmcurtheme.6,"(",@zmcurtheme.1,"69%~-75%",@zmcurtheme.6,")")}
#TRIGGER {nasty wounds and bleeding cuts.}    {zmtargcond = %concat("Nasty Wounds ",@zmcurtheme.6,"(",@zmcurtheme.1,"41%~-47%",@zmcurtheme.6,")")}
#TRIGGER {has some small wounds and bruises.} {zmtargcond = %concat("Small Wounds ",@zmcurtheme.6,"(",@zmcurtheme.1,"76%~-82%",@zmcurtheme.6,")")}
#TRIGGER {with blood from oozing wounds.}     {zmtargcond = %concat("Oozing ",@zmcurtheme.6,"(",@zmcurtheme.1,"15%~-21%",@zmcurtheme.6,")")}
#TRIGGER {is in excellent condition.}         {zmtargcond = %concat("Excellent ",@zmcurtheme.6,"(",@zmcurtheme.1,"100%",@zmcurtheme.6,")")}
#TRIGGER {and will die soon, if not aided.}   {zmtargcond = %concat("Mortally Wounded ",@zmcurtheme.6,"(",@zmcurtheme.1,"0%",@zmcurtheme.6,")")}
#TRIGGER {looks pretty awful.}                {zmtargcond = %concat("Pretty Awful ",@zmcurtheme.6,"(",@zmcurtheme.1,"29%~-35%",@zmcurtheme.6,")")}
#TRIGGER {pales visibly as death nears.}      {zmtargcond = %concat("Paling Visibly ",@zmcurtheme.6,"(",@zmcurtheme.1,"8%~-14%",@zmcurtheme.6,")")}
#TRIGGER {winces in pain.}                    {zmtargcond = %concat("Wincing ",@zmcurtheme.6,"(",@zmcurtheme.1,"62%~-68%",@zmcurtheme.6,")")}
#TRIGGER {is DEAD}                            {zmtargcond = %item(@zmdeathmsg,%random(1,%numitems(@zmdeathmsg))}
#CLASS 0

#CLASS {Combat|ZMaverick|Backstab Types}
    #VARIABLE zmattempts {0} {0}
    #VARIABLE zmlanded   {0} {0}
    #VARIABLE zmbackstablist {} {}
#CLASS 0

#CLASS {Combat|ZMaverick|Backstab Types|User}
#VARIABLE zmbuserstab {0} {0}
#VARIABLE zmtargetname {""} {""}

#ALIAS zmAddBackstab {zmProcsOn;zmbuserstab = 1;zmtargetname = %1;zmbackstablist = %additem(%2,@zmbackstablist);#ADD zmattempts {1};#IF {%2 != 0.0} {#ADD zmlanded {1}}}
#TRIGGER {(*) makes a strange sound but is suddenly very silent, as you place * in * back.} {zmAddBackstab "%1" 6.0}
#TRIGGER {(*) turns * head, noticing you.} {zmAddBackstab "%1" 0.0}
#TRIGGER {You lunge at (*) with * but miss.} {zmAddBackstab "%1" 0.0}
#TRIGGER {You plunge * into the back of (*).} {zmAddBackstab "%1" 3.5}
#TRIGGER {(*) convulses in pain as you land a powerful backstab.} {zmAddBackstab "%1" 4.0}                
#TRIGGER {* finds a chink in (*)'s defenses and slides in for a direct hit!} {zmAddBackstab "%1" 5.0}
#TRIGGER {* finds its true mark as you stab at (*)'s back, as} {zmAddBackstab "%1" 5.5}
#TRIGGER {A flash of metal interrupts your concentration and your pierce lands slightly off-target as you stab at (*)'s back.} {zmAddBackstab "%1" 3.0}
#TRIGGER {Before * can react, * tears through (*)'s defenses and plunges into %w back.} {zmAddBackstab "%1" 4.5}
#TRIGGER {With unbelievable luck, (*) moves away just as you slash at %w back.} {zmAddBackstab "%1" 0.0}
#TRIGGER {You attempt to stab (*) in the back, but your thrust is partially deflected before penetrating %w defenses.} {zmAddBackstab "%1" 2.5}
#TRIGGER {Your clumsy attempt at a backstab barely hurts (*) at all.} {zmAddBackstab "%1" 1.5}
#TRIGGER {Your grip on * slips, and its tip only finds (*)'s shoulder blades.} {zmAddBackstab "%1" 2.0}
#CLASS 0

#CLASS {Combat|ZMaverick|Backstab Types|Enemy}
#VARIABLE zmbenemystab {0} {0}
#VARIABLE zmenemystab {""} {""}
#VARIABLE zmenemystabs {""} {""}
#VARIABLE zmmydeath {0} {0}
#VARIABLE zmenemyname {""} {""}
#ALIAS zmAddEnemyBs {zmProcsOn;zmbenemystab = 1;zmenemyname = %1;zmbackstablist = %additem(%2,@zmbackstablist);#ADD zmattempts {1};#if {%2 != 0.0} {#ADD zmlanded {1}}}
#TRIGGER {(*) slashes at you with * and misses.} {zmAddEnemyBs "%1" 0.0}
#TRIGGER {A vicious backstab from (*) causes you to choke on your own blood.}  {zmAddEnemyBs "%1" 3.5}
#TRIGGER {Suddenly (*) stabs you in the back, RIP...} {zmmydeath = 1;zmAddEnemyBs "%1" 6.0}
#TRIGGER {You hear footfalls behind, turning your head, you notice (*).}  {zmAddEnemyBs "%1" 0.0}
#TRIGGER {(*) skillfully stabs at your back with * and tears through your armor, landing a devastating backstab.}{zmAddEnemyBs "%1" 4.5}
#TRIGGER {Instinctively, you jump to the side and avoid (*) as he lunges at your back.} {zmAddEnemyBs "%1" 0.0}
#TRIGGER {(*) critically stabs you in the back with * and your body is wracked with excruciating pain.} {zmAddEnemyBs "%1" 5.5}
#TRIGGER {(*) skillfully stabs at your back with * and tears through your defenses, landing a devastating backstab.} {zmAddEnemyBs "%1" 4.5}
#TRIGGER {(*) stabs you in the back critically with * and your body is wracked with excruciating pain.} {zmAddEnemyBs "%1" 5.5}
#TRIGGER {Pain shoots through your back as (*) stabs at you with * and slides it through your defenses.} {zmAddEnemyBs "%1" 5.0}
#TRIGGER {Tendrils of pain shoot through your back as (*) stabs at your back with * and lands an off-center blow} {zmAddEnemyBs "%1" 3.0}
#TRIGGER {You convulse in pain as (*) powerfully stabs you in the back with} {zmAddEnemyBs "%1" 4.0}
#TRIGGER {You feel a sharp, stinging pain as (*) stabs at your shoulder blades with} {zmAddEnemyBs "%1" 2.0}
#TRIGGER {You reel in pain as (*) lunges at your back and lazily penetrates your defenses with a} {zmAddEnemyBs "%1" 2.5}
#TRIGGER {You reel in pain as (*) lunges at your back and lazily penetrates your defenses with the} {zmAddEnemyBs "%1" 2.5}
#TRIGGER {You wince in pain as (*) clumsily stabs at your back.} {zmAddEnemyBs "%1" 1.5}
#CLASS 0

#CLASS {Combat|ZMaverick|Shields|FireShield} {disable}
#VARIABLE zmFShield {0} {0}
#TRIGGER {^Energy rebounds from *'s fireshield hitting you.$} {zmFShield = 1}
#CLASS 0

#CLASS {Combat|ZMaverick|Twists}
#VARIABLE zmTwists {""} {""}
#TRIGGER {You twist * as you remove it from (*)'s back.} {#ADDITEM zmTwists @zmattempts}
#TRIGGER {(*) twists * as * removes it from your back.} {#ADDITEM zmTwists @zmattempts}
#CLASS 0

#CLASS {Combat|ZMaverick|Theme Manager}
//0:
//1: Attempts Landed Ratio, Numbers and the words targname and condition and hp #
//2: will be the / and the multiplier #s the x and the condition percentage
//3: will be average #
//4: will be the hyphens around singled doubled...
//5: will be the singled
//6: will be the skeleton color You just * (*!/*) [*] on * to * it was Fireshielded (Damage:*hps) (*hps)
//7: will be the Twist (T) id suggest leaving this red

#ALIAS zmlisttheme {zmMessage Currently Installed Themes;#FORALL @zmthemelist {#SHOW %i}}
#VARIABLE zmthemelist {white|peace|slime|saiyan}
#VARIABLE zmbackuptheme {""} {""}
#ALIAS zmtheme {#IF {%1} {zmswitchtheme %1} {#SHOW @CaebColor(cyan)~[@CaebColor(bold,cyan)ZMaverick@CaebColor(cyan)~]Current Theme~:;themeexample}}
#ALIAS zmswitchtheme {#IF {%ismember(%1,@zmthemelist)} {#SHOW @CaebColor(cyan)~[@CaebColor(bold,cyan)ZMaverick@CaebColor(cyan)~]Switching To Theme~: %1 - @CaebColor(BOLD,RED)EXAMPLE:;zmcurtheme = @%1;themeexample} {#SHOW @CaebColor(cyan)~[@CaebColor(bold,cyan)ZMaverick@CaebColor(cyan)~]@CaebColor(bold,white) Error, does not appear to be a valid theme}}
#ALIAS themeexample {zmsetfakebackstab;zmCreateDisplay;zmShowMeDisplay;zmClearData}
#VARIABLE zmcurtheme {@CaebColor(bold,white)|@CaebColor(bold,cyan)|@CaebColor(cyan)|@CaebColor(bold,white)|@CaebColor(bold,green)|@CaebColor(bold,blue)|@CaebColor(bold,red)|@CaebColor(bold,magenta)}
#ALIAS zmCreateDisplay {zmCreateFireShield;zmCreateType;zmCreateOutof;zmCreateMults;zmCreateAvg;zmCreateTarget;zmCreateCondition;zmCreateHps;zmCreateRoomInfo}
#VARIABLE slime {@CaebColor(bold,green)|@CaebColor(green)|@CaebColor(blue)|@CaebColor(green)|@CaebColor(bold,green)|@CaebColor(blue)|@CaebColor(bold,red)|@CaebColor(bold,magenta)}
#VARIABLE saiyan {@CaebColor(bold,blue)|@CaebColor(bold,yellow)|@CaebColor(bold,white)|@CaebColor(bold,magenta)|@CaebColor(bold,green)|@CaebColor(bold,cyan)|@CaebColor(bold,red)|@CaebColor(bold,magenta)}
#VARIABLE white {@CaebColor(bold,white)|@CaebColor(bold,white)|@CaebColor(bold,white)|@CaebColor(bold,white)|@CaebColor(bold,white)|@CaebColor(bold,white)|@CaebColor(bold,red)|@CaebColor(bold,magenta)}
#VARIABLE peace {@CaebColor(bold,white)|@CaebColor(bold,cyan)|@CaebColor(cyan)|@CaebColor(bold,white)|@CaebColor(bold,green)|@CaebColor(bold,blue)|@CaebColor(bold,red)|@CaebColor(bold,magenta)}
#CLASS 0

#CLASS {Combat|ZMaverick|Display Creator} {setdef}
#VARIABLE zmBsDisplayTypes {WhIfFeD|SiNgLeD|DoUbLeD|TrIpLeD!}
#VARIABLE zmFireShield {@CaebColor(red)F@CaebColor(bold,red)i@CaebColor(red)R@CaebColor(bold,red)e@CaebColor(red)S@CaebColor(bold,red)h@CaebColor(red)I@CaebColor(bold,red)e@CaebColor(red)L@CaebColor(bold,red)d@CaebColor(red)E@CaebColor(bold,red)d}

#VARIABLE zmTempAvg {0} {0}
#VARIABLE zmDisplay {""} {""}
#VARIABLE zmDType {""} {""}
#VARIABLE zmDOutof {""} {""}
#VARIABLE zmDMults {""} {""}
#VARIABLE zmDAvg {""} {""}
#VARIABLE zmDTarget {""} {""}
#VARIABLE zmDCondition {""} {""}
#VARIABLE zmDHps {""} {""}
#VARIABLE zmRoomInfo {""} {""}
#VARIABLE zmDamage {0} {0}
#VARIABLE zmDFire {""} {""}
#VARIABLE zmbsaverage {0} {0}

#ALIAS zmSetFakeBackstab {zmtwists = "1|2";zmFShield=1;zmoldhps = 1110;zmnewhps = 1000;zmtargcond = "NUKED!";zmtargetname = "Kathy Lee Gifford";zmbackstablist = "5.5|5.5|6.0";zmattempts = 3;zmlanded = 3}
#ALIAS zmMakeAverage {zmTempavg = 0;#FORALL @zmbackstablist {#MATH {zmTempAvg} {@zmTempAvg + %i};#MATH zmbsaverage {@zmTempAvg / %float(%numitems(@zmbackstablist))}}}
#ALIAS zmMakeDamage {zmDamage = %eval(@zmoldhps - @zmnewhps)}
#ALIAS zmCreateFireShield {zmMakeDamage;#IF {zmFShield} {zmDFire = {%concat(@zmFireShield,@zmcurtheme.6,~(,@zmcurtheme.1,@zmdamage,@zmcurtheme.2,dmg,@zmcurtheme.6~))}}}
#ALIAS zmCreateType {zmDType = %concat(@zmcurtheme.4,-,@zmcurtheme.5,%item(@zmBsDisplayTypes,@zmlanded + 1),@zmcurtheme.4,-)}
#ALIAS zmCreateOutof {zmDOutof = %concat(@zmcurtheme.6,~(,@zmcurtheme.1,@zmlanded,@zmcurtheme.6,/,@zmcurtheme.1,@zmattempts,@zmcurtheme.6,~))}
#ALIAS zmCreateMults {zmDMults = %concat(" ",@zmcurtheme.6,~[,@zmcurtheme.2);#LOOP %numitems(@zmbackstablist) {zmDMults = %concat(@zmcurtheme.2,@zmDMults,@zmbackstablist.%i,%if(%ismember(%i,@zmtwists),%item(@zmcurtheme,7)T@zmcurtheme.2));#IF {%i < %numitems(@zmbackstablist)} {zmDMults = %concat(@zmDMults," ")}};#variable zmDMults {@zmDMults~%literal(@zmcurtheme.6]~)}}
#ALIAS zmCreateAvg {zmMakeAverage;zmDAvg = %concat(" ",@zmcurtheme.6,~[,@zmcurtheme.3,%format(1,@zmbsaverage),@zmcurtheme.2,x,@zmcurtheme.1," ",Average);#VARIABLE zmDAvg {@zmDAvg~%literal(@zmcurtheme.6]~)}} 
#ALIAS zmCreateTarget {zmDTarget = %concat(" ",@zmcurtheme.1,@zmtargetname)}
#ALIAS zmCreateCondition {zmDCondition = %concat(" ",@zmcurtheme.1,@zmtargcond)}
#ALIAS zmCreateHps {zmDHps = %concat(" ",@zmcurtheme.6,~(,@zmcurtheme.1,@zmnewhps,@zmcurtheme.2,hps,@zmcurtheme.6,/,@zmcurtheme.1,@zmnewmana,@zmcurtheme.2,m,@zmcurtheme.6,~))}
#ALIAS zmCreateRoomInfo {zmRoomInfo = %concat(" ",@zmcurtheme.6,at," ",@zmcurtheme.1,@RoomName," ",@zmcurtheme.6,~{,@RoomStatus,@zmcurtheme.6,~})}
#ALIAS zmShowDisplay {zmCreateDisplay;#IF {@zmShow} {zmChatDisplay} {zmShowMeDisplay};zmClearData}
#ALIAS zmShowMeDisplay {#SHOW @zmcurtheme.6 You just @zmDtype@zmDOutof@zmDMults@zmDAvg@zmcurtheme.6 on@zmDTarget@zmcurtheme.6 %if(@zmlanded,to@zmDCondition)@zmcurtheme.6%if(@zmFShield, " it was "@zmDFire)@zmDHps@zmRoomInfo}
#ALIAS zmChatDisplay {#EMOTEALL @zmcurtheme.6 just @zmDtype@zmDOutof@zmDMults@zmDAvg@zmcurtheme.6 on@zmDTarget@zmcurtheme.6 %if(@zmlanded,to@zmDCondition)@zmcurtheme.6%if(@zmFShield," it was "@zmDFire)@zmDHps@zmRoomInfo}
#ALIAS zmCreateDisplay {zmCreateFireShield;zmCreateType;zmCreateOutof;zmCreateMults;zmCreateAvg;zmCreateTarget;zmCreateCondition;zmCreateHps;zmCreateRoomInfo}

#ALIAS zmShowEnemyDisplay {zmCreateEnemyDisplay;#IF {@zmShow} {zmChatEnemyDisplay} {zmShowMeEnemyDisplay};zmClearData}
#ALIAS zmCreateEnemyDisplay {zmCreateHps;zmMakeDamage;zmCreateType;zmCreateOutof;zmCreateMults;zmCreateAvg;zmCreateRoomInfo}
#ALIAS zmShowMeEnemyDisplay {#SHOW @zmcurtheme.2~:~: @zmcurtheme.1 @zmenemyname@zmcurtheme.6 just @zmDtype@zmDOutof@zmDMults@zmDAvg@zmcurtheme.6 on me for @zmcurtheme.1@zmDamage@zmcurtheme.6 damage!%if(@zmmydeath,@zmcurtheme.1 @zmenemyname@zmcurtheme.6 has just@zmcurtheme.1 Obliterated@zmcurtheme.6 me!,@zmDhps)}
#ALIAS zmChatEnemyDisplay {#EMOTEALL @zmcurtheme.2~:~: @zmcurtheme.1 @zmenemyname@zmcurtheme.6 just @zmDtype@zmDOutof@zmDMults@zmDAvg@zmcurtheme.6 on me for @zmcurtheme.1@zmDamage@zmcurtheme.6 damage!%if(@zmmydeath,@zmcurtheme.1 @zmenemyname@zmcurtheme.6 has just@zmcurtheme.1 Obliterated@zmcurtheme.6 me!,@zmDhps)} 
#ALIAS zmClearData {zmTwists = 0;zmbenemystab = 0;zmenemystab = "";zmenemystabs = "";zmmydeath = 0;zmFShield = 0;zmtargcond = "";zmbuserstab = 0;zmbackstablist = "";zmattempts = 0;zmlanded = 0;zmtargetname = "";zmProcsOff;usermal = 0;usermalme = 0}
#CLASS 0

